OnUpdate() not being called often if...

Monkey Targets Forums/HTML5/OnUpdate() not being called often if...

Salmakis

(Posted 2016) [#1]

OnUpdate() not being called often if the canvas is not visible (i.e. if im in another tab in the browser (firefox in this case)), or if browser is minized etc.
i also found out that the javascript setInterval() function also is not working fine when the tab where the game is in is not visible, the time gets shifted compared to a tab that is all time open.
i think OnUpdate uses the setIntervall stuff? so this might be the reason then?

is there any trick to force it to keep it calling 30 updates per second even if the tab is not open/minimized/on other desktop?

Or is the workaround to count the updates and calculate them with the time, and let them all come after if the user returns to the tab with the game?

ImmutableOctet(SKNG)

(Posted 2016) [#2]

The exact approach is up to you, but have you tried setting 'MOJO_AUTO_SUSPEND_ENABLED' to 'False'?

#MOJO_AUTO_SUSPEND_ENABLED = False

Salmakis

(Posted 2016) [#3]

yes i have that setting on false

k.o.g.

(Posted 2016) [#4]

Use a Webworker :D

It is not 100% tested! and not fully finished

Strict

#If MOJO_AUTO_SUSPEND_ENABLED = False And TARGET = "html5" Then
Private
Import dom.dom

Extern Private
#If CONFIG = "debug" Then
	Function log:Void(str:String) = "window.console.log"
#Else
	Function log:Void(str:String) = "(function(str){})"
#End

	'Function evalBlob:Blob(cmd:String) = "window.eval"
	Function createObjectURL:String(blob:Blob) = "window.URL.createObjectURL"
	Function revokeObjectURL:Void(url:String) = "window.URL.revokeObjectURL"
	
	Function GenerateBlob:Blob(script:String) = "(function(script){return new Blob([script], {type: 'text/javascript'});})"
	Function DelegateUpdate:Void(instance:BBGame) = "(function(game){if(game._debugExs){try{game._delegate.UpdateGame();}catch(ex){game.Die(ex);}}else{game._delegate.UpdateGame();}})"

	Class BBGame Extends Null = "BBGame"
		Function Game:BBGame()
		Field _started:Bool
		Field _updateRate:Int
	End
	
	Class Blob Extends Null = "Blob"
	End
	
	Class CmdObject Extends Null = "Object"
		Field cmd:String
		
		Field updaterate:Int
		Field active:Int
	End
	
	Class CustomEvent Extends Event = "Event"
		Field data:CmdObject = "data"
	End
	
	Function NewWorker:Worker(url:String) = "new Worker"
	Class Worker Extends EventTarget = "Worker"
		Method postMessage:Void(message:CmdObject)
	End

	Global MonkeyWindowIsActive:Bool
	Global MonkeyUpdateThreadInstance:UpdateThread
Public

Class UpdateThread Extends EventListener
Private
	Field _worker:Worker
	Field _url:String
	Field _game:BBGame
	
	Field _cmd:CmdObject = New CmdObject()
	
	Method New()
	End
	
	Function Instance:UpdateThread()
		If MonkeyUpdateThreadInstance = Null MonkeyUpdateThreadInstance = New UpdateThread()
		Return MonkeyUpdateThreadInstance
	End
	
	Method UpdateGame:Void()
		If _game = Null Return
		
		If _game._started DelegateUpdate(_game)
	End
	
	Method SendUpdate:Void()
		If _worker = Null Return
		
		_cmd.cmd = "change"
		_cmd.updaterate = _game._updateRate
		_cmd.active = 1 - MonkeyWindowIsActive
		_worker.postMessage(_cmd)
	End
	
	Method SetUpdateRate:Void(fake:Bool = False)
		If fake = False SendUpdate()
	End
	
	Method handleEvent:Int( event:Event )
		Local e:CustomEvent = CustomEvent(event)
		If e.type <> "message" log(e.type)
		Select event.type
			Case "loaded"
				
			Case "message"
				Select e.data.cmd
					Case "tick"
						UpdateGame()
				End
				
			Case "focus"
				MonkeyWindowIsActive = True
				SendUpdate()
			Case "blur"
				MonkeyWindowIsActive = False
				SendUpdate()
		End
		
		Return 1
	End
	
	Function WrapperScript:String()
		Local script:String = ""
		
		script += "/* Author: k.o.g. (c) 2016 */~n"
		script += "var MonkeyUpdateThreadInstance=null;"
		script += "var MonkeyWindowIsActive=" + document.hasFocus() * 1 + ";"
		script += "(function(){"
		script += "~quse strict~q;"
		script += "BBHtml5Game.prototype.UpdateGame_org=BBHtml5Game.prototype.UpdateGame;"
		script += "BBHtml5Game.prototype.UpdateGame=function(){"
		script += "if(MonkeyWindowIsActive) BBHtml5Game.prototype.UpdateGame_org.call(this);"
		script += "};"
		script += "BBHtml5Game.prototype.SetUpdateRate_org=BBHtml5Game.prototype.SetUpdateRate;"
		script += "BBHtml5Game.prototype.SetUpdateRate=function(updateRate){"
		script += "BBHtml5Game.prototype.SetUpdateRate_org.call(this, updateRate);"
		script += "MonkeyUpdateThreadInstance.p_SetUpdateRate();"
		script += "}"
		script += "})();"
		
		Return script
	End
	
	Function WorkerScript:String()
		Local script:String = ""
		
		script += "(function(){"
		script += "  ~quse strict~q;"
		script += "  var _timer = 0;"
		script += "  var _updaterate = 60;"
		script += "  var _active = 0;"
		script += "  function Setup(){"
		script += "    if(_timer) clearInterval(_timer);"
		script += "    _timer = 0;"
		script += "    if(_active) {"
		script += "      _timer = setInterval(function(){"
		script += "        self.postMessage({'cmd':'tick'});"
		script += "      }, (1000 / _updaterate) / 2);"
		script += "    }"
		script += "  }"
		script += "  self.addEventListener('message', function(event){"
		script += "    var data = event.data;"
		script += "    switch(data.cmd) {"
		script += "      case 'change':"
		script += "        _updaterate = data.updaterate;"
		script += "        _active = data.active;"
		script += "        Setup();"
		script += "      break;"
		script += "    }"
		script += "  });"
		script += ""
		script += "  self.postMessage({'cmd':'loaded'});"
		script += "})();"
		
		Return script
	End
	
	Method Do:Void()
		SetUpdateRate(True)
		
		_game = BBGame.Game()
		
		window.addEventListener("blur", Self, False)
		window.addEventListener("focus", Self, False)

		' Evil
		'Local s:String = "new Blob(['"+WorkerScript().Replace("'", "\'")+"'], {type: 'text/javascript'});"
		'Local data:Blob = evalBlob(s)
		
		Local data:Blob = GenerateBlob(WorkerScript())
		_url = createObjectURL(data)
		_worker = NewWorker(_url)
		_worker.addEventListener("message", Self, False)

		SendUpdate()
	End
	
	Method Clear:Void()
		revokeObjectURL(_url)
		_url = ""
	End
	
Public
	Function Initialize:Void()
		#If CONFIG = "debug" Then
		Local workerScriptElement:HTMLElement = HTMLElement(document.createElement("script"))
		workerScriptElement.setAttribute("id", "MonkeyUpdateThread")
		workerScriptElement.setAttribute("type", "javascript/worker")
		workerScriptElement.innerHTML = WorkerScript().Replace(";", ";~n")
		document.head.appendChild(workerScriptElement)
		#End

		Local wrapperScriptElement:HTMLElement = HTMLElement(document.createElement("script"))
		wrapperScriptElement.setAttribute("id", "MonkeyUpdateWrapper")
		wrapperScriptElement.setAttribute("type", "text/javascript")
		wrapperScriptElement.setAttribute("data-info", "http://www.monkey-x.com/")
		wrapperScriptElement.innerHTML = WrapperScript()
		document.body.appendChild(wrapperScriptElement)
		
		Instance().Do()
	End
	
	Function Free:Void()
		Instance().Clear()
	End
	
	Function ThreadActive:Bool()
		Return MonkeyWindowIsActive = 0
	End
End
#Else
Class UpdateThread
	Function Initialize:Void()
	End
	
	Method Free:Void()
	End
	
	Function ThreadActive:Bool()
		Return False
	End
End
#End

Use in Main() the function UpdateThread.Initialize()