Texture Atlas with TexturePacker

Monkey Forums/Monkey Programming/Texture Atlas with TexturePacker

erebel55

(Posted 2014) [#1]

I searched around the forums and found this thread
http://www.monkey-x.com/Community/posts.php?topic=1216

So, I took the penguin image from there, added it to TexturePacker and set the following settings.

Which generated the following the following penwalker.png file

And the following penwalker.txt file

penwalker.png
format: RGBA8888
filter: Linear,Linear
repeat: none
walker
  rotate: false
  xy: 0, 0
  size: 256, 64
  orig: 256, 64
  offset: 0, 0
  index: -1

From here I created the following from Adam's Another Texture Atlas Loader
textureloader.monkey

Import mojo.app
Import mojo.graphics
Import monkey

'' libgdx sprite sheet loader
'' 
''this is best used in loading all textures, don't create during the game time, as it would create lag

Function LoadAtlas:CTextureAtlas(fn:String)
	Local atlas:CTextureAtlas = New CTextureAtlas
	If Not atlas.LoadTex(fn) Then Return Null
	Return atlas
End

Function LoadAtlas:CTextureAtlas(fn:String[])
	Local atlas:CTextureAtlas = New CTextureAtlas
	Local fconcat$
	
	For Local f$ = Eachin fn
		fconcat += LoadString( f )+"~n"
		
	Next
	If Not atlas.ProcessAtlas(fconcat) Then Return Null
	
	Return atlas
End

Class CTextureAtlas
	Field tmap:StringMap<CSubTextureAtlas> = New StringMap<CSubTextureAtlas>
	Field texture:Image[]
	Field total:Int =0
	Field subimage:CSubTextureAtlas[]

	Method LoadTex:Int(fn:String)
		
		If Not fn Return 0
		Local txtfile:String = fn[..(fn.FindLast("."))]+".txt"
		Local str:String=LoadString(txtfile)
		
		Return ProcessAtlas(str)
		
	End

	Method ProcessAtlas:Int(str:String)
		
		'Print "******BEGIN"
		
		If Not str Then Return 0
		
		texture = New Image[1]
		
		Local all:String[] = str.Split("~n")
		Local textureCount:Int = 0
		
		texture[textureCount] = LoadImage(all[0].Trim(), 1)
		DebugLog("Loading new texture " + all[0].Trim() + " here, index " + textureCount)
		If Not texture Then Return
		
		''count total
		For Local i:Int = 0 To all.Length()-1
			If all[i].Contains("xy:") Then total += 1
		Next
				
		''create sub images
		subimage = New CSubTextureAtlas[total + 1]
		Local si:Int = 0
		Local nextimage:Int = 0
		Local nextfile:Int = 0
		Local xy:String[] =["",""] '= New String[10]
		Local row:String = ""

		For Local i:Int = 4 To all.Length()-1
			Local EOF:Bool = (i=(all.Length()-1))
			
			row = all[i].Trim()
			If row.Contains(":")
			
				If row.Contains("xy")
					xy = row[ (row.FindLast(":")+1)..].Split(",")				
					subimage[si].x = Int(xy[0].Trim())
					subimage[si].y = Int(xy[1].Trim())
				Elseif row.Contains("size")
					xy = row[ (row.FindLast(":") + 1) ..].Split(",")
					subimage[si].w = Int(xy[0].Trim())
					subimage[si].h = Int(xy[1].Trim())
				Elseif row.Contains("offset")
					xy = row[ (row.FindLast(":") + 1) ..].Split(",")
					subimage[si].offsetx = Int(xy[0].Trim())
					subimage[si].offsety = Int(xy[1].Trim())
				Elseif row.Contains("index")
					Local ind:String = row[ (row.FindLast(":") + 1) ..]
					subimage[si].index = Int(ind.Trim() )
				EndIf
				
			Else
				
				If row="" Then
					' blank lines lead to a new texture file
					nextfile = 1
					Continue
				EndIf
				
				If nextfile = 1
					If row.Contains(".")
						' new texture file
						textureCount = textureCount + 1
						DebugLog("Loading new texture " + row + " here, index " + textureCount)
						texture = texture.Resize(texture.Length + 1)
						texture[textureCount] = LoadImage(row, 1)
						nextfile = 0
					Endif
					Continue					
				EndIf
				
				'' nextimage=0 is used for first time through
				If nextimage
					If subimage[si].index >-1 Then subimage[si].file = subimage[si].file+"_"+String(subimage[si].index)
					tmap.Set( (subimage[si].file), subimage[si])
					DebugLog("Added " + subimage[si].file + "~n")
					si += 1
				EndIf

				''start new image
				subimage[si] = New CSubTextureAtlas
				subimage[si].file = row
				subimage[si].page = textureCount ' added to handle pages
				
				nextimage = 1
				
			Endif
		Next
	
		If si>0 Or total <=1
			''add last image
			If subimage[si].index >-1 Then subimage[si].file = subimage[si].file+"_"+String(subimage[si].index)
			DebugLog subimage[si].file
			tmap.Set((subimage[si].file), subimage[si])
		Endif
		
		total = si
		
		Return 1
	End
	
	Method GetSubTexture:CSubTextureAtlas(fn:String, index:Int=0)
		Local noindexfn:String
		
		''drop any .png ext
		If fn.Contains(".") Then fn = fn[..(fn.FindLast(".")) ]
		noindexfn = fn.Trim()
		If index>0 Then fn=fn+"_"+String(index)

		Local subimage:CSubTextureAtlas = tmap.Get(fn)
		If Not subimage
			''try without index
			subimage = tmap.Get(noindexfn)
			If Not subimage
				Print "**atlas not found:"+fn
				Return Null
			Endif
		Endif

		Return subimage
	End
	
	Method Grab:Image(fn:String, index:Int=0, flags:Int=Image.DefaultFlags)
	
		Local subimage:CSubTextureAtlas = GetSubTexture(fn,index)
		If Not subimage Then Return Null
		
		Local p:Int = subimage.page ' added to handle pages
		Return texture[p].GrabImage(subimage.x, subimage.y, subimage.w, subimage.h, 1, flags)
	End
	
	Method GrabSet:Image[](fn:String, w:Int, h:Int, frames:Int=0, flags:Int=Image.DefaultFlags, index:Int=0)
		Local imgs:Image[frames+1]
		imgs[0] = Null
		
		Local subimage:CSubTextureAtlas = GetSubTexture(fn,index)
		Local p:Int = subimage.page ' added to handle pages
		Local newx:Int =0 , newy:Int=0
		For Local i:=0 To frames-1
			imgs[i] = texture[p].GrabImage(subimage.x + newx, subimage.y + newy, w, h, 1, flags)
			newx += w+1
			If newx >= subimage.w-2
				newx=0
				newy += h+1
				If newy>subimage.h
					Exit
				Endif
			Endif
			
		Next
		Return imgs
	End

End

Class CSubTextureAtlas
	Field file:String = ""
	Field page:Int = 0 ' added to handle pages
	Field x:Int, y:Int, offsetx:Int, offsety:Int
	Field w:Int, h:Int
	Field index:Int
	Field totalframes:Int
End

I then took therevills example and created the following
textureloadertest.monkey

Strict

Import mojo
Import textureloader

Global myGame:MyGame

Function Main:Int()
	myGame = new MyGame
	Return 0
End

Class MyGame Extends App
	Field unitAtlas:CTextureAtlas
	Field imgunit:Image[16]
	Field frame:Int
	Field frameTimer:Int
	Field frameEnd:Int = 15
	Field frameSpeed:Int = 100

	Method OnCreate:Int()
		SetUpdateRate 60
		unitAtlas = LoadAtlas("penwalker.txt")
		For Local i:Int = 0 to 15
			if i < 10
				imgunit[i] = unitAtlas.Grab("0"+i,0,Image.MidHandle)
			Else
				imgunit[i] = unitAtlas.Grab(i,0,Image.MidHandle)
			End
		Next

		Return 0
	End
	
	Method OnUpdate:Int()
		if frameSpeed > 0
			If Millisecs() > frameTimer + frameSpeed
				frame+=1
				If frame > frameEnd
					frame = 0
                End
				frameTimer = Millisecs()
			End	
		end
		Return 0		
	End
	
	Method OnRender:Int()
		Cls
        DrawImage imgunit[frame], 100, 100
		Return 0
	End
End

However, I am getting the following when I try to run.

Loading new texture penwalker.png here, index 0
walker
**atlas not found:00
**atlas not found:01
**atlas not found:02
**atlas not found:03
**atlas not found:04
**atlas not found:05
**atlas not found:06
**atlas not found:07
**atlas not found:08
**atlas not found:09
**atlas not found:10
**atlas not found:11
**atlas not found:12
**atlas not found:13
**atlas not found:14
**atlas not found:15
Monkey Runtime Error : Memory access violation
C:/MonkeyXPro78c/modules/mojo/graphics.monkey<457>
C:/Users/Ethan/Dropbox/textureloadertest.monkey<50>
C:/MonkeyXPro78c/modules/mojo/app.monkey<113>

So I am assuming I did something wrong in TexturePacker?

AdamRedwoods

(Posted 2014) [#2]

according to the "penwalker.txt" file, you only added one file, so the texture atlas only sees the one.
in this case, you do not need the texture atlas loader. instead use this, which is in Monkey:

myImage = LoadImage ( path:String, frameWidth:Int, frameHeight:Int, frameCount:Int, flags:Int=image.defaultflags )

where frameWidth=32 and frameHeight=32 and frameCount=16
then use

DrawImage(myImage, x, y, your frame number)

erebel55

(Posted 2014) [#3]

Right, I understand how to do LoadImage/DrawImage; that is what I'm currently using in my game.

I am trying to understand how to use atlases. So for animated images I have to add each frame as a separate image to TexturePacker? I just added the whole frame strip.

AdamRedwoods

(Posted 2014) [#4]

So for animated images I have to add each frame as a separate image to TexturePacker?

yes. then the "atlas.Get()" filename would be the names of the files you added.

erebel55

(Posted 2014) [#5]

Thanks I got it working now :D