Apache helper

Monkey Targets Forums/HTML5/Apache helper

Suco-X

(Posted 2011) [#1]

Hi Guys.

If you want to use the Apache server (Which supports PHP) for Ajax things, take a look at my post.

The Problem: Marks Mini-Server doesn´t support PHP (because he´s not god) and if you want to work with PHP and Apache, you have to copy your project into your local htdocs folder and you have to Copy the http://localhost/... Url into your browser. Everytime if you want to execute your Monkey Program. Hard thing, I know, but here´s the solution.

Starting BlitzMax, execute the following code:

Strict

Const filename_config:String = "config.apache.txt"
Const dirname_build:String   = "monkey_build"

Global path_apache:String, path_project:String


Try
   CheckArgs()
   ReadConfig()
   Run()
Catch error:String
   Throw "Apache Server: "+error
EndTry
   
End


Function CheckArgs()
   If AppArgs.length<2 Throw "Wrong size of AppArgs array"
   
   path_project = ExtractDir(AppArgs[1])
   
   If Not path_project Throw "Couldn´t find path of the monkey project you want to execute"
End Function


Function ReadConfig()
   Local stream_config:TStream
   
   If FileType(filename_config)<>FILETYPE_FILE Throw "Config file "+filename_config+" doesn´t exists"
   
   stream_config = ReadFile(filename_config)
   
   If Not stream_config Throw "Failed to open config file "+filename_config
   
   path_apache = stream_config.ReadLine()
   
   If Not path_apache Throw "Couldn´t read apache path from config file "+filename_config
   
   stream_config.close()
End Function


Function Run()
   Local path_dst:String
   
   path_dst = path_apache+dirname_build
   
   If FileType(path_dst)=FILETYPE_DIR
      If Not DeleteDir(path_dst, True) Throw "Couldn´t cleanup "+path_dst
   EndIf
   
   If Not CreateDir(path_dst) Throw "Couldn´t create "+path_dst
   
   If Not CopyDir(path_project, path_dst) Throw "Couldn´t copy files from "+path_project+" to "+path_dst
   
   OpenURL "http://localhost/"+dirname_build+"/MonkeyGame.html"
End Function

or use this exe file [url=http://www.blitzforum.de/upload/file.php?id=10754[/url]

Name this file apache_helper.exe and copy it to your monkey/bin folder. Same folder within Mini-Server exists.
Create in the same folder the file config.apache.txt and add one line to your htdocs folder. In my case and as an example for the path, C:\xampp\htdocs\ .
Then open config.winnt.txt and change HTML_PLAYER="${TRANSDIR}\mserver_winnt.exe" to HTML_PLAYER="${TRANSDIR}\apache_helper.exe". Now start your Apache Server and everytime you execute a monkey program, apache_helper will copy the files into your htdocs folder and execute it. If you work with php scripts, please create them in the data folder and use it with data/phpscript.php.

Mf Suco

Difference

(Posted 2011) [#2]

Suco-X just told me he made this, but heres my take on the same thing:

SuperStrict

' **********************************************************
'     monkeylauch v 1.0  by Difference  , 2011.09.13
'     For launching your html or flash monkey project in a local webserver 
'     
'     USAGE:
'     in monekeyconfic write something like:
'     HTML_PLAYER=open -n "/Applications/monkeylauch.app" --args "/Users/yourname/Sites/monkeyrun/" "http://localhost/myfolder/"
'
'     and/or
'
'     FLASH_PLAYER=open -n "/Applications/monkeylauch.app" --args "/Users/yourname/Sites/monkeyrun/" "http://localhost/myfolder/"
'
'     the two last args are actual folder, and your webserver path
'
' **********************************************************

Local filename:String = AppArgs[AppArgs.Length-1]
Local launchpath:String = AppArgs[2]
Local destdir:String = AppArgs[1]

If filename <> launchpath
	
	Local sourcedir:String = ExtractDir(filename) + "/"
	Local filename:String = StripDir(filename)
	CopyDir (sourcedir, destdir)
	OpenURL launchpath + filename
Else
	Notify "Please set url and destination in config txt"
EndIf