WIP: Spaced!

Monkey Archive Forums/Monkey Projects/WIP: Spaced!

degac

(Posted 2011) [#1]

This is a little game I'm writing to understand monkey.
Here you can play the latest HTML5 version
Here my first attempt to port it on an Android device.

Of course is still a WIP, some thing doesnt' work (ie: shield)

Some notes on Android version:
- when you exit the application, the monkey game is still running in background: please close it manually - at the moment I've not implemented any 'exit' system
- about the FPS:
WITHOUT 'touch/accel' controls enabled I get 119/120 fps
WITH 'touch/accel' controls enabled I get 79/80 fps (and some jerky movements...)
- there are NO SOUNDs AT ALL (in any version)

Enjoy!

therevills

(Posted 2011) [#2]

Hi degac, just tried your Spaced game on my droid.

How is your FPS calculated? There seems to be a slight skipping happening with the movement of the sprites without touching the screen.

Oh BTW if you want your app to be full screen and locked to landscape, just change your manifest:

<activity android:name="MonkeyGame"
          android:label="@string/app_name"
          android:screenOrientation="landscape"
          android:theme= "@android:style/Theme.NoTitleBar.Fullscreen">

degac

(Posted 2011) [#3]

This is the source code

#rem
	Spaced - monkey
	
	(c) degac - degasperi christian
	www.graphio.net
	www.graphioware.com
	date: 05 mar 2011

	version: 0.01

#end
Strict
Import mojo
Global dt:DeltaTimer

Global myapp:Tgame
Global SCREEN_WIDTH:Int
Global SCREEN_HEIGHT:Int
Global FIRE_TIME:Int=300
Global UPDATE_TIMER:Int
Global BONUS_TIMER:Int

Global MAX_ALIEN:Int=10
Global KILLED_ALIEN:Int=0
Global SCORE:Int=0
Global LEVEL:Float=1
Global SIZE_X:Int=3,SIZE_Y:Int=3
Const GAME_RUN:Int=1
Const GAME_DEAD:Int=2
Const GAME_MENU:Int=3
Const GAME_GAMEOVER:Int=4

Const WEAPON_NORMAL:Int=1
Const WEAPON_DOUBLE:Int=2
Const WEAPON_TRIPLE:Int=3
Global WEAPON_RECHARGE:Int=-1
Global SHIELD:Int=-1
Global WEAPON_TYPE:Int=WEAPON_NORMAL
Global BONUS_COUNT:Int=0

Global image_bonus:Image
Global image_block:Image


Const TEMP_AVG:Int = 10
Const VERSION:String="0.3"

Global GAME_STATUS:Int

Function Main:Int()
	myapp=New Tgame()
	Return 0	
End


Class Sprite
	Field dead:Int
	Field x#,y#
	Field dx#, dy#
	Field speedX#, speedY#
	Field maxXSpeed#, maxYSpeed#
	Field image:Image
	Field scaleX# = 1, scaleY# = 1
	Field currentframe:Int
	Field rotation#
	Field red%, green%, blue%
	Field w%, h%
	Field w2%, h2%
	Field score%
	Field alpha:Float=1.0
	Field energy:Int=100
	Field frameTimer:Int,frameMax:Int,frameMin:Int,frameSpeed:Int=125
	Field d_rot:Float,d_scale:Float=0.1
	Field scaled:Int,lifeTime:Int,timer:Int
	Field fireTimer:Int,fireFreq:Int
	
	
	Method New(img:Image,x#, y#,frame:Int=0)
		Self.image = img
		Self.x = x
		Self.y = y
		Self.w = img.Width()
		Self.h = img.Height()
		Self.w2 = Self.w/2
		Self.h2 = Self.h/2
		Self.currentframe=frame
	End
	
	Method SetFrame:Void(_min:Int=0,_max:Int=0,_speed:Int=125)
		frameMin=_min
		frameMax=_max
		frameSpeed=_speed
		frameTimer=Millisecs()
	End
	
	
	Method setRGB:Void(r%,g%,b%)
		Self.red = r
		Self.green = g
		Self.blue = b
	End
	
	Method move:Void()
		Self.x+=Self.dx * dt.delta
		Self.y+=Self.dy * dt.delta
	End
	
	Method draw:Void()
		SetAlpha alpha
		DrawImage(image, x, y, rotation, scaleX, scaleY,currentframe)
		SetColor 255, 255, 255
		SetAlpha 1.0
	End
	
	Method UpdateAnimation:Void()
		If Millisecs()>frameTimer+frameSpeed
			currentframe+=1
			If currentframe>frameMax currentframe=frameMin			
			frameTimer=Millisecs()
		End	
		
		rotation+=d_rot
		If scaled=1
			scaleX+=d_scale
			scaleY+=d_scale		
		End 
		
	End
	
End


Class DeltaTimer
	Field targetfps:Float = 60
	Field currentticks:Float
	Field lastticks:Float
	Field frametime:Float
	Field delta:Float
	Field average:Float [TEMP_AVG]

	
	Method New (fps:Float)
		targetfps = fps
		lastticks = Millisecs()
	End
	
	Method UpdateDelta:Int()
		currentticks = Millisecs()
		frametime = currentticks - lastticks
		
		Local total:Float
		
		For Local loop:Int = 1 Until TEMP_AVG
			average [loop - 1] = average [loop]
			total = total + average [loop - 1]
		Next
		
		average [TEMP_AVG - 1] = currentticks - lastticks
		total = total + average [TEMP_AVG - 1]
		
		frametime = total / Float (TEMP_AVG - 1)
		
		delta = frametime / (1000.0 / targetfps)

		lastticks = currentticks
		Return 0
	End

	
End

Class Tbonus
	Field sprite:Sprite
	Field tipo:Int,dead:Int
	Field x:Float,y:Float
	
	
	Method New(t:Int,x:Float,y:Float)
		Self.tipo=t
		Self.sprite=New Sprite(image_block,x,y)
		Self.sprite.SetFrame(0,3)
		Self.sprite.dy=2
	End

	Method draw:Int()
		sprite.y+=sprite.dy*dt.delta
		sprite.UpdateAnimation()
		sprite.draw()
		DrawImage image_bonus,sprite.x,sprite.y,tipo		
		Return 0
	End 
End


Class Tgame Extends App

	Field player:Sprite
	Field game_timer:Int
	Field list_aliens:List<Sprite>=New List<Sprite>
	Field list_bullets:List<Sprite>=New List<Sprite>
	Field list_explosions:List<Sprite>=New List<Sprite>
	Field list_fires:List<Sprite>=New List<Sprite>
	Field list_bonus:=New List<Tbonus>
	
	Field bullet_timer:Int
	Field logo:Image
	Field bg:Image
	Field ix:Float,iy:Float
	
	Field image_alien:Image
	Field image_player:Image
	Field image_bullet:Image
	Field image_explosion:Image
	Field image_fire:Image
	
	
	Global FPS:Int = 60
	Field fpsCount:Int
	Field startTime:Int
	Field totalFPS:Int
	
	Method countFPS:Void()
		If Millisecs()>startTime+1000
			totalFPS = fpsCount
			fpsCount = 0
			startTime = Millisecs()
		Endif
		fpsCount+=1		
	End Method

	
	Method OnCreate:Int()
		
		SCREEN_WIDTH = DeviceWidth()
		SCREEN_HEIGHT = DeviceHeight()
		
		Seed = Millisecs()
		dt = New DeltaTimer (FPS)

		image_block=LoadImage("block.png",4)
		image_bonus=LoadImage("bonus.png",4)
		
		logo=LoadImage("monkey_logo.png")
		bg=LoadImage("bg1.png")
		
		'create player
	
		image_player=LoadImage("ship.png",5)
		image_alien=LoadImage("alien1.png",8)
		image_bullet=LoadImage("bullet1.png",2)
		image_explosion=LoadImage("fx_bomb.png",64,64,16)
		image_fire=LoadImage("alien_fire.png",8,16,4)
		
		player=New Sprite(image_player,SCREEN_WIDTH/2-10,SCREEN_HEIGHT-64)

		player.SetFrame(0,4)

		'create aliens
	'	CreateAlien()
		SetFont(LoadImage("font_16.png",16,16,64))
		SetUpdateRate FPS
		startTime=Millisecs()
		GAME_STATUS=GAME_MENU
	Return 0
	End
	
	Method OnUpdate:Int()
	
		Select GAME_STATUS
		
			Case GAME_RUN
					countFPS()
					dt.UpdateDelta
					controls()
					
					If Millisecs()>BONUS_TIMER+10000
						Local bn:=New Tbonus(Int(Rnd(0,4)),Rnd(10,SCREEN_WIDTH-64),-32)
						list_bonus.AddLast(bn)
						BONUS_TIMER=Millisecs()
					End 

					
			Case GAME_DEAD
					countFPS()
					dt.UpdateDelta()
					
					
			Case GAME_MENU,GAME_GAMEOVER
			
				If MouseHit(MOUSE_LEFT) Or KeyHit(KEY_SPACE)
					GAME_STATUS=GAME_RUN
					SCORE=0
					MAX_ALIEN=10
					KILLED_ALIEN=0
					LEVEL=1
					Print "Start game..."
					list_explosions.Clear()
					list_bullets.Clear()
					list_fires.Clear()
					list_aliens.Clear()
					CreateAlien()

				End If
			
		End Select
	
		Return 0

	End
	
	
	Method OnRender:Int()
		'Cls
	'	If Millisecs()>UPDATE_TIMER+16

		Select GAME_STATUS
		Case GAME_RUN,GAME_DEAD
				
		PushMatrix()

		Translate DeviceWidth() * 0.5, DeviceHeight() * 0.5 'Thanks BlitzSupport:)
	'	Scale scale_width,scale_hieght
		Translate -DeviceWidth() * 0.5, -DeviceHeight() * 0.5' ""

		ix=ix+1.5*dt.delta
		iy=iy+1*dt.delta

		Tile_Image(bg,ix,iy,128,128,1,1)
		PopMatrix()

		'CONTROL OF BONUS
			
			If WEAPON_RECHARGE>0
				
				FIRE_TIME=50
				WEAPON_RECHARGE-=1
				SetColor 200,200,200
				DrawRect SCREEN_WIDTH-100,5,100,10
				SetColor 200,20,20
				Local lvl:Float=Float(WEAPON_RECHARGE)/1000
				DrawRect SCREEN_WIDTH-99,6,lvl*100,7
				DrawImage image_bonus,SCREEN_WIDTH-133,0,2

			Else
				FIRE_TIME=300
				BONUS_COUNT-=1
			End If
			
			If SHIELD>0
				SHIELD-=1
				SetColor 200,200,200
				DrawRect SCREEN_WIDTH-233,5,100,10
				SetColor 200,20,20
				Local lvl:Float=Float(SHIELD)/1000
				DrawRect SCREEN_WIDTH-233,6,lvl*100,7
				DrawImage image_bonus,SCREEN_WIDTH-266,0,3
			Else
				BONUS_COUNT-=1
			End If
			
			If BONUS_COUNT<0 BONUS_COUNT=0


		'draw bullets
		For Local b:=Eachin list_bullets
			b.UpdateAnimation()
			b.draw()
			b.x+=b.dx*dt.delta
			b.y+=b.dy*dt.delta
			
			If b.y<0
				list_bullets.Remove(b)
				b=Null
			End		
		Next
		'draw aliens
		PushMatrix
		Scale 2,2
		Local af:Sprite
		For Local a:=Eachin list_aliens
		
			If a<>Null
			a.UpdateAnimation()
			a.draw()
			a.x+=a.dx*dt.delta
			
			If Millisecs()>a.fireTimer+a.fireFreq
				
				af=New Sprite(image_fire,a.x*2+5,a.y*2)
				af.SetFrame(Int(Rnd(0,3)),3)
				af.dy=2
				list_fires.AddLast(af)
				
				If LEVEL>9 And Rnd(1,6)>4
						af.dy=1
						af=New Sprite(image_fire,a.x*2,a.y*2)
						af.SetFrame(Int(Rnd(0,3)),3)
						af.dx=0.15
						af.dy=1
						list_fires.AddLast(af)
						af=New Sprite(image_fire,a.x*2+5,a.y*2)
						af.SetFrame(Int(Rnd(0,3)),3)
						af.dx=-0.15
						af.dy=1
						list_fires.AddLast(af)
						'Print "Triple fire!"
						Seed=Millisecs()
						a.fireFreq=1000
				End 
				a.fireTimer=Millisecs()

			End
			
					
			If a.x>SCREEN_WIDTH/2 a.x=-32
			If a.x<-32 And a.dx<0 a.x=SCREEN_WIDTH/2
			
			For Local b1:=Eachin list_bullets
				If b1<>Null And a<>Null
					If rectsOverlap(a.x*2,a.y*2,32,32,b1.x,b1.y,5,16)
					list_aliens.Remove(a)
					list_bullets.Remove(b1)
					SCORE+=100
					
					Local ex:Sprite=New Sprite(image_explosion,a.x*2-52,a.y*2-52)
					
					ex.SetFrame(0,15,80)
					ex.timer=Millisecs()
					ex.lifeTime=1000
					ex.scaleX=2
					ex.scaleY=2
					list_explosions.AddLast(ex)					
					
					a=Null
					b1=Null
					
					If list_aliens.Count()=0
						MAX_ALIEN+=2
						LEVEL+=1
						CreateAlien()
					End
				End If
			End 
		
			Next
			End  If
		Next
		PopMatrix

		'update enemy fire
		For Local f:=Eachin list_fires
			If f<>Null
				f.y+=f.dy*dt.delta
				f.x+=f.dx*dt.delta
				
				f.UpdateAnimation()
				f.draw()
			
				If rectsOverlap(player.x,player.y,20,23,f.x,f.y,5,16)
					list_fires.Remove(f)
					f=Null
					Local ex:Sprite=New Sprite(image_explosion,player.x-52,player.y-51)
					ex.SetFrame(0,15,80)
					ex.timer=Millisecs()
					ex.lifeTime=1000
					ex.scaleX=2
					ex.scaleY=2
					list_explosions.AddLast(ex)					
					GAME_STATUS=GAME_DEAD
					game_timer=Millisecs()
				End If
				If f<>Null
					If f.y>SCREEN_HEIGHT
						list_fires.Remove(f)
						f=Null
					End If
				End If
			End If
		Next		
		
		'draw bonus
		
		For Local bn:=Eachin list_bonus
				If bn<>Null
					bn.draw()
					
					'If rectsOverlap(bn.x,bn.y,32,32,player.x,player.y,20,23)
					If rectsOverlap(player.x,player.y,20,23,bn.sprite.x,bn.sprite.y,32,32)	
						Select bn.tipo
							Case 0	'double
								WEAPON_TYPE=WEAPON_DOUBLE
							Case 1	'triple
								WEAPON_TYPE=WEAPON_TRIPLE
							Case 2	'rapid fire
								If WEAPON_RECHARGE<=0
								WEAPON_RECHARGE=1000				
								BONUS_COUNT+=1
								End If
							Case 3	'shield
								If SHIELD<=0
								SHIELD=1000
								BONUS_COUNT+=1
								End If
							Default
									'normal fire
								WEAPON_TYPE=WEAPON_NORMAL
						End Select
					Print "BOnus Count. "+BONUS_COUNT
					list_bonus.Remove(bn)
					bn.dead=1
					End 
					If bn.sprite.y>SCREEN_HEIGHT
						list_bonus.Remove(bn)
						bn.dead=1
					End
					
					If bn.dead=1 bn=Null
				End If
		Next
		
		'update explosion
		
		For Local e:=Eachin list_explosions
			If e<>Null
				PushMatrix
				e.UpdateAnimation()
				e.draw()
				e.alpha-=Float(1.0)/e.lifeTime*20
				
				If e.alpha<0 e.alpha=0
				PopMatrix
			
				If Millisecs()>e.timer+e.lifeTime
					list_explosions.Remove(e)
					e=Null
					'Print "Stop explosion"
				End
			End If
		Next
		
		player.UpdateAnimation()
		player.draw()
	
		DrawImage logo,SCREEN_WIDTH-48,SCREEN_HEIGHT-48

		DrawText "SCORE:"+Pad(String(SCORE),7),0,SCREEN_HEIGHT-32
		DrawText "LEVEL:"+Pad(String(LEVEL),3),250,SCREEN_HEIGHT-32
		DrawText "FPS : "+totalFPS,0,0

		If GAME_STATUS=GAME_DEAD And Millisecs()>game_timer+2000
			GAME_STATUS=GAME_GAMEOVER
		End If
		
		Case GAME_MENU
			Cls
			PushMatrix()
			Scale 2,2
'			DrawCenterText "SPACED!",100,80,1
			DrawText "SPACED!",SCREEN_WIDTH/4,80,.5
			PopMatrix()
			Scale 1,1
			'DrawCenterText "PRESS MOUSE LEFT To START",80,400,1
			DrawText "PRESS MOUSE LEFT OR SPACE TO START",SCREEN_WIDTH/2,400,.5

			DrawText "CURSOR KEYS TO MOVE",SCREEN_WIDTH/2,300,.5
			DrawText "SPACE TO FIRE",SCREEN_WIDTH/2,340,.5
			DrawText "VERSION "+VERSION,0,0
			
			DrawImage logo,SCREEN_WIDTH-48,SCREEN_HEIGHT-48

		
		Case GAME_GAMEOVER
			PushMatrix()
			Translate DeviceWidth() * 0.5, DeviceHeight() * 0.5
			Translate -DeviceWidth() * 0.5, -DeviceHeight() * 0.5
			ix=ix+1.5*dt.delta
			iy=iy+1*dt.delta
			Tile_Image(bg,ix,iy,128,128,1,1)
			Scale 2,2
			
			DrawText "G A M E",SCREEN_WIDTH/4,50,.5
			DrawText "O V E R",SCREEN_WIDTH/4,100,.5
			

			

			
			PopMatrix()
			Scale 1,1
		
			DrawText "PRESS MOUSE LEFT OR SPACE TO START",SCREEN_WIDTH/2,400,.5
			DrawImage logo,SCREEN_WIDTH-48,SCREEN_HEIGHT-48

					
				
		End Select
		
	'	UPDATE_TIMER=Millisecs()
	'	End If
		
	Return 0
	End 
	
	
Function Tile_Image:Int(img:Image,x#,y#,ih:Int,iw:Int,scalex#,scaley#)
'Based in part on - <a href="http://www.blitzbasic.com/codearcs/codearcs.php?code=1842" target="_blank">http://www.blitzbasic.com/codearcs/codearcs.php?code=1842</a> 
	Local w#=iw * scalex
	Local h#=ih * scaley

	Local scissor:Float[]
	scissor=GetScissor()
	Local viewport_x:Float=scissor[0]
	Local viewport_y:Float=scissor[1]
	Local viewport_w:Float=scissor[2]
	Local viewport_h:Float=scissor[3]
	
	Local ox#=viewport_x-w+1
	Local oy#=viewport_y-h+1

    Local px#=x
    Local py#=y

    Local fx#=px-Floor(px)
    Local fy#=py-Floor(py)
    Local tx#=Floor(px)-ox
    Local ty#=Floor(py)-oy

    If tx>=0 tx=tx Mod w + ox Else tx = w - -tx Mod w + ox
    If ty>=0 ty=ty Mod h + oy Else ty = h - -ty Mod h + oy

    Local vr#= viewport_x + viewport_w, vb# = viewport_y + viewport_h

	Local iy#=ty
	While iy<(vb + h) 
        Local ix#=tx
        While ix<(vr + w) 
            DrawImage(img,ix+fx,iy+fy)
            ix=ix+w
        Wend
        iy=iy+h
    Wend

Return 0
End Function

	Function Pad:String(val:String,npad:Int=5)
		val="                    "+val
		Return val[val.Length()-npad..]
	End Function
	
	
	Method controls:Void()
	
	Local fired:Int=0
	
	#If TARGET="android" Then
			player.x += (AccelY() * 2) * dt.delta
			If player.x<0 player.x=0
			If player.x>SCREEN_WIDTH-20 player.x=SCREEN_WIDTH-20
	#Endif

	
	#If TARGET="android" Then
		If TouchDown(0) And Millisecs()>bullet_timer+FIRE_TIME fired=1

	#else
		If KeyHit(KEY_SPACE) And Millisecs()>bullet_timer+FIRE_TIME fired=1
	#endif
		If fired=1
			Select WEAPON_TYPE
			
			Case WEAPON_NORMAL
					Local b:Sprite=New Sprite(image_bullet,player.x+5,player.y-5)
					b.dx=0
					b.dy=-2
					b.SetFrame(0,1,125)
					
					list_bullets.AddLast b
					bullet_timer=Millisecs()
					
			Case WEAPON_DOUBLE
					Local b:Sprite
					b=New Sprite(image_bullet,player.x+0,player.y-5)
					b.dx=-.1
					b.dy=-2
					b.SetFrame(0,1,125)
					list_bullets.AddLast b
			
					b=New Sprite(image_bullet,player.x+10,player.y-5)
					b.dx=0.1
					b.dy=-2
					b.SetFrame(0,1,125)
					list_bullets.AddLast b
										
					bullet_timer=Millisecs()
		
			
			Case WEAPON_TRIPLE
					Local b:Sprite
					b=New Sprite(image_bullet,player.x+5,player.y-5)
					b.dx=0
					b.dy=-3
					b.SetFrame(0,1,125)
					list_bullets.AddLast b
			
					b=New Sprite(image_bullet,player.x+5,player.y-5)
					b.dx=0.4
					b.dy=-3
					b.SetFrame(0,1,125)
					list_bullets.AddLast b
			
					b=New Sprite(image_bullet,player.x+5,player.y-5)
					b.dx=-.4
					b.dy=-3
					b.SetFrame(0,1,125)
					list_bullets.AddLast b
										
					bullet_timer=Millisecs()
			End Select
		
		End
		
		If KeyDown(KEY_LEFT)
			player.x-=2*dt.delta
			If player.x<0 player.x=0
		End
		
		If KeyDown(KEY_RIGHT)
			player.x+=2*dt.delta
			If player.x>SCREEN_WIDTH-20 player.x=SCREEN_WIDTH-20

		End
		

	End
	
Method CreateAlien:Void()
	
		Local al:Sprite
		Local _x:Int
		Local _y:Int
		Local _f:Int
	'	Print "Create aliens..."
		
		If Int(LEVEL/2)=Float(LEVEL/2)
			_x=40
			_y=30
			MAX_ALIEN=0
			
			SIZE_X=LEVEL*1.5+1
			SIZE_Y=SIZE_X
			If SIZE_Y>=5 Then SIZE_Y=5
			If SIZE_X>=8 Then SIZE_X=8
			
			Local _dx:Float=Sgn(Rnd(-1,1))
			For Local x:Int=1 To SIZE_Y
			For Local y:Int=1 To SIZE_X
				_f=Rnd(0,7)
			
				al=New Sprite(image_alien,_x,_y,_f)
				al.SetFrame(_f,7)
				al.dx=_dx
				list_aliens.AddLast(al)
				al.fireFreq=Rnd(1,10)*(1500)
				al.fireTimer=Millisecs()
				_x+=48
				MAX_ALIEN+=1
			Next
			_x=40
			If LEVEL>8 And Rnd(1,5)>2 _dx=-1*_dx
			_y+=18
			Next	
			'Print "Totale Alien: "+MAX_ALIEN
		Else
		MAX_ALIEN=5+LEVEL*2
		'Print "Totale Alieni: "+MAX_ALIEN
		For Local i:Int=1 To MAX_ALIEN
			_x=Rnd(10,SCREEN_WIDTH-128)
			_y=Rnd(10,SCREEN_HEIGHT/2-100)
			_f=Rnd(0,7)

			al=New Sprite(image_alien,_x,_y,_f)	
			al.SetFrame(_f,7)
			al.dx=Rnd(-1,1)*Rnd(1.2,1.5)
			If al.dx=0 al.dx=1
			If Abs(al.dx)<0.1 al.dx=1
			list_aliens.AddLast(al)
			
			al.fireFreq=Rnd(1,10)*(1500-(MAX_ALIEN)*50)
			If al.fireFreq<800 al.fireFreq=1500+Rnd(500,1500)
			al.fireTimer=Millisecs()
			
			'Print "Alien "+al.fireFreq
		Next
		End If
End 

Function DrawBox:Void(x0:Float,y0:Float,w:Float,h:Float)
	DrawLine x0,y0,x0+w,y0
	DrawLine x0,y0,x0,y0+h
	DrawLine x0+w,y0,x0+w,y0+h
End Function

Function rectsOverlap:Int(x0:Float, y0:Float, w0:Float, h0:Float, x2:Float, y2:Float, w2:Float, h2:Float)
	If x0 > (x2 + w2) Or (x0 + w0) < x2 Then Return False
	If y0 > (y2 + h2) Or (y0 + h0) < y2 Then Return False
	Return True
End Function

End

by the way I think I used your method (grabbed from Pong...)

	Method countFPS:Void()
		If Millisecs()>startTime+1000
			totalFPS = fpsCount
			fpsCount = 0
			startTime = Millisecs()
		Endif
		fpsCount+=1		
	End Method

and a little change in the DeltaTimer method: see Rockout example for the 'average thing'

Thank for the manifest file: I really need it!

therevills

(Posted 2011) [#4]

Thanks - Ill have a good look tonight. Looks a lot like my code :P