Count the number of connected game controllers

Monkey Forums/Monkey Programming/Count the number of connected game controllers

chimaera

(Posted 2014) [#1]

I was wondering if there is any way to find out how many game controllers that are connecrted. JoyX() and the other commands have supports more than one, but I do not know to find out how many are connected.

I am at a game jam, so I would really appreciate fast help! :)

ImmutableOctet(SKNG)

(Posted 2014) [#2]

Unfortunately, I don't think Monkey supports detecting what's plugged in. If I remember right, this was because of an issue with the XNA target. You'll have to set it up manually by either checking for any button, or by checking for specific buttons. Either way, you'll have to log the state of each controller manually. And disconnection would effectively be the same.

But just because Monkey doesn't support it, that doesn't mean GLFW doesn't. So, assuming you're using one of the GLFW targets (Doesn't work with GLFW2; see below for a full example with GLFW2 support), you could do the following:

' Constant variable(s):

' This is just an example, but it technically can go to 16 controllers (Code 15):
Const GLFW_JOYSTICK_1:Int = 0
Const GLFW_JOYSTICK_2:Int = 1
Const GLFW_JOYSTICK_3:Int = 2
Const GLFW_JOYSTICK_4:Int = 3

' External declarations:
Extern

' Functions:

' Name this what you want, this was just an example name.
Function GLFW_JoyPresent:Int(JoyID:Int)="glfwJoystickPresent"

Public

The 'JoyID' argument (Just 'joy' in GLFW) works like 'JoyX', it starts at controller zero. Though, Monkey (To my knowledge) doesn't currently support 16 controllers (Without some hacks), so 1-4 should be fine detection-wise. You might want to stick to those constants for the sake of compatibility. And in-fact, I should have made them globals, and just put them in the external area, but I wanted to show what they were.

And if you really wanted to (And I wasn't lazy), you could use my 'input' module, but that'd require code changes, not to mention myself putting in the work of setting it up on GitHub. If you were to do something like that, you'd get some added features relating to remapping.

ImmutableOctet(SKNG)

(Posted 2014) [#3]

Here's a full example (With proper support for GLFW2):

Strict

Public

' Preprocessor related:

' Reflection related:
' Nothing so far.

' GLFW related:
#GLFW_WINDOW_WIDTH=0
#GLFW_WINDOW_HEIGHT=0

' Imports:
Import mojo

' External declarations:
Extern

#If TARGET = "glfw"
	' Global variable(s):
	
	' General:
	Global GLFW_PRESENT:Int
	
	' Joystick IDs:
	Global GLFW_JOYSTICK_1:Int
	Global GLFW_JOYSTICK_2:Int
	Global GLFW_JOYSTICK_3:Int
	Global GLFW_JOYSTICK_4:Int
	Global GLFW_JOYSTICK_5:Int
	Global GLFW_JOYSTICK_6:Int
	Global GLFW_JOYSTICK_7:Int
	Global GLFW_JOYSTICK_8:Int
	Global GLFW_JOYSTICK_9:Int
	Global GLFW_JOYSTICK_10:Int
	Global GLFW_JOYSTICK_11:Int
	Global GLFW_JOYSTICK_12:Int
	Global GLFW_JOYSTICK_13:Int
	Global GLFW_JOYSTICK_14:Int
	Global GLFW_JOYSTICK_15:Int
	Global GLFW_JOYSTICK_16:Int
	Global GLFW_JOYSTICK_LAST:Int
	
	' Functions:
	#If GLFW_VERSION = 3
		' Name this what you want, this was just an example name.
		Function _GLFW_JoyPresent:Int(JoyID:Int)="glfwJoystickPresent"
	#Else
		Function GLFW_GetJoyParam:Int(JoyID:Int, Param:Int)="glfwGetJoystickParam"
	#End
#End

Public

' Global variable(s):
#If TARGET = "glfw"
	Global GLFW_JOYSTICK_FIRST:= GLFW_JOYSTICK_1
#End

' Functions:
Function JoyPresent:Bool(JoyID:Int)
	#If TARGET = "glfw"
		#If Not GLFW_VERSION Or GLFW_VERSION = 2
			If (GLFW_GetJoyParam(JoyID, GLFW_PRESENT) = 1) Then ' GL_TRUE
				Return True
			Endif
		#Else
			If (_GLFW_JoyPresent(JoyID) = 1) Then ' GL_TRUE
				Return True
			Endif
		#End
	#End
	
	' Return the default response.
	Return False
End

Function JoyCount:Int()
	#If TARGET = "glfw"
		' Local variable(s):
		Local Count:Int = 0
		
		For Local I:= GLFW_JOYSTICK_FIRST To GLFW_JOYSTICK_LAST
			If (JoyPresent(I)) Then
				Count += 1
			Endif
		Next
		
		' Return the calculated number of controllers plugged in.
		Return Count
	#Else
		' Just an optimization, ideally you'd use custom constants for controllers,
		' then do the usual loop with the 'JoyPresent' command.
		Return 0
	#End
End

' Example:
Function Main:Int()
	' Begin a new instance of the test-application.
	New Application()
	
	' Return the default response.
	Return 0
End

' Classes:
Class Application Extends App Final
	' Constructor(s):
	Method OnCreate:Int()
		Print("GLFW_JOYSTICK_FIRST: " + GLFW_JOYSTICK_FIRST)
		Print("GLFW_JOYSTICK_LAST: " + GLFW_JOYSTICK_LAST)
		
		For Local I:= GLFW_JOYSTICK_FIRST To GLFW_JOYSTICK_LAST
			If (JoyPresent(I)) Then
				Print("Joy " + I + "	: True")
			Else
				Print("Joy " + I + "	: False")
			Endif
		Next
		
		Print("Joysticks plugged in: " + JoyCount())
		
		' Close this application.
		OnClose()
		
		' Return the default response.
		Return 0
	End
End

EDIT: Updated the example to be a bit less GLFW specific for the sake of potential code changes.

chimaera

(Posted 2014) [#4]

Thanks for the help!

Unfortunately we didn't have time to add this to our game, but I will check it out and might add it to the "post gamejam" release of the game.