Need help with bullet velocity

Monkey Forums/Monkey Programming/Need help with bullet velocity

Sensei

(Posted 2013) [#1]

Hey guys,
Making a shooter game and I'm hoping you can help me with my small problem.

Below is the current code I have written, which is close but no cigar.
This is supposed to be bullets shot from the enemy toward the player.

If sx > ex
	speedX = sx / ex
	horizontalMove = (-speedX * speed) - speed
Else
	speedX = ex / sx
	horizontalMove = (speedX * speed) + speed
End
If sy > ey
	speedY = sy / ey
	verticalMove = (-speedY * speed) - speed
Else
	speedY = ey / sy
	verticalMove = (speedY * speed) + speed
End

Assume sx (start X), sy (start Y), ex (player's X position/end X), ey (player's Y position/end Y) and speed is the bullet's standard speed.

horizontalMove and verticalMove then become the bullet object's actual x/y speed to travel towards the player's position.

I need the bullets to go exactly where the player currently is.
Help meeeeee!! :)

Goodlookinguy

(Posted 2013) [#2]

Here, I mocked-up this example up quickly. Also, you may wanna brush up on your math if you can't solve this.

Import mojo

Function Main:Int()
	New Example()
End

Class Example Extends App
	Method OnCreate()
		SetUpdateRate(30)
		
		player.x = 40
		player.y = 10
		
		enemy.x = 200
		enemy.y = 300
		
		bullet.x = 40
		bullet.y = 10
	End
	
	Method OnUpdate()
		Local angle:Float = ATan2(enemy.y - player.y, enemy.x - player.x)
		bullet.x = bullet.x + Cos(angle) * speed
		bullet.y = bullet.y + Sin(angle) * speed
	End
	
	Method OnRender()
		Cls()
		DrawCircle(player.x, player.y, 3)
		DrawCircle(bullet.x, bullet.y, 2)
		DrawCircle(enemy.x, enemy.y, 3)
	End
	
	Field player:Vec2D = New Vec2D()
	Field enemy:Vec2D = New Vec2D()
	Field bullet:Vec2D = New Vec2D()
	Field speed:Int = 3
End

Class Vec2D
	Field x:Float, y:Float
End

Sensei

(Posted 2013) [#3]

Thanks for that Goodlookinguy! (that sounds like a come-on) :)

I'll give it a try later when back at home.

Sensei

(Posted 2013) [#4]

got this working, thanks mate.
I had to reverse the bullet x and y addition though as it was going the opposite direction:

...
i.sx -= Cos(i.angle) * i.speed * dt.delta
i.sy -= Sin(i.angle) * i.speed * dt.delta
...

Still, works a treat thanks!

Goodlookinguy

(Posted 2013) [#5]

I had it pointing from player to enemy. To get the exact opposite effect you just have to change theses lines.

bullet.x = 10
bullet.y = 10

Local angle:Float = ATan2(enemy.y - player.y, enemy.x - player.x)

bullet.x = enemy.x
bullet.y = enemy.y

Local angle:Float = ATan2(player.y - enemy.y, player.x - enemy.x)

Sensei

(Posted 2013) [#6]

Ah I see now, thanks!