Strict 
Framework gg.IrrB3D

ib3d_Graphics3D(640,480)

Local cam:CAMERA=ib3d_CreateCamera()
T_irrICameraSceneNode(cam._node).setAspectRatio(4.0/3.0) ' need interface to this and this needs to be default
ib3d_PositionEntity(cam,30,30,30)

Local syd:MESH=ib3d_LoadAnimMesh("sydney.md2")
ib3d_EntityTexture(syd,ib3d_LoadTexture("sydney.bmp"))

Local LIGHT:LIGHT=ib3d_CreateLight()
ib3d_LightColor(LIGHT,255,255,0)
ib3d_LightRange(LIGHT,1000)
ib3d_LightCastShadows(LIGHT,True)

T_irrIAnimatedMeshSceneNode(syd._node).setFrameLoop(0,320) ' animation stuff not done
ib3d_CameraClsColor(200,200,200)
ib3d_ShadowColor(150,0,0,0)

ib3d_EntityDebugDataVisible(syd,True)
ib3d_NameEntity(syd,"SYD")
ib3d_NameEntity(cam,"CAM")

ib3d_AddZipFileArchive("map-20kdm2.pk3")

Local quake:MESH=ib3d_LoadOctTreeMesh("20kdm2.bsp")
ib3d_PositionEntity(quake,-1300,-144,-1249)

ib3d_EntityRadius(cam,30)
ib3d_EntityOffset(cam,0,10,0)
ib3d_EntityType(cam,1)
ib3d_EntityType(syd,2)
ib3d_EntityType(syd,1)
ib3d_EntityType(quake,3)

ib3d_Collisions(1,2,CD_ELLIPSOID_POLY_IRRLICHT,CR_STOP,"TEST")
ib3d_MapIncludeInCounts(ib3d_Collisions(1,3,CD_ELLIPSOID_POLY_STATIC_IRRLICHT,CR_SLIDE_LIMITED_IRRLICHT,"TEST2"),False)

Local zoom:Float=1.0

While Not ib3d_KeyDown(EKEY_ESCAPE)

	If ib3d_KeyDown(EKEY_KEY_Z) Then zoom:+0.005
	If ib3d_KeyDown(EKEY_KEY_X) Then zoom:-0.005
	
	If ib3d_KeyDown(EKEY_NUMPAD9) Then ib3d_MoveEntity(cam,0,1,0)
	If ib3d_KeyDown(EKEY_NUMPAD3) Then ib3d_MoveEntity(cam,0,-1,0)
	If ib3d_KeyDown(EKEY_NUMPAD6) Then ib3d_MoveEntity(cam,1,0,0)
	If ib3d_KeyDown(EKEY_NUMPAD4) Then ib3d_MoveEntity(cam,-1,0,0)
	If ib3d_KeyDown(EKEY_NUMPAD8) Then ib3d_MoveEntity(cam,0,0,1)
	If ib3d_KeyDown(EKEY_NUMPAD2) Then ib3d_MoveEntity(cam,0,0,-1)
	
	If ib3d_KeyDown(EKEY_LEFT) Then ib3d_TurnEntity(cam,0,-1,0)
	If ib3d_KeyDown(EKEY_RIGHT) Then ib3d_TurnEntity(cam,0,1,0)
	If ib3d_KeyDown(EKEY_UP) Then ib3d_TurnEntity(cam,1,0,0)
	If ib3d_KeyDown(EKEY_DOWN) Then ib3d_TurnEntity(cam,-1,0,0)
	If ib3d_KeyDown(EKEY_SPACE) Then ib3d_TurnEntity(cam,0,0,1)

	If ib3d_KeyDown(EKEY_KEY_Y) Then ib3d_TrackEntity(cam)

	ib3d_CameraZoom(cam,zoom)
	
	ib3d_UpdateWorld()
	ib3d_RenderWorld()
Wend

ib3d_FreeEntity(syd)
ib3d_EndGraphics()

' This simple example implements a keyboard controlled ball.
' Arrow keys apply forces To the ball.
' [Ctrl] key reverses gravity force direction.

' After compilation, this source code is turned into a file named 3impactd.dll And
' saved To the 3impactWork folder on your hard disk.
' When 3impactd.exe file (the engine) is launched, it loads this .dll file And
' executes the five functions below, also known as 'callbacks'.
' They are: PreInit(), Init(), Run(), Exit(), PostExit().

' You can fully control the engine by calling creation functions, setting functions
' And transformation functions inside the callbacks. It is that easy! See below.

Strict
Framework Pub._3Impact

' In the Init() callback you'll see that we create virtual world objects by calling
' creation functions.
' Newly created objects should always be stored in proper 'containers', named
' 'object variables', to allow for subsequent handling.
' Object variables are typically declared at the beginning of the code. Typically, one
' single line of code declares one single variable. A declaration is made of two parts.
' The first part declares the Type of the variable (For example 'CAMERA*') and the
' second part declares its custom (user defined) name (For example 'Camera').
' For simplicity, an Object variable is usually called 'object' (e.g., 'camera object').
' The following are the Object variables we need For this example.
Global Camera:Byte Ptr
Global LoadingMessage:Byte Ptr
Global SkyBox:Byte Ptr
Global Terrain:Byte Ptr
Global TerrainMesh:Byte Ptr
Global Ball:Byte Ptr
Global BallMesh:Byte Ptr
Global BallMeshShadow:Byte Ptr
Global BallTerrain:Byte Ptr

i3ImpactOpen()

Local settings:ISETTINGS=New ISETTINGS
settings.dwMode=1024*768*32
settings.bFullScreen=False
settings.bDoNotShow=True

i3ImpactSettings(settings.param())

Local engine:sample_3IEngine=New sample_3IEngine

engine.BeginRenderingLoop()

Type sample_3IEngine Extends _3IEngine

	Method _Init()

	   ' This callback is executed once, Right after opening the rendering window Or the
	   ' rendering fullscreen display.
	   ' This callback is typically used To create objects, To set their initial status,
	   ' physics properties, rendering mode, etc.
	
	   ' We always need To create a camera (point of view). Without a camera, nothing can
	   ' be rendered To the screen. The following line calls the iCameraCreate() Function
	   ' And stores the camera Object which it creates in the Object variable named Camera.
	   Camera=iCameraCreate(0.0,0.0,1.0,1.0)
	   ' Now that the newly created camera is in the 'Camera' variable, we can handle it.
	   ' For example, we can set its location, inside the virtual space. The Next line of code
	   ' calls the iCameraLocationSet() Function, passing the Camera as first parameter And
	   ' a constant 3d vector as second parameter (the location).
	   iCameraLocationSet(Camera,_D3DXVECTOR3(0.0,3.0,-10.0))
	
	   ' We also want To specify sun light direction And color.
	   iLightDirectionalSet(_D3DXVECTOR3(1.0,-1.0,1.0),_D3DXVECTOR4(1.0,1.0,1.0,0.35))
	
	   ' Creating objects can be a lengthy operation. We want To display something While
	   ' loading is in progress. So we create a 2d Object (also known as 'sprite') to
	   ' display a 'Loading...' message.
	   ' Note that Object creation will typically require a resource file, as source.
	   ' For example, For sprites, we need an image file And a .x file.
	   ' Custom resources can be created. Refer To the quick start tutorial For details.
	   ' The Next line of code will create a sprite from the loading.x resource, And will
	   ' store it in the variable named 'LoadingMessage'.
	   LoadingMessage=iSpriteCreate("default_res\\sprites\\loading.x".ToCString(),Null)
	   ' We want the message displayed now, before we start creating (loading) all other objects.
	   iSpriteRender(LoadingMessage,False)
	
	   ' We now create a 3d background For the virtual space.
	   SkyBox=iSkyBoxCreate("default_res\\skyboxes\\skybox01.sky".ToCString())
	
	   ' The first 3d 'solid' object we create is a piece of terrain. Solid objects
	   ' are called 'bodies'. A body is considered 'solid' because it is collision-response
	   ' capable. In this Case, the body is a polygonal Object (polyhedron).
	   Terrain=iBodyCreate("default_res\\terrain_5.00.ply".ToCString())
	   ' Bodies are invisible. They are processed by the engine as invisible-solid objects.
	   ' It means that they cannot be rendered (displayed) by the engine. However, we can
	   ' attach a visible mesh To them, To show where they are And what their shape is.
	   ' Mesh objects are non-solid 3d models. Unlike bodies, they are rendered by the engine.
	   ' With the Next line of code, we create a 3d visible Object from a .x
	   ' resource file. As parameters, we pass the file name For the resource To load And
	   ' the body Object we want To attach the mesh To (Terrain).
	   TerrainMesh=iBodyMeshCreate("default_res\\terrain.x".ToCString(),Terrain)
	
	   ' The second body we create is a ball. Unlike the terrain, which is made of polygons,
	   ' this Object is sphere-group based. It is as simple as a ball, so it is a one-ball
	   ' group. See tutorials For details on polyhedron And sphere-group based bodies.
	   Ball=iBodySGCreate("default_res\\ball_.spg".ToCString(),0.13)
	   ' As a body, the newly created ball is invisible. Let's attach a ball-shaped mesh to it.
	   BallMesh=iBodyMeshCreate("default_res\\ball.x".ToCString(),Ball)
	   ' We want the ball at about 5 meters above the ground, at startup.
	   iBodyLocationSet(Ball,_D3DXVECTOR3(0.0,5.0,0.0),True)
	   ' By Default, there is no air friction For bodies. We can simulate it by setting
	   ' some damping For the ball.
	   ' See Reference document For details on iBodyDampingSet() instruction And damping.
	   iBodyDampingSet(Ball,0.0,0.999,0.0,0.995)
	
	   ' We want our ball To cast a shadow onto other objects in the scenery.
	   ' The Next line of code creates a shadow volume mesh from a source .x file
	   ' And attaches it To the Ball body. See Reference document For details on
	   ' iMeshBodyShadowCasterCreate() instruction And shadows.
	   BallMeshShadow=iMeshBodyShadowCasterCreate("default_res\\ball_shadow.x".ToCString(),Ball,500.0)
	
	   ' By Default, no collision checking is performed For the bodies we have created.
	   ' We have To tell the engine what body couples should be checked For collision.
	   ' The Next line of code creates a so called body-body object.
	   ' Basically, the body-body Object is a data block specifying a body couple And
	   ' a few parameters required by the engine To compute collision-response.
	   BallTerrain=iBodyBodyCreate(Ball,Terrain)
	   ' We have stored the body-body Object For the ball-terrain couple, so that we can
	   ' set collision-response parameters For it. See Reference document For details on them.
	   iBodyBodyFrictionSet(BallTerrain,10.0)
	
	   ' Newly created bodies are disabled (no physics, no collision-response computation).
	   ' The Next two lines of code enable Ball And Terrain bodies.
	   iBodyEnable(Terrain)
	   iBodyEnable(Ball)

	   ' We don't want to show the loading message any longer, now that object creation is complete.
	   iSpriteHide(LoadingMessage)
	   ' Newly created meshes are hidden. Let's show all of them.
	   iSkyBoxShow(SkyBox)
	   iMeshShow(TerrainMesh)
	   iMeshShow(BallMesh)
	   iMeshShow(BallMeshShadow)
	EndMethod
	Method _Run()
	   ' This callback is executed 75 times per second. The first execution happens
	   ' after the Init() callback above is completed.
	
	   ' It means that the engine will repeatedly scan the lines of code from the '{'
	   ' Right below the 'void Run()' line to the '}' right above the 'void Exit()' line.
	
	   ' Each scan from '{' to '}' is called 'dll loop'. It is basically the heartbeat
	   ' of the simulation.
	
	   ' The rendering phase, in which the virtual world is displayed in its current status,
	   ' as seen from the current camera location, happens after each dll loop is complete.
	
	   ' The dll loops Continue Until the [Esc] key is pressed Or the iExit() Function
	   ' is called. Terminating the dll loops basically stops the simulation.
	
	   ' So, we have a piece of terrain And a ball. We want the camera To constantly
	   ' take the ball, wherever it goes. First of all, let's define a vector variable
	   ' To save the current ball position, that is the target To point the camera to.
   	   Local cameratarget:D3DXVECTOR3=New D3DXVECTOR3

	   ' We put the current ball location into the vector by calling iBodyLocationCM().
	   iBodyLocationCM(Ball,cameratarget.param())
	   ' Finally, we call a special Function that will point the camera To the target.
	   iCameraLookAt(Camera,cameratarget.param(),0.1)
	
	   ' We finally want the ball To be controlled by key presses. The idea is applying
	   ' forces To it according To what arrow keys are pressed by the user.
	   ' First of all, let's define proper variables to store some temporary information
	   ' we need To achieve our goal.
	   Local acceleration:D3DXVECTOR3=New D3DXVECTOR3
	   Local cameraorientation:D3DXQUATERNION=New D3DXQUATERNION
	
	   ' Linear accelerations (*) are defined by 3d vectors. We have provided a variable
	   ' named 'acceleration' to store the acceleration generated by key presses.
	   ' This vector variable will work as an accumulator. The first Step is resetting it.
	   acceleration.x=0
	   acceleration.y=0
	   acceleration.z=0

	   ' Depending on what keys are pressed, we will add a constant vector To the
	   ' acceleration variable. The length of the vector defines the intensity of
	   ' the acceleration. The direction of the vector defines the direction of it.
	   ' For example, If up-arrow is pressed, we add a 10 meter Long vector
	   ' To the accumulator. Its direction is towards Z-positive world axis.
	   ' It basically means that the ball will be pushed with an acceleration of 10
	   ' meters per second^2 in that direction, when up-arrow is pressed (**).
	   If (iKeyDown(DIK_LEFT)) acceleration.PlusEq(D3DXVECTOR3.create(-10.0,0.0,0.0))
	   If (iKeyDown(DIK_RIGHT)) acceleration.PlusEq(D3DXVECTOR3.create(10.0,0.0,0.0))
	   If (iKeyDown(DIK_UP)) acceleration.PlusEq(D3DXVECTOR3.create(0.0,0.0,10.0))
	   If (iKeyDown(DIK_DOWN)) acceleration.PlusEq(D3DXVECTOR3.create(0.0,0.0,-10.0))
	
	   ' (**) The code above basically tends To push the ball along world's X and Z
	   ' axes only, no matter where the camera is taking the scene from. It makes a bit
	   ' difficult For the user To effectively direct the ball.
	   ' We want To re-orientate the resulting acceleration vectors so that they
	   ' are camera relative. For example, we want an acceleration towards X+ axis To be
	   ' re-orientated so that it becomes an acceleration towards the Right of the screen.
	   ' To achieve this, we first store the camera orientation in a quaternion variable.
	   ' Note: most physics engine quantities (locations, forces, torques, etc) can be stored
	   ' in vector variables. To store orientations And rotations we use special variables
	   ' called 'quaternions'.
	   iCameraOrientation(Camera,cameraorientation.param())
	   ' The Next Function takes a vector (acceleration) And rotates it by using a
	   ' quaternion as a reference. Basically, 'cameraorientation' quaternion is
	   ' the rotation required To change the camera from its natural status (that
	   ' is, looking at Z+ horizon) To its current orientation. We can
	   ' say that it is the current camera orientation, but it is a rotation actually. 
	   ' So, we basically apply that orientation To the given vector. The result
	   ' is that the vector is transformed from world coordinates (absolute) To
	   ' camera coordinates (relative). And it is exactly what we need here.
	   iVectorRotate(acceleration.param(),acceleration.param(),cameraorientation.param())
	
	   ' Controls are easier now that applied acceleration has been made camera-relative.
	   ' Still we aren't done yet. Controlling the ball when the camera is pitched (for
	   ' example facing downward) isn't very easy. For some reason, it would be easier
	   ' If acceleration vector direction was always parallel To the XZ (ground) plane.
	   ' To constrain the vector To the XZ plane we just have To force its Y
	   ' coordinate To zero. Note that this may reduce vector length (intensity) on
	   ' extreme camera pitching, but it is ok For this simple example.
	   acceleration.y = 0.0
	
	   ' Now that the acceleration vector is set (Or still reset To Null If no
	   ' key was pressed), we can finally apply it To the Ball body.
	   ' (*) We are applying an acceleration And Not a force. Applying a force
	   ' means transferring To a body a defined quantity of energy. So, the resulting
	   ' speed depends on the body mass: a force applied To an heavy body will generate
	   ' a Lower speed respect To the same force applied To a lighter body.
	   ' Applying an acceleration, instead, means transferring To a body the energy required
	   ' To obtain, over time, a defined velocity Or spin, regardless of the body mass.
	   iBodyAccelerationApply(Ball,acceleration.param())
	
	   ' Finally, we apply a constant acceleration To simulate gravity.
	   ' We also implement an additional control, with the Next lines of code.
	   ' We want To reverse the gravity force (but we should actually name it
	   ' 'gravity acceleration'...) while the [Ctrl] key is pressed.
	   If Not iKeyDown(DIK_LCONTROL)
	      iBodyAccelerationApply(Ball,_D3DXVECTOR3(0.0,-9.80665,0.0))
	   Else 
	      iBodyAccelerationApply(Ball,_D3DXVECTOR3(0.0,9.80665,0.0))
	   EndIf

	EndMethod
EndType

'  ALPHA TEXTURES UNLIMITED DEMO.
'  By WeirdPumpkin.

'  This demo is based on the AlphaTexture demo. It has been modified To handle any number of masked objects,
'  automatically calculating the correct rendering priority order with a fast linked-list algorithm.
'  If you can find a better way, either by improving the sorting Or finding a workaround which eliminates the
'  entire need For sorting, please let me know.

'  The user controls the red ball. Move the red ball around And between the other balls, And knock them around.
'  You should find that distant balls are always visible through closer balls, regardless of which balls obscure which.
'  If you find a Case where this isn't so - let me know as well.

'  You can increase the number of balls easily. Just set the Balls constant, And specify locations For the balls.
'  Apart from that, the rest is handled automatically.

'  THIS SOURCE CODE IS PROVIDED "AS IS" WITHOUT WARRANTY OF ANY KIND. USE AT YOUR OWN RISK.

Strict

Framework Pub._3Impact

Global Camera:Byte Ptr
Global LoadingMessage:Byte Ptr
Global SkyBox:Byte Ptr
Global Terrain:Byte Ptr
Global TerrainMesh:Byte Ptr

' ************************************************
'  ADDED For THIS DEMO
' ************************************************
Const Balls:Int   = 5          '  Specify number of balls in scene.
Const Couples:Int = 10         '  5 objects - 10 unique connections. Count 'em.

Global Ball:Byte Ptr[Balls]
Global BallMesh:Byte Ptr[Balls]
Global ShadowMesh:Byte Ptr[Balls]
Global BallTerrain:Byte Ptr[Balls]
Global BallBall:Byte Ptr[Couples]
Global BallDist:Float[Balls]

'  Linked-list structure For quickly ordering objects For rendering.
Type _NODE 
    Field prev:_NODE     '  Reference To preceeding node, If any, Or NULL.
    Field _next:_NODE    '  Reference To Next node, If any, Or NULL.
    Field mesh:Byte Ptr     '  Reference To mesh at this node.
    Field dist:Float        '  Distance between camera And mesh.
EndType

Global Node:_NODE[Balls]

' init the nodes
For Local i:Int=0 To Balls-1
	Node[i]=New _NODE
Next

Global first:_NODE
Global Nodes:Int         '  Number of nodes used so far.

' ************************************************

Global rendermode:Int

Global FontWhite:Byte Ptr

i3ImpactOpen()

Local settings:ISETTINGS=New ISETTINGS
settings.dwMode=1024*768*32
settings.bFullScreen=False
settings.bDoNotShow=True

i3ImpactSettings(settings.param())

Local engine:sample_3IEngine=New sample_3IEngine

engine.BeginRenderingLoop()

Type sample_3IEngine Extends _3IEngine

	Method _Init()
	    Camera=iCameraCreate(0.0,0.0,1.0,1.0)
	    iCameraLocationSet(Camera,_D3DXVECTOR3(0.0,1.0,-10.0))
	
	    FontWhite=iFontCreate("default_res\\fontwhite\\font.wid".ToCString(),Null)
	
	    iLightDirectionalSet(_D3DXVECTOR3(1.0,-1.0,1.0),_D3DXVECTOR4(1.0,1.0,1.0,0.35))
	    iShadowColorSet(_D3DXVECTOR3(0.9,0.9,0.7))
	
	    LoadingMessage=iSpriteCreate("default_res\\sprites\\loading.x".ToCString(),Null)
	    iSpriteRender(LoadingMessage,False)
	
	    SkyBox=iSkyBoxCreate("default_res\\skyboxes\\skybox01.sky".ToCString())
	
	    Terrain     = iBodyCreate    ("default_res\\terrain_5.00.ply".ToCString())
	    TerrainMesh = iBodyMeshCreate("default_res\\terrain.x".ToCString(),Terrain)
	
	    ' ************************************************
	    '  ADDED For THIS DEMO
	    ' ************************************************
	    Local i:Int,j:Int,n:Int
	
	    '  Create balls.
	    For i = 0 To Balls-1
	        Ball[i] = iBodySGCreate("default_res\\ball_.spg".ToCString(),0.13)
	        If (i = 0)
	            '  First ball is red - And user-controlled.
	            BallMesh[i] = iBodyMeshCreate("default_res\\ballred.x".ToCString(),  Ball[i])
	        Else
	            '  Remaining balls are green - And Not user-controlled.
	            BallMesh[i] = iBodyMeshCreate("default_res\\ballgreen.x".ToCString(),Ball[i])
	        EndIf
	        ShadowMesh[i] = iMeshBodyShadowCasterCreate("default_res\\ball_shadow.x".ToCString(),Ball[i],25.0)
	        iMeshAlphaTextureChange(BallMesh[i],"default_res\\alpha_a.jpg")
	        iBodyDampingSet(Ball[i],0.0,0.999,0.0,0.995)
	        BallTerrain[i] = iBodyBodyCreate(Ball[i],Terrain)
	        iBodyBodyFrictionSet(BallTerrain[i],10.0)
	    Next
	
	    '  Set ball locations.
	    iBodyLocationSet(Ball[0],_D3DXVECTOR3( 0.0,1.2, 0.0),True)  '  Red ball - user controlled.
	    iBodyLocationSet(Ball[1],_D3DXVECTOR3( 4.0,1.2,-5.0),True)
	    iBodyLocationSet(Ball[2],_D3DXVECTOR3(-4.0,1.2,-5.0),True)
	    iBodyLocationSet(Ball[3],_D3DXVECTOR3( 4.0,1.2, 5.0),True)
	    iBodyLocationSet(Ball[4],_D3DXVECTOR3(-4.0,1.2, 5.0),True)
	
	    '  Create collsion couples.
	    n = 0
	    For i = 0 To Balls-1
	        For j = 0 To Balls-1
	            If (j > i) 
	                '  Create only unique collision couples.
	                BallBall[n] = iBodyBodyCreate(Ball[i],Ball[j])
	                iBodyBodyFrictionSet(BallBall[n],1.0)
	                n:+1
	            EndIf
	        Next
	    Next
	
	    '  Set initial render mode To 0
	    Rendermode = 0
	
	    '  Hide message And show all meshes
	    iSpriteHide(LoadingMessage)
	    iSkyBoxShow(SkyBox)
	    iBodyEnable(Terrain)
	    iMeshShow(TerrainMesh)
	    ' ************************************************
	    '  MODIFIED For THIS DEMO.
	    ' ************************************************
	    For i = 0 To Balls-1
	        iBodyEnable(Ball      [i])
	        iMeshShow  (BallMesh  [i])
	        iMeshShow  (ShadowMesh[i])
	    Next
	    ' ************************************************
	EndMethod

	Method _Run()
	    Local i:Int
	   Local cameratarget:D3DXVECTOR3=New D3DXVECTOR3
	   iBodyLocationCM(Ball[0],cameratarget.param())
	   iCameraLookAt(Camera,cameratarget.param(),0.1)
	
	   Local acceleration:D3DXVECTOR3=New D3DXVECTOR3
	   Local cameraorientation:D3DXQUATERNION=New D3DXQUATERNION
	
	   acceleration.x=0
	   acceleration.y=0
	   acceleration.z=0
	
	   If (iKeyDown(DIK_LEFT)) acceleration.PlusEq(D3DXVECTOR3.create(-10.0,0.0,0.0))
	   If (iKeyDown(DIK_RIGHT)) acceleration.PlusEq(D3DXVECTOR3.create(10.0,0.0,0.0))
	   If (iKeyDown(DIK_UP)) acceleration.PlusEq(D3DXVECTOR3.create(0.0,0.0,10.0))
	   If (iKeyDown(DIK_DOWN)) acceleration.PlusEq(D3DXVECTOR3.create(0.0,0.0,-10.0))
	
	   iCameraOrientation(Camera,cameraorientation.param())
	   iVectorRotate(acceleration.param(),acceleration.param(),cameraorientation.param())
	
	   acceleration.y = 0.0
	
	    '  Apply user-controlled accelerations To red ball.
	    iBodyAccelerationApply(Ball[0],acceleration.param())
	
	    '  Apply gravity To red ball, as dictated by user.
	    If Not iKeyDown(DIK_LCONTROL)
	       iBodyAccelerationApply(Ball[0],_D3DXVECTOR3(0.0,-9.80665,0.0))
	    Else 
	       iBodyAccelerationApply(Ball[0],_D3DXVECTOR3(0.0,9.80665,0.0))
	    EndIf	
	    '  Apply gravity To all other balls.
	    For i = 1 To Balls-1
	        iBodyAccelerationApply(Ball[i],_D3DXVECTOR3(0.0,-9.80665,0.0))
		Next
		
	    ' ************************************************
	    '  MODIFIED For THIS DEMO
	    ' ************************************************
	
	    '  Acquire distance between camera And each ball.
	   ' define some temporary vectors
	    Local cameralocation:D3DXVECTOR3=New D3DXVECTOR3
	    Local balllocation:D3DXVECTOR3=New D3DXVECTOR3

	    iCameraLocation(Camera,cameralocation.param())
	    For i = 0 To Balls-1
	        iMeshLocation(BallMesh[i],balllocation.param())
	        BallDist[i] = iVectorLengthSq(balllocation.Minus(cameralocation).param())
	    Next
	
	    '  Clear node list.
	    For i = 0 To Balls-1
	        Node[i].prev = Null
	        Node[i]._next = Null
	    Next
	
	    '  Add first mesh directly, so following balls have something To compare against.
	    Nodes       = 1
	    first       = Node[0]
	    first.mesh = BallMesh[0]
	    first.dist = BallDist[0]
	
	    '  Add remaining balls by finding the Right place For them in the linked list.
	    '  NOTE: Must be added in reverse order, that is, from farthest To nearest.
	    Local curr:_NODE = first
	    For i = 1 To Balls-1
	
	        Repeat
	
	            If (BallDist[i] > curr.dist)
	                '  This ball is further than the current node.
	
	                If (curr.prev)
	                    '  There is a previous node - jump To it now.
	                    curr = curr.prev
	
	                    '  Check If ball is closer than predeccessor.
	                    If (BallDist[i] < curr.dist)
	                        '  Ball is further than previous node, but closer than its predeccessor - so insert between them.
	                        Node[Nodes].prev = curr
	                        Node[Nodes]._next = curr._next
	                        Node[Nodes].mesh = BallMesh[i]
	                        Node[Nodes].dist = BallDist[i]
	                        curr._next.prev = Node[Nodes]
	                        curr._next       = Node[Nodes]
	                        Nodes:+1
	                        Exit
	                    EndIf
	                    
	                Else
	                    '  This is the first node - add the New node To the start of the list And Proceed To Next ball.
	                    Node[Nodes]._next = curr
	                    Node[Nodes].mesh = BallMesh[i]
	                    Node[Nodes].dist = BallDist[i]
	                    curr.prev = Node[Nodes]
	                    first      = Node[Nodes]
	                    Nodes:+1
	                    Exit
	                EndIf
	
	            Else
	                '  This ball is closer than the current node.
	
	                If (curr._next)
	                    '  There is a successor node - jump To it now.
	                    curr = curr._next
	
	                    '  Check If ball is further than successor.
	                    If (BallDist[i] > curr.dist)
	                        '  Ball is closer than previous node, but furhter than its successor - so insert between them.
	                        Node[Nodes].prev = curr.prev
	                        Node[Nodes]._next = curr
	                        Node[Nodes].mesh = BallMesh[i]
	                        Node[Nodes].dist = BallDist[i]
	                        curr.prev._next = Node[Nodes]
	                        curr.prev       = Node[Nodes]
	                        Nodes:+1
	                        Exit
	                    EndIf
	
	                Else
	                    '  This is the last node - add the New node To the End of the list And Proceed To Next ball.
	                    Node[Nodes].prev = curr
	                    Node[Nodes].mesh = BallMesh[i]
	                    Node[Nodes].dist = BallDist[i]
	                    curr._next = Node[Nodes]
	                    Nodes:+1
	                    Exit
	                EndIf
	            EndIf
	        Forever
	    Next
	
	    '  Set rendering order, from farthest (1) To closest (n).
	    Local order:Int = 1
	    Repeat
	        iMeshRenderPrioritySet(first.mesh,order)
	        first = first._next
	        order:+1
	    Until Not first
	
	    ' ************************************************
	
	    '  Select render mode For the balls according To current Rendermode variable state
	    If (Rendermode = 0)
	        '  Render the balls in normal mode
	        For i = 0 To Balls-1
	            iMeshRenderModeSet(BallMesh[i],D3DBLEND_SRCALPHA,D3DBLEND_INVSRCALPHA,True,False)
		   Next
	    Else
	        '  Render the balls in 'burnout' mode
	        For i = 0 To Balls-1
	            iMeshRenderModeSet(BallMesh[i],D3DBLEND_SRCALPHA,D3DBLEND_ONE,False,False)
		   Next
	    EndIf
	    '  Switch render modes on [space] key press
	    If (iKeyClick(DIK_SPACE)) Then Rendermode = Not RenderMode ' If 0 turns 1, If 1 turns 0
	    iPrintCentered("PRESS [SPACE] TO SWITCH RENDERING MODE".ToCString(),_D3DXVECTOR2(0.0,10.0),_D3DXVECTOR2(0.4,0.35),0.1,FontWhite,0.0)
	EndMethod
EndType

' Alpha texture demo

' THIS SOURCE CODE IS PROVIDED "AS IS" WITHOUT WARRANTY OF ANY KIND. USE AT YOUR OWN RISK.

Strict

Framework Pub._3Impact

Global Camera:Byte Ptr
Global LoadingMessage:Byte Ptr
Global SkyBox:Byte Ptr
Global Terrain:Byte Ptr
Global TerrainMesh:Byte Ptr
Global RedBall:Byte Ptr
Global GreenBall:Byte Ptr
Global RedBallMesh:Byte Ptr
Global RedBallMeshShadow:Byte Ptr
Global GreenBallMesh:Byte Ptr
Global GreenBallMeshShadow:Byte Ptr
Global RedBallTerrain:Byte Ptr
Global GreenBallTerrain:Byte Ptr
Global RedBallGreenBall:Byte Ptr

Global rendermode:Int

Global FontWhite:Byte Ptr

i3ImpactOpen()

Local settings:ISETTINGS=New ISETTINGS
settings.dwMode=1024*768*32
settings.bFullScreen=False
settings.bDoNotShow=True

i3ImpactSettings(settings.param())

Local engine:sample_3IEngine=New sample_3IEngine

engine.BeginRenderingLoop()

Type sample_3IEngine Extends _3IEngine

	Method _Init()
	   Camera=iCameraCreate(0.0,0.0,1.0,1.0)
	   iCameraLocationSet(Camera,_D3DXVECTOR3(0.0,1.0,-10.0))
	
	   FontWhite=iFontCreate("default_res\\fontwhite\\font.wid".ToCString(),Null)
	
	   iLightDirectionalSet(_D3DXVECTOR3(1.0,-1.0,1.0),_D3DXVECTOR4(1.0,1.0,1.0,0.35))
	   iShadowColorSet(_D3DXVECTOR3(0.9,0.9,0.7))
	
	   LoadingMessage=iSpriteCreate("default_res\\sprites\\loading.x".ToCString(),Null)
	   iSpriteRender(LoadingMessage,False)
	
	   SkyBox=iSkyBoxCreate("default_res\\skyboxes\\skybox01.sky".ToCString())
	
	   Terrain=iBodyCreate("default_res\\terrain_5.00.ply".ToCString())
	   TerrainMesh=iBodyMeshCreate("default_res\\terrain.x".ToCString(),Terrain)
	
	   ' create red ball body
	   RedBall=iBodySGCreate("default_res\\ball_.spg".ToCString(),0.13)
	   ' create red ball meshes And attach them To red ball body
	   RedBallMesh=iBodyMeshCreate("default_res\\ballred.x".ToCString(),RedBall)
	   RedBallMeshShadow=iMeshBodyShadowCasterCreate("default_res\\ball_shadow.x".ToCString(),RedBall,25.0)
	   ' change red ball alpha texture
	   iMeshAlphaTextureChange(RedBallMesh,"default_res\\alpha_a.jpg")
	
	   ' create green ball body
	   GreenBall=iBodySGCreate("default_res\\ball_.spg".ToCString(),0.13)
	   ' create green ball meshes And attach them To green ball body
	   GreenBallMesh=iBodyMeshCreate("default_res\\ballgreen.x".ToCString(),GreenBall)
	   GreenBallMeshShadow=iMeshBodyShadowCasterCreate("default_res\\ball_shadow.x".ToCString(),GreenBall,25.0)
	   ' change green ball alpha texture
	   iMeshAlphaTextureChange(GreenBallMesh,"default_res\\alpha_a.jpg")
	
	   ' NOTE: redball.x And greenball.x meshes have been modeled with a Double surface.
	   ' That is, both the outside And the inside of the balls are visible. This is
	   ' evident when we apply the transparent (alpha_a.jpg) texture To them.
	
	   ' set red ball body initial location
	   iBodyLocationSet(RedBall,_D3DXVECTOR3(0.0,5.0,0.0),True)
	   iBodyDampingSet(RedBall,0.0,0.999,0.0,0.995)
	   ' set green ball body initial location
	   iBodyLocationSet(GreenBall,_D3DXVECTOR3(4.0,1.2,-5.0),True)
	   iBodyDampingSet(GreenBall,0.0,0.999,0.0,0.995)
	
	   ' enable collisions
	   RedBallTerrain=iBodyBodyCreate(RedBall,Terrain)
	   iBodyBodyFrictionSet(RedBallTerrain,10.0)
	   GreenBallTerrain=iBodyBodyCreate(GreenBall,Terrain)
	   iBodyBodyFrictionSet(GreenBallTerrain,10.0)
	   RedBallGreenBall=iBodyBodyCreate(RedBall,GreenBall)
	   iBodyBodyFrictionSet(RedBallGreenBall,1.0)
	
	   ' set initial render mode To 0
	   Rendermode = 0
	
	   ' enable bodies
	   iBodyEnable(Terrain)
	   iBodyEnable(RedBall)
	   iBodyEnable(GreenBall)
	
	   ' hide message And show all meshes
	   iSpriteHide(LoadingMessage)
	   iSkyBoxShow(SkyBox)
	   iMeshShow(TerrainMesh)
	   iMeshShow(RedBallMesh)
	   iMeshShow(RedBallMeshShadow)
	   iMeshShow(GreenBallMesh)
	   iMeshShow(GreenBallMeshShadow)

	EndMethod

	Method _Run()
	   Local cameratarget:D3DXVECTOR3=New D3DXVECTOR3
	   iBodyLocationCM(RedBall,cameratarget.param())
	   iCameraLookAt(Camera,cameratarget.param(),0.1)
	
	   Local acceleration:D3DXVECTOR3=New D3DXVECTOR3
	   Local cameraorientation:D3DXQUATERNION=New D3DXQUATERNION
	
	   acceleration.x=0
	   acceleration.y=0
	   acceleration.z=0
	
	   If (iKeyDown(DIK_LEFT)) acceleration.PlusEq(D3DXVECTOR3.create(-10.0,0.0,0.0))
	   If (iKeyDown(DIK_RIGHT)) acceleration.PlusEq(D3DXVECTOR3.create(10.0,0.0,0.0))
	   If (iKeyDown(DIK_UP)) acceleration.PlusEq(D3DXVECTOR3.create(0.0,0.0,10.0))
	   If (iKeyDown(DIK_DOWN)) acceleration.PlusEq(D3DXVECTOR3.create(0.0,0.0,-10.0))
	
	   iCameraOrientation(Camera,cameraorientation.param())
	   iVectorRotate(acceleration.param(),acceleration.param(),cameraorientation.param())
	
	   acceleration.y = 0.0
	
	   iBodyAccelerationApply(RedBall,acceleration.param())
	
	   If Not iKeyDown(DIK_LCONTROL)
		iBodyAccelerationApply(RedBall,_D3DXVECTOR3(0.0,-9.80665,0.0))
	   Else 
		iBodyAccelerationApply(RedBall,_D3DXVECTOR3(0.0,9.80665,0.0))
        EndIf
	
	   iBodyAccelerationApply(GreenBall,_D3DXVECTOR3(0.0,-9.80665,0.0))
	
	   ' Set the rendering priority For the two ball meshes depending on their
	   ' distance from the camera, so that the farther ball is rendered first.
	
	   ' define some temporary vectors
	   Local cameralocation:D3DXVECTOR3=New D3DXVECTOR3
	   Local redlocation:D3DXVECTOR3=New D3DXVECTOR3
	   Local greenlocation:D3DXVECTOR3=New D3DXVECTOR3

	   ' And store current camera And ball locations in them
	   iCameraLocation(Camera,cameralocation.param())
	   iMeshLocation(RedBallMesh,redlocation.param())
	   iMeshLocation(GreenBallMesh,greenlocation.param())
	
	   ' compare the [squared] lengths of vector from camera To red ball And
	   ' from camera To green ball. Note that &(redlocation-cameralocation)
	   ' is an expression that calculates the vector from one point To another
	   ' And resolves To a pointer To a temporary variable allocated somewhere
	   ' by the compiler. It is basically an advanced C++ trick... ;-)
	   If (iVectorLengthSq(redlocation.Minus(cameralocation).param()) > iVectorLengthSq(greenlocation.Minus(cameralocation).param()))
	      ' red ball is farther
	      iPrintCentered("Red ball is farther: rendered first".ToCString(),_D3DXVECTOR2(0.0,11.0),_D3DXVECTOR2(1.0,0.5),0.1,FontWhite,0.0)
	      iMeshRenderPrioritySet(RedBallMesh,1) ' render this mesh...
	      iMeshRenderPrioritySet(GreenBallMesh,2) ' ...before this mesh
	   Else
	      ' green ball is farther
	      iPrintCentered("Green ball is farther: rendered first".ToCString(),_D3DXVECTOR2(0.0,11.0),_D3DXVECTOR2(1.0,0.5),0.1,FontWhite,0.0)
	      iMeshRenderPrioritySet(RedBallMesh,2) ' render this mesh...
	      iMeshRenderPrioritySet(GreenBallMesh,1) ' ...after this mesh
	   EndIf
	
	   ' Select render mode For the balls according To current Rendermode variable state
	   If (Rendermode = 0)
	      ' render the balls in normal mode
	      iMeshRenderModeSet(RedBallMesh,D3DBLEND_SRCALPHA,D3DBLEND_INVSRCALPHA,True,False)
	      iMeshRenderModeSet(GreenBallMesh,D3DBLEND_SRCALPHA,D3DBLEND_INVSRCALPHA,True,False)
	   Else
	      ' render the balls in 'burnout' mode
	      iMeshRenderModeSet(RedBallMesh,D3DBLEND_SRCALPHA,D3DBLEND_ONE,False,False)
	      iMeshRenderModeSet(GreenBallMesh,D3DBLEND_SRCALPHA,D3DBLEND_ONE,False,False)
	   EndIf
	
	   ' switch render modes on [space] key press
	   If (iKeyClick(DIK_SPACE)) Then Rendermode = Not RenderMode ' If 0 turns 1, If 1 turns 0
	   iPrintCentered("PRESS [SPACE] TO SWITCH RENDERING MODE".ToCString(),_D3DXVECTOR2(0.0,10.0),_D3DXVECTOR2(0.4,0.35),0.1,FontWhite,0.0)
	EndMethod

EndType

Framework BRL.Basic

Type t1
	Function test1()
		test2()
	EndFunction
	
	Function test2()
		DebugLog("t1")
	EndFunction
EndType

Type t2 Extends t1
	Function test2()
		DebugLog("t2")
	EndFunction
EndType

t2.test1()

Framework BRL.Basic

Type t1
	Function test1(pTest2())
		pTest2()
	EndFunction
	
	Function test2()
		DebugLog("t1")
	EndFunction
EndType

Type t2 Extends t1
	Function test2()
		DebugLog("t2")
	EndFunction
EndType

t2.test1(t2.test2)