Type lists help needed...

Monkey Forums/Monkey Programming/Type lists help needed...

necky

(Posted 2013) [#1]

Hi Everyone!

I've been trying to figure this out but for some reason I just can't seem to find any documentation on how its done so I'm hoping some awesome chap/chapette that can help me out :)

What I want to do is create an undefinable amount of objects (particles for this example) that I can then draw to the screen. So what I'm trying to do is to create a new class when I want to and then just go through the list of these particles at draw time.

In Blitz you just create a new type and then run through the list of those created types with a simple 'for' loop. How would I do something similar in Monkey?

I've added my code for this so far. As you can see I've set up the class and that's about it :)

All the best!

Mike

'CODE STARTS HERE '

Import mojo
Import mojo.app
Import mojo.graphics

Class MyApp Extends App

Method OnCreate:Int()
SetUpdateRate 60
End

Method OnUpdate()

End

Method OnRender()

End

End

Function Main()
New MyApp
End

' PLAYER CLASS '

Class Particle

Field posX:Int
Field posY:Int

Method Draw:Void(positionX:Int, positionY:Int)

posX=positionX
posY=positionY

DrawPoint (PosX,posY)

End

End

dawlane

(Posted 2013) [#2]

You should view InvaderJim's tutorials.

The method below uses a static variable (Global) to hold a list of particles and some static functions to create, update and draw all the particles.

But there is nothing to stop you from creating a member variable (Field) in a class as a particle list and using Methods in stead of functions to create particles.

Strict
Import mojo

Class MyApp Extends App

	Method OnCreate:Int()
		SetUpdateRate 60
		Particle.Create()
		Return 0
	End Method

	Method OnUpdate:Int()
		Particle.Update()
		Return 0
	End method

	Method OnRender:Int()
		Cls
		Particle.Draw()
		Return 0
	End Method

End

Function Main:Int()
	New MyApp
	Return 0
End

Class Particle

	Global particleList:= New List<Particle>
	Field posX:Int
	Field posY:Int
	Field dy:Int
	Field dx:Int

	Method New()
		Self.posX = Rnd(640)
		Self.posY = Rnd(480)
		Self.dx=Rnd(1,5);If Rnd(1)>=.5 dx=-dx
		Self.dy=Rnd(1,5);If Rnd(1)>=.5 dy=-dy
		Self.size = Rnd(5)
	End Method
	
	Function Create:Void()
		Local tmp:Particle
		For Local i:Int = 0 To 100
			tmp = New Particle()
			particleList.AddLast(tmp)
		Next	
	End Function
	
	Function Update:Void()
		Local i:Particle
		For i = Eachin particleList
			i.posY += i.dy
			i.posX += i.dx
			If i.posX > 639 Or i.posX < 1 Then i.dx= -i.dx
			If i.posY > 479 Or i.posY < 1 Then i.dy= -i.dy
		Next
	End Function
	
	Function Draw:Void()
		Local i:Particle
		For i = Eachin particleList
			i.DrawParticle()
		Next
	End Function
	
	Method DrawParticle:Void()
		DrawRect(Self.posX, Self.posY, Self.size, Self.size)
	End Method
End

necky

(Posted 2013) [#3]

Hi!

This is fantastic!! :D Thank you so much for such super feedback! :D

all the best!
Mike