Question about Leaderboards and html5

Monkey Forums/Monkey Programming/Question about Leaderboards and html5

MisterBull

(Posted 2014) [#1]

I understand that in web browser code (such as javascript/html) aside from php that you cant simply just save data to the server (or/and retrieve it)

So before I go through the headache of experimenting and researching this topic (wasting valuable time) I feel I should just ask about it here...

Can a monkey html5 app use a leader board system of sorts?

You know, recording and retrieving players scores.

Desperado

(Posted 2014) [#2]

There are many cloud backend services available for that. I’ve used Scoreoid which works great. Scores can be stored and retrieved with simple http request calls from your Monkey app. Buddy, App42, and QuickBlox are some other options that also have leaderboard support.

MisterBull

(Posted 2014) [#3]

I've looked through the links you gave me and I've signed up for Buddy. now, how would I go about linking my buddy app thing to my game? o.0

this looks a bit confusing atm.

Danilo

(Posted 2014) [#4]

Wouldn't it be enough to call a PHP / CGI script with arguments on your server to save some info to a database?

MisterBull

(Posted 2014) [#5]

I havent learned much PHP yet, unfortunately (I suppose its never too late to start learning though)

Desperado

(Posted 2014) [#6]

Working with Buddy is more complicated than Scoreoid, but it might be worth the effort since it appears to provide more usage for free.

Below is the beginnings of a class that communicates with Buddy to create a user (and the user’s player), add scores to a board, and retrieve high scores for a board. To use it, first create an instance of it by passing in your Buddy Application Name and Key like this:

buddy = New Buddy("testgame1", "CA578BC9-DEDC-4CCD-A465-2FCA940779A8", "", "")

Here’s how you create a user:

buddy.CreateUser("user", "password")

That code will contact Buddy to create the user and add the user’s player. Note you’ll need to save off the userToken and restore it when the app is run again so the user doesn’t have to login each time you run the app. The userToken and name can be passed in when creating the Buddy instance.

Here’s how you add a score to a board for the current user:

buddy.AddScore(100, "board")

Here’s how you can retrieve the high scores for a board:

buddy.GetScores("board", 25)

Here’s the example Buddy class:

Import brl.httprequest
Import brl.json

Class Buddy Implements IOnHttpRequestComplete

	Private
	
	Field appName:String
	Field appKey:String
	Field userToken:String
	Field userName:String
	Field createUserReq:HttpRequest
	Field loginUserReq:HttpRequest
	Field addPlayerReq:HttpRequest
	Field addScoreReq:HttpRequest
	Field getScoresReq:HttpRequest
	
	Public
	
	Method New(appName:String, appKey:String, userToken:String, userName:String)
		Self.appName = appName
		Self.appKey = appKey
		Self.userToken = userToken
		Self.userName = userName
	End
	
	Method UserToken:String() Property
		Return userToken
	End

	Method UserName:String() Property
		Return userName
	End
	
	Method CreateUser(userName:String, userPassword:String)
		Self.userName = userName
		userToken = ""
		createUserReq = New HttpRequest("POST", "http://webservice.buddyplatform.com/v1/UserAccount_Profile_Create?BuddyApplicationName=" + appName + "&BuddyApplicationPassword=" + appKey + "&NewUserName=" + userName + "&UserSuppliedPassword=" + userPassword + "&NewUserEmail=" + userName + "&NewUserGender=male&UserAge=18&StatusID=-1&ApplicationTag=", Self)
		createUserReq.Send()
	End

	Method LoginUser(userName:String, userPassword:String)
		Self.userName = userName
		userToken = ""
		loginUserReq = New HttpRequest("POST", "http://webservice.buddyplatform.com/v1/UserAccount_Profile_Recover?BuddyApplicationName=" + appName + "&BuddyApplicationPassword=" + appKey + "&UserName=" + userName + "&UserSuppliedPassword=" + userPassword, Self)
		loginUserReq.Send()
	End
	
	Method AddPlayer()
		addPlayerReq = New HttpRequest("POST", "http://webservice.buddyplatform.com/v1/Game_Player_Add?BuddyApplicationName=" + appName + "&BuddyApplicationPassword=" + appKey + "&UserTokenOrID=" + userToken + "&PlayerName=" + userName + "&PlayerLatitude=0.0&PlayerLongitude=0.0", Self)
		addPlayerReq.Send()
	End
	
	Method AddScore(score:Int, board:String)
		addScoreReq = New HttpRequest("POST", "http://webservice.buddyplatform.com/v1/Game_Score_Add?BuddyApplicationName=" + appName + "&BuddyApplicationPassword=" + appKey + "&UserTokenOrID=" + userToken + "&ScoreBoardName=" + board + "&ScoreValue=" + score + "&OneScorePerPlayerBit=1&ScoreLatitude=0.0&ScoreLongitude=0.0", Self)
		addScoreReq.Send()
	End
	
	Method GetScores(board:String, limit:Int)
		getScoresReq = New HttpRequest("POST", "http://webservice.buddyplatform.com/v1/Game_Score_GetBoardHighScores?BuddyApplicationName=" + appName + "&BuddyApplicationPassword=" + appKey + "&ScoreBoardName=" + board + "&RecordLimit=" + limit, Self)
		getScoresReq.Send()
	End
	
	Method OnHttpRequestComplete:Void(req:HttpRequest)
		Select req
			Case createUserReq
				createUserReq = Null
				If req.Status() = -1
					Print "Buddy CreateUser error, status = -1"
				Elseif req.ResponseText().StartsWith("UT-")
					userToken = req.ResponseText()
					Print "Buddy CreateUser success, userToken = " + userToken
					AddPlayer()
				Else
					Print "Buddy CreateUser error, response = " + req.ResponseText()
				Endif
			
			Case loginUserReq
				loginUserReq = Null
				If req.Status() = -1
					Print "Buddy LoginUser error, status = -1"
				Elseif req.ResponseText().StartsWith("UT-")
					userToken = req.ResponseText()
					Print "Buddy LoginUser success, userToken = " + userToken
				Else
					Print "Buddy LoginUser error, response = " + req.ResponseText()
				Endif
			
			Case addPlayerReq
				addPlayerReq = Null
				If req.Status() = -1
					Print "Buddy AddPlayer error, status = -1"
				Elseif req.ResponseText() = "1"
					Print "Buddy AddPlayer success"
				Else
					Print "Buddy AddPlayer error, response = " + req.ResponseText()
				Endif
				
			Case addScoreReq
				addScoreReq = Null
				If req.Status() = -1
					Print "Buddy AddScore error, status = -1"
				Elseif req.ResponseText() = "1"
					Print "Buddy AddScore success"
				Else
					Print "Buddy AddScore error, response = " + req.ResponseText()
				Endif
				
			Case getScoresReq
				getScoresReq = Null
				If req.Status() = -1
					Print "Buddy GetScores error, status = -1"
				Elseif req.ResponseText().StartsWith("{")
					Try
						Local respObj := New JsonObject(req.ResponseText())
						Print "Buddy GetScores success, scores ="
						Local respData:JsonArray = JsonArray(respObj.Get("data"))
						If respData
							Local scoresAry := respData.GetData()
							For Local index:Int = 0 Until scoresAry.Length
								Local scoreObj:JsonObject = JsonObject(scoresAry[index])
								Print "  userName = " + scoreObj.GetString("userName") + ", score = " + scoreObj.GetString("scoreValue")
							Next
						Endif
					Catch e:JsonError
						Print "Buddy GetScores json error, response = " + req.ResponseText()
					End
				Else
					Print "Buddy GetScores error, response = " + req.ResponseText()
				Endif
		End
	End
End

MisterBull

(Posted 2014) [#7]

thanks for the code, I'll play around with it when it comes time to add the leader board to my game. If I have any further questions I'll post in this thread again.

Mucho apreciato!

MisterBull

(Posted 2014) [#8]

I cant seem to get it to send the score to the buddy app :P

I'm not sure if I'm just coding it wrong or what... It does receive the new user code just fine though

Desperado

(Posted 2014) [#9]

Well here's a complete example that works for me. Just save it to a .monkey file and run it. Press the various keys it displays to create or login users, submit scores, and get the list of high scores. Check the log for info about what's going on.

Import mojo
Import brl.httprequest
Import brl.json


Interface IOnBuddyResponse
 	Method OnBuddyResponse(type:String, success:Bool, data:String)
End


Class Buddy Implements IOnHttpRequestComplete
	Private
	
	Field appName:String
	Field appKey:String
	Field userToken:String
	Field userName:String
	Field userId:String
	Field playerId:String
	Field handler:IOnBuddyResponse
	Field requests:StringMap<HttpRequest> = New StringMap<HttpRequest>
	
	Public
	
	Method New(appName:String, appKey:String, handler:IOnBuddyResponse, userToken:String, userName:String, userId:String, playerId:String)
		Self.appName = appName
		Self.appKey = appKey
		Self.userToken = userToken
		Self.userName = userName
		Self.userId = userId
		Self.playerId = playerId
		Self.handler = handler
	End
	
	Method UserToken:String() Property
		Return userToken
	End

	Method UserName:String() Property
		Return userName
	End

	Method UserId:String() Property
		Return userId
	End

	Method PlayerId:String() Property
		Return playerId
	End
	
	Method CreateUser(userName:String, userPassword:String)
		LogoutUser()
		Self.userName = userName
		userToken = ""
		SendRequest("CreateUser", "UserAccount_Profile_Create", "&NewUserName=" + userName + "&UserSuppliedPassword=" + userPassword + "&NewUserEmail=" + userName + "&NewUserGender=male&UserAge=18&StatusID=-1&ApplicationTag=")
	End

	Method LoginUser(userName:String, userPassword:String)
		LogoutUser()
		Self.userName = userName
		userToken = ""
		SendRequest("LoginUser", "UserAccount_Profile_Recover", "&UserName=" + userName + "&UserSuppliedPassword=" + userPassword)
	End
	
	Method AddPlayer()
		SendRequest("AddPlayer", "Game_Player_Add", "&UserTokenOrID=" + userToken + "&PlayerName=" + userName + "&PlayerLatitude=0.0&PlayerLongitude=0.0")
	End

	Method GetPlayer()
		SendRequest("GetPlayer", "Game_Player_GetPlayerInfo", "&UserTokenOrID=" + userToken)
	End
	
	Method AddScore(score:Int, board:String)
		SendRequest("AddScore", "Game_Score_Add", "&UserTokenOrID=" + userToken + "&ScoreBoardName=" + board + "&ScoreValue=" + score + "&OneScorePerPlayerBit=1&ScoreLatitude=0.0&ScoreLongitude=0.0")
	End
	
	Method GetScores(board:String, limit:Int)
		SendRequest("GetScores", "Game_Score_GetBoardHighScores", "&ScoreBoardName=" + board + "&RecordLimit=" + limit)
	End
	
	Method LogoutUser()
		userToken = ""
		userName = ""
		userId = ""
		playerId = ""
	End
	
	Method SendRequest:HttpRequest(type:String, func:String, params:String)
		Local url:String = "http://webservice.buddyplatform.com/v1/" + func + "?BuddyApplicationName=" + appName + "&BuddyApplicationPassword=" + appKey + params
		Print "Buddy.SendRequest " + type + ", url=" + url
		Local req := New HttpRequest("POST", url, Self)
		requests.Set(type, req)
		req.Send()
		Return req
	End
	
	Method OnHttpRequestComplete:Void(req:HttpRequest)
		Print "Buddy.OnHttpRequestComplete Status=" + req.Status() + ", ResponseText=" + req.ResponseText()
		For Local type := Eachin requests.Keys
			If requests.Get(type) = req
				Select type
					Case "CreateUser"
						If req.Status() <> -1 And req.ResponseText().StartsWith("UT-")
							userToken = req.ResponseText()
							handler.OnBuddyResponse(type, True, req.ResponseText())
						Else
							handler.OnBuddyResponse(type, False, req.ResponseText())
						Endif
					
					Case "LoginUser"
						If req.Status() <> -1 And req.ResponseText().StartsWith("UT-")
							userToken = req.ResponseText()
							handler.OnBuddyResponse(type, True, req.ResponseText())
						Else
							handler.OnBuddyResponse(type, False, req.ResponseText())
						Endif
					
					Case "AddPlayer"
						handler.OnBuddyResponse(type, req.Status() <> -1 And req.ResponseText() = "1", req.ResponseText())
					
					Case "GetPlayer"
						If req.Status() <> -1 And req.ResponseText().StartsWith("{")
							Try
								Local respObj := New JsonObject(req.ResponseText())
								Local dataAry := JsonArray(respObj.Get("data"))
								If dataAry
									Local dataObj := JsonObject(dataAry.Get(0))
									If dataObj
										userId = dataObj.GetString("userID")
										playerId = dataObj.GetString("playerID")
									Endif
								Endif
							Catch e:JsonError
								Print "json error"
							End
							handler.OnBuddyResponse(type, True, req.ResponseText())
						Else
							handler.OnBuddyResponse(type, False, req.ResponseText())
						Endif

					Case "AddScore"
						handler.OnBuddyResponse(type, req.Status() <> -1 And req.ResponseText() = "1", req.ResponseText())
						
					Case "GetScores"
						handler.OnBuddyResponse(type, req.Status() <> -1 And req.ResponseText().StartsWith("{"), req.ResponseText())
				End
				requests.Remove(type)
				Exit
			Endif
		Next
	End
End


Class Score
	Field userId:String
	Field userName:String
	Field score:Int
	
	Method New(userId:String, userName:String, score:Int)
		Self.userId = userId
		Self.userName = userName
		Self.score = score
	End
End


Class GameApp Extends App Implements IOnBuddyResponse
	Private

	Const BUDDY_APP := "testgame1"
	Const BUDDY_KEY := "CA578BC9-DEDC-4CCD-A465-2FCA940779A8"
	
	Field buddy:Buddy
	Field testUserIndex:Int = 1
	Field testScore:Int
	Field leaderboard:Stack<Score> = New Stack<Score>
	
	Public
	
	Method OnCreate()
		SetUpdateRate 60
		
		'load saved data
		Local userToken:String
		Local userName:String
		Local userId:String
		Local playerId:String
		Local data := LoadState()
		If data
			Local obj := New JsonObject(data)
			userToken = obj.GetString("userToken")
			userName = obj.GetString("userName")
			userId = obj.GetString("userId")
			playerId = obj.GetString("playerId")
			testUserIndex = obj.GetInt("testUserIndex")
			testScore = obj.GetInt("testScore")
		Endif
		
		'initialize buddy
		buddy = New Buddy(BUDDY_APP, BUDDY_KEY, Self, userToken, userName, userId, playerId)
	End

	Method OnUpdate()
		UpdateAsyncEvents()
		
		If KeyHit(KEY_1) > 0
			SetUser(1)
		Elseif KeyHit(KEY_2) > 0
			SetUser(2)
		Elseif KeyHit(KEY_3) > 0
			SetUser(3)
		Elseif KeyHit(KEY_4) > 0
			SetUser(4)
		Elseif KeyHit(KEY_5) > 0
			SetUser(5)
		Elseif KeyHit(KEY_6) > 0
			SetUser(6)
		Elseif KeyHit(KEY_7) > 0
			SetUser(7)
		Elseif KeyHit(KEY_8) > 0
			SetUser(8)
		Elseif KeyHit(KEY_9) > 0
			SetUser(9)
		Elseif KeyHit(KEY_C) > 0
			Print "******************* CreateUser"
			buddy.CreateUser("TestUser" + testUserIndex, "password")
		Elseif KeyHit(KEY_P) > 0
			Print "******************* AddPlayer"
			buddy.AddPlayer()
		Elseif KeyHit(KEY_L) > 0
			Print "******************* LoginUser"
			buddy.LoginUser("TestUser" + testUserIndex, "password")
		Elseif KeyHit(KEY_O) > 0
			Print "******************* LogoutUser"
			buddy.LogoutUser()
		Elseif KeyHit(KEY_G) > 0
			Print "******************* GetPlayer"
			buddy.GetPlayer()
		Elseif KeyHit(KEY_I) > 0
			Print "******************* testScore + 1"
			testScore += 1
		Elseif KeyHit(KEY_R) > 0
			Print "******************* testScore = 0"
			testScore = 0
		Elseif KeyHit(KEY_S) > 0
			Print "******************* AddScore"
			buddy.AddScore(testScore, "board")
		Elseif KeyHit(KEY_H) > 0
			Print "******************* GetScores"
			buddy.GetScores("board", 100)
		Elseif KeyHit(KEY_V) > 0
			Print "******************* Save"
			Save()
		Endif
	End

	Method OnRender()
		Cls
		
		Local userName := "TestUser" + testUserIndex
		
		DrawText("user:  " + userName,							10, 0, 0, 0)
		DrawText("score: " + testScore,							160, 0, 0, 0)
		
		DrawText("press:",										10, 40, 0, 0)
		DrawText("  1 to 9 - Select TestUser1 to TestUser9",	10, 60, 0, 0)
		DrawText("  C - Create " + userName,					10, 80, 0, 0)
		DrawText("  P - Create Player For " + userName,		10, 100, 0, 0)
		DrawText("  L - Login " + userName,						10, 120, 0, 0)
		DrawText("  O - Logout " + userName, 					10, 140, 0, 0)
		DrawText("  G - Get Player For " + userName,			10, 160, 0, 0)
		DrawText("  I - Increment Score",						360, 60, 0, 0)
		DrawText("  R - Reset Score",							360, 80, 0, 0)
		DrawText("  S - Submit Score",							360, 100, 0, 0)
		DrawText("  H - Get High Scores",						360, 120, 0, 0)
		DrawText("  V - Save",									360, 160, 0, 0)
		
		DrawText("buddy:",										10, 200, 0, 0)
        DrawText("  userToken: " + buddy.UserToken,			10, 220, 0, 0)
        DrawText("  userName:  " + buddy.UserName,				10, 240, 0, 0)
        DrawText("  userId:    " + buddy.UserId,				10, 260, 0, 0)
        DrawText("  playerId:  " + buddy.PlayerId,				10, 280, 0, 0)
        
		DrawText("leaderboard:",								10, 320, 0, 0)
		For Local index:Int = 0 Until leaderboard.Length
			Local entry := leaderboard.Get(index)
			DrawText("#" + (index+1),							10, 340 + index*20, 0, 0)
			DrawText(entry.userName,							50, 340 + index*20, 0, 0)
			DrawText(entry.score,								200, 340 + index*20, 0, 0)
			DrawText(entry.userId,								250, 340 + index*20, 0, 0)
		Next
	End
	
	Method OnBuddyResponse(type:String, success:Bool, data:String)
		Print "OnBuddyResponse " + type + ", success=" + Int(success)
		
		Select type
			Case "CreateUser"
			
			Case "AddPlayer"
			
			Case "LoginUser"
			
			Case "GetPlayer"
			
			Case "AddScore"
			
			Case "GetScores"
				Try
					Local dataObj := New JsonObject(data)
					Local dataAry := JsonArray(dataObj.Get("data"))
					If dataAry
						leaderboard.Clear()
						Local scoresAry := dataAry.GetData()
						For Local index:Int = 0 Until scoresAry.Length
							Local scoreObj := JsonObject(scoresAry[index])
							Print "userId = " + scoreObj.GetString("userID") + ", userName = " + scoreObj.GetString("userName") + ", score = " + scoreObj.GetString("scoreValue")
							leaderboard.Push(New Score(scoreObj.GetString("userID"), scoreObj.GetString("userName"), Int(scoreObj.GetString("scoreValue"))))
						Next
					Endif
				Catch e:JsonError
					Print "json error, data = " + data
				End
		End
	End
	
	Method SetUser(index:Int)
		Print "******************* SetUser " + index
		buddy.LogoutUser()
		testUserIndex = index
	End
	
	Method Save()
		Local obj := New JsonObject()
		obj.SetString("userToken", buddy.UserToken)
		obj.SetString("userName", buddy.UserName)
		obj.SetString("userId", buddy.UserId)
		obj.SetString("playerId", buddy.PlayerId)
		obj.SetInt("testUserIndex", testUserIndex)
		obj.SetInt("testScore", testScore)
		Local data := obj.ToJson()
		SaveState(data)
	End
End


Function Main()
	New GameApp()
End

MisterBull

(Posted 2014) [#10]

hey, yea, that helped allot! thanks! :D

IMMGames

(Posted 2015) [#11]

I'm sorry to dig up such an old thread, but this example seems outdated now?
Any chance of you updating it for the new Buddy API?

Desperado

(Posted 2015) [#12]

It looks like they may have dropped support for leaderboards with the new Buddy API.

Here are some other game backend services that support leaderboards which you could check out instead:
PlayFab
GameSparks
brainCloud
Clan of the Cloud
App42

MisterBull

(Posted 2015) [#13]

yeah, they changed their services over to some new system just in the past month.

unfortunate since I now gotta find some time to rework the code in my game :P