SetChannelPan

Monkey Forums/Monkey Programming/SetChannelPan

cgrossi

(Posted 2015) [#1]

Hello!

Does the command SetChannelPan work? I've downloaded the 83a version and I can't make it pan right or left, like BlitzMax. Does anyone know why?

MikeHart

(Posted 2015) [#2]

Which target platform? Which value do you use for left and right?

cgrossi

(Posted 2015) [#3]

So far for Desktop, the values are -1 and 1, acording to the documentation...

MikeHart

(Posted 2015) [#4]

On GLFW and HTML it works here like I would expect it. Running OSX 10.8.5.

cgrossi

(Posted 2015) [#5]

ok, I'm not using OSX. instead, I'm using Windows 7. on blitzmax it works fine....

MikeHart

(Posted 2015) [#6]

Are you sure you are setting the channels correctly?

MikeHart

(Posted 2015) [#7]

Tested on Win7 too, it works.

cgrossi

(Posted 2015) [#8]

I think so... Here is it, it's just a test code, to learn the language.

Import mojo
Import mojo.app

Class Point
    Field x#
    Field y#
End

Global points:=New List<Point>
Global image:Image

Global fullscreen:Bool=False

Class Game Extends App

	Field t:teste
	Field som:Sound

	Function AddPoint(x#,y#)
	    Local p:Point=New Point
	    p.x=x
	    p.y=y
		points.AddFirst p
	End

    Method OnCreate()
    	t=New teste
        SetUpdateRate 30
        image=LoadImage("monkey64.png")
        image.SetHandle image.Width/2,image.Height/2
        som=LoadSound("som.ogg")
        SetChannelVolume 1,1
        SetChannelPan 1,-1
        SetDeviceWindow(800,600, False)
    End

    Method OnUpdate()
        If MouseX()>=100 And MouseX()<=500 And MouseY()>=50 And MouseY()<=450
        	If MouseHit() Then 
        		PlaySound som,1
        	Endif 
	        If MouseHit(MOUSE_LEFT) Then AddPoint MouseX,MouseY
	        If MouseHit(MOUSE_MIDDLE) Then points.RemoveFirst
	        If MouseHit(MOUSE_RIGHT) Then 
	        	For Local p:Point=Eachin points
	        		points.RemoveEach p
	        	Next
	        Endif
		Endif
	    #If TARGET="glfw" Then
		    If KeyHit(KEY_F11) Then
		    	fullscreen=Not fullscreen
				SetDeviceWindow(800,600,fullscreen)
				ShowMouse()
		    Endif
		#Endif
		
	    If KeyHit(KEY_ESCAPE) Then EndApp
		
    End

    Method OnRender()
        Cls
        SetScissor 0,0,DeviceWidth,DeviceHeight
        SetAlpha 1
        SetColor 130,130,130
        DrawRect 0,0,DeviceWidth,DeviceHeight
        SetColor 255,0,0
        DrawText "Teste",10,10
        DrawText t.Calcula,10,100
        
    	SetScissor 100,50,400,400
    	SetColor 50,50,50
    	DrawRect 0,0,DeviceWidth,DeviceHeight
        SetColor 255,255,255
        SetAlpha .5
        For Local point:=Eachin points
            DrawImage image,point.x,point.y
        Next
        
        SetScissor 0,0,DeviceWidth,DeviceHeight
        
    End

End

Function Main()

	Seed=Millisecs()

    New Game()
End

Class teste

	Public Field a,b,c,d
	Method New()
		a=Millisecs()
		b=Int(Rnd(1,10))-1
		c=3
		d=4
	End Method
	
	Method Calcula:String()
		Return b
	End Method
End Class

cgrossi

(Posted 2015) [#9]

That's strange... How is your code?

MikeHart

(Posted 2015) [#10]

I just placed this in the autotest example after the SetUpdateRate(15) command:

		SetChannelPan(0,-1)
		SetChannelPan(1,0)
		SetChannelPan(2,1)

And then I press 2 all the time so you hear the effect,

dawlane

(Posted 2015) [#11]

Is the file you are playing stereo? Stereo files should play equally out of the left and right speakers no matter what you set the panning to. Only mono files would play correctly.

If I remember OpenAL does not support the pan left/right as it is a 3D Sound API. As in real life a sound close to you on the left will be louder on the left than the right. You would still hear the sound through the right. If the sound was far away, then you would hear the sound equally through the left and right.

Google Panning in OpenAL you will see there have been a number of questions asked.

Use the code below and one of the compatible target shoot audio file formats from the examples. And then try your own audio file.

Strict

Import mojo

Class CGame Extends App
	Field audio:Sound
	Field panning:Float = 0
	Field slide:Float = -.1
	Field lasttick:Int
	Field time:Int = 1000*.4775 ' Change panning every 477 miliseconds which is the closest length to the shoot sound being played
	
	Method OnCreate:Int()
		SetUpdateRate(30)
		audio = LoadSound("shoot.ogg")
		SetChannelPan(1,panning)	' Important: Set the initial start
		SetChannelVolume(1,.5)
		PlaySound(audio,1,1)
		lasttick = Millisecs()
		Return 0
	End Method
	
	Method OnUpdate:Int()
		Local time:Int = Millisecs()
		If time > lasttick+Self.time Then
			Print "Local time "+time
			Print "stepping time "+Self.time
			lasttick = time	
			If panning <= -1.0 Or panning >= 1.0 Then slide = -slide		
			panning += slide
			SetChannelPan(1,panning)
		EndIf
		Return 0
	End Method
	
	Method OnRender:Int()
		Cls
		DrawText("Panning: "+panning,0,0)
		DrawText("Slide: "+slide,0,20)
		Return 0
	End Method
End Class

Function Main:Int()
	New CGame
	Return 0
End Function

cgrossi

(Posted 2015) [#12]

Hello.
I turn my audio into mono and it works perfectly. Thank you, dawlane.

Thanks a lot, guys!!

Best regards.

dawlane

(Posted 2015) [#13]

Tips for audio:
Music should be stereo for best results. If there is no difference between left and right channels, then consider using mono to save a bit of memory and disk space. Sound effects should be mono.

Audio format support for web browsers depends on the browser, so expect to have to use the Dom module to try and work out which browser is being used so you can load the correct supported audio file. Also limit the number of sound channels being use to avoid sound issues. Search the forum in the HTML5 targets and in the BUGS section for more.

The MP3 format is not seamless. I don't think looping audio was thought about when that format was drafted, so looping creates a gap. There are tools to remove or limit this gap in play back, but your mileage will vary.

Not all audio formats are supported by the desktop targets. So don't expect to play an wma format on a Linux distribution.

Two tools to check out if you are short on cash.
LMMS is a free cross platform music creation application that is similar to FL Studio.
Audacity is a free audio editing suite like SoundWave, etc. To export audio as MP3 you have to have LAME installed.

cgrossi

(Posted 2015) [#14]

Thanks, dawlane, for the tips.

Regards