need help with rotating stuff

Monkey Forums/Monkey Programming/need help with rotating stuff

Duke87

(Posted 2015) [#1]

Hey Monks,

I got a little Problem over here.

I have a "GetMouseOverBox" (X,Y are Midhandled like my Images, so I can rotate them easily) Function like :

Function MOBox:Bool(_X:Float, _Y:Float, _Width:Float, _Height:Float)
	If (_X-_Width/2.0) < MouseX() And _X + _Width/2.0 > MouseX() And (_Y-_Height/2.0) < MouseY() And (_Y + _Height/2.0) > MouseY()
		Return True
	Else
		Return False
	Endif
End Function

And now I let them Rotate within the OnRender like:

...
RotateAt(X,Y,Angle)
DrawImage MyImg, X,Y,0,pxlX/MyImg.Width(),pxlY/MyImg.Height()
ResetMatrix()

So far, so fine.

But when i want to check for a 'MouseOver' within the OnUpdate like:

...
if MOBox(X,Y,Width,Height)
...

RotateAt(X,Y, Angle)
If MOBox(X,Y,Width,Height)
...
ResetMatrix()

it both uses the 'unrotated' rect of my MOBox() function

How do i Check for a Mouseover within a rotated rectangle?

If needed my Rotate-func.

Function RotateAt:Void(x:Float, y:Float, angle:Float)
    Translate(x, y)
    Rotate(angle)
    Translate(-x, -y)
End
Function ResetMatrix:Void()
    SetMatrix(1,0,0,1,0,0)
End

Midimaster

(Posted 2015) [#2]

This sample shows, that a rotation command does not affect the mouse coordinates:

Strict
Import mojo


Class Game Extends App

	Global X%
	
	Method OnCreate%()
		SetUpdateRate 10
		Return 0
	End	

	Method OnUpdate%()
		If KeyHit(KEY_ESCAPE) OnBack()
		Return 0
	End	

	Method OnRender%()
		Cls
		Translate 200,200
		Rotate X
		X=X+1
		Scale 2,2
		DrawText TouchX(),30,30
		Return 0
	End	
	
	
	Method OnBack%()
		EndApp()
		Return 0
	End	
End

Function Main%()
	New Game
	Return 0
End

You have to invent a GetMouseOverBox() function which calculates the true rectangle of the rotated box. GetMatrix() will help you finding aut the current rotation angle. Sin() and Cos() will be need to calculate the borders.

MikeHart

(Posted 2015) [#3]

This is my method inside fE for checking if a touch is inside a rotated box. You should easily be able to adapt it:


		Method internal_PointInsidePolygon:Bool(sp:ftObject, px:Float, py:Float)

			Local cx:Float,cy:Float
			Local SinVal:Float, CosVal:Float
			Local t:Float, b:Float, l:Float, r:Float
			Local hys:Float, wxs:Float

			SinVal = Sin(-sp.angle)
			CosVal = Cos(-sp.angle)

			cx = px - sp.xPos
			cy = py - sp.yPos
	
			px =(cx*CosVal) - (cy*SinVal) + sp.xPos
			py =(cy*CosVal) + (cx*SinVal) + sp.yPos
			
			wxs = sp.w*sp.scaleX * sp.collScale
			hys = sp.h*sp.scaleY * sp.collScale
			


			l =  sp.xPos + sp.hOffX - (wxs/2.0)
			r =  l + wxs


			t =  sp.yPos + sp.hOffY - (hys/2.0)
			b += t + hys
			
			If px < l Or px > r Or py < t Or py > b Then Return False
			Return True
	   End

Duke87

(Posted 2015) [#4]

Thank you,

will have a look at this.