fantomEngine built-in functions

Monkey Forums/Monkey Programming/fantomEngine built-in functions

trainer

(Posted 2013) [#1]

Hello Everyone ..
Can anybody tell me if there is any built-in function inside fantomEngine framework that let me make some echo or flash on a specific object, which I want the player to notice to click on it depending on the voice instructions..

What I'm asking about is the built-in functions that will let me make my game more entertaining ..

MikeHart

(Posted 2013) [#2]

Häää????? Echo???? Flash???? Define echo. Is it a sound effect? Define flash.
Do you mean that it lights up?

Sorry, but english is not my native language so it could be that I didn't understand what you ment.

rIKmAN

(Posted 2013) [#3]

I'm sure fE will have a way to handle animation frames, although I don;t use it so not sure of the specific commands.

Find those, and then you can set the animation for that specific object so it will "flash" and draw the users attention to it.

When they select the object, you can then go back to the normal static image (frame 1 etc)

trainer

(Posted 2013) [#4]

Ammm .. let me explain what I want clearly
-----------------
obj.CreateTransRot(360,800, True,1)
obj.SetScale(1)
-----------------
Those are a functions inside the fantomEngine..isn't ?

I'm just looking for such function which allow me to let some object flashing .. I mean it appears and goes in at most two seconds and keeps coming and leaving continually until I click on it ..

I hope that what I want is clear now .. :/

MikeHart

(Posted 2013) [#5]

Yes, these are functions in fE.

Ok, you want to alpha fade it in and out. There you would use ftObject.CreateTransAlpha and then in ftEngine.OnObjectTrans fire the opposite. Give me a few minutes and I will post a little example.

MikeHart

(Posted 2013) [#6]

Here you go:

Strict

#rem
	Script:			FlashObject.monkey
	Description:	This sample script shows some ways on how to flash an object 
	Author: 		Michael Hartlef
	Version:      	1.0
#End

' Import the fantomEngine framework which imports mojo itself
Import fantomEngine

' The _g variable holds an instance to the cGame class
Global _g:cGame

'***************************************
Class myObject Extends ftObject

	Field frameOnTime:Int = 60
	Field frameOn:Int = 1

	Method New()
		Self.SetColor(Rnd(50,255), Rnd(50,255), Rnd(50,255))
	End
	Method myUpdate:void()
		Self.frameOnTime -= 1
		If Self.frameOnTime < 0
			Self.frameOnTime = 60
			Self.frameOn = 1 - Self.frameOn
		Endif
		
		If Self.frameOn = 1 Then
			Self.SetScale(1)
		Else
			Self.SetScale(-0.01,True)
		Endif
	End
End


'***************************************
' The cGame class controls the app
Class cGame Extends App
	' Create a field to store the instance of the cEngine class, which is an instance
	' of the ftEngine class itself
	Field fE:cEngine
	
	'------------------------------------------
	Method OnCreate:Int()
		' Set the update rate of Mojo's OnUpdate events to 60 FPS
		SetUpdateRate(60)
		
		' Seed the random number generator
		Seed = Millisecs()
		
		' Create an instance of the fantomEngine, which was created via the cEngine class
		fE = New cEngine
		
		' Create some objects
		Local obj1 := fE.CreateBox(100, 100, 150, 150, New myObject)
		obj1.ActivateRenderEvent()
		obj1.ActivateUpdateEvent(false)
		
		Local obj2 := fE.CreateBox(100, 100, 350, 150, New myObject)
		obj2.SetID(2)
		obj2.CreateTimer(0, 500, -1)
		obj2.ActivateUpdateEvent(false)
		
		Local obj3 := fE.CreateBox(100, 100, 150, 350, New myObject)
		obj3.CreateTransAlpha(0, 1000, False,1)
		obj3.ActivateUpdateEvent(false)
		
		Local obj4 := fE.CreateBox(100, 100, 350, 350, New myObject)
		
		Return 0
	End
	'------------------------------------------
	Method OnUpdate:Int()
		If KeyHit( KEY_CLOSE ) fE.ExitApp()
		' Determine the delta time and the update factor for the engine
		Local d:Float = Float(fE.CalcDeltaTime())/60.0

		' Update all objects of the engine
		If fE.GetPause() = False Then
			fE.Update(d)
		Endif
		Return 0
	End
	'------------------------------------------
	Method OnRender:Int()
		' Check if the engine is not paused
		If fE.GetPause() = False Then
			' Clear the screen 
			Cls 
		
			' Render all visible objects of the engine
			fE.Render()
		Endif
		Return 0
	End
End	

'***************************************
' The cEngine class extends the ftEngine class to override the On... methods
Class cEngine Extends ftEngine
	'------------------------------------------
	Method OnObjectRender:Int(obj:ftObject)
		' This method is called when an object was being rendered
		Local o:myObject = myObject(obj)
		Local px:Float = o.GetPosX()
		Local py:Float = o.GetPosY()
		
		o.frameOnTime -= 1
		If o.frameOnTime < 0
			o.frameOnTime = 60
			o.frameOn = 1 - o.frameOn
		Endif
		
		If o.frameOn = 1 Then
			DrawLine(px-55 , py-55, px+55, py-55)
			DrawLine(px-55 , py+55, px+55, py+55)
		Endif
		Return 0
	End
	'------------------------------------------
	Method OnObjectTimer:Int(timerId:Int, obj:ftObject)
		' This method is called when an objects' timer was being fired
		If obj.GetID() = 2 Then
			obj.SetAlpha(1-obj.GetAlpha())
		Endif
		Return 0
	End	
	'------------------------------------------
	Method OnObjectTransition:Int(transId:Int, obj:ftObject)
		' This method is called when an object finishes its transition
		obj.CreateTransAlpha(1.0-obj.GetAlpha(), 1000, False,1)
		Return 0
	End
	'------------------------------------------
	Method OnObjectUpdate:Int(obj:ftObject)
		' This method is called when an object finishes its update
		myObject(obj).myUpdate()
		Return 0
	End
End

'***************************************
Function Main:Int()
	' Create an instance of the cGame class and store it inside the global var 'g'
	_g = New cGame
	
	Return 0
End

It also shows how to use custom objects with fE and how to utilizes some of fE's callback methods.

Have fun
Michael

trainer

(Posted 2013) [#7]

Waw .. It looks so great ..

I will apply this on my game now

Thank you so much :)

MikeHart

(Posted 2013) [#8]

Glad you like it.

Ken	(Posted 2013) [#9]

Hiya,

Monkey newbie here.

I'm just trying to get this running so I can see how it's working...but first fantom engine wasn't found, then I copied that into my working directory.

Then it was the JSON module missing. I took this to mean it was the JSON stuff written by warpy. I copied that into my working directory.

When i ran it, I'm now told JSONDataItem not found.

The docs are are rather sparse when talking about modules. Is there a module manager? Are modules stored in a system-wide place?

Thanks for any input.

-Ken

MikeHart

(Posted 2013) [#10]

When you download fE, it comes with a JSON module. And it says on the download page to copy it in your modules directory too. But i will add this info to the docs too.

MikeHart

(Posted 2013) [#11]

Modules are stored inside monkeys module folder or a userdefined folder which you then need to specify inside the config file under modpath.

Edit: There is no module manager to my knowledge.

Ken	(Posted 2013) [#12]

Does it? Really?

I downloaded fantomEngine_V150.zip, unpacked it into my modules directory, and no joy:
Module 'json' not found.

Tried on both Windows and Mac.

If I copy the json directory from MonkeyPro70b/bananas/warpy/json into the modules directory, I get the error
Type 'JSONDataItem' not found.

Again, both Windows and Mac.

...and no json directory anywhere. In fact, the download page also mentions Box2D, whch would be cool to see, but no Box2D directory either.

Am I simply looking in the wrong place?

-Ken

MikeHart

(Posted 2013) [#13]

I will check, maybe i have forgotten to include it. Sorry.

MikeHart

(Posted 2013) [#14]

Ok, I have uploaded a new backage. This time, WITH the box2D and json module. Sorry for the confusion.

ordigdug

(Posted 2013) [#15]

I expanded this example a bit and included some additional comments. Mike, feel free to use all or part.

NOTE: Uses font.png & font.txt (Can grab from FathomEngine examples "examples/UI/MultilineText/MultilineText.data")

Strict

#rem
	Script:		FlashObject.monkey
	Description:	This sample script shows some ways on how to flash an object 
	Author: 	Michael Hartlef / Expanded by Douglas Williams 
	Version:      	1.01
	Data:		Uses font.png & font.txt from "examples/UI/MultilineText/MultilineText.data"
#End

' Import the fantomEngine framework which imports mojo itself
Import fantomEngine

' The _g variable holds an instance to the cGame class
Global _g:cGame

'***************************************
Class myObject Extends ftObject
	
	Field frameOnTime:Int = 100
	Field frameOn:Int = 0	

	Method New()
		Self.SetColor(Rnd(50,255), Rnd(50,255), Rnd(50,255))	'Set random color on object
	End
	Method myUpdate:Void()		'--obj4-- & --obj5-- 	'Called from "feEngine.OnObjectUpdate"
		Self.frameOnTime -= 1		
		
		If Self.frameOnTime < 0
			Self.frameOnTime = 100
			Self.frameOn = 1 - Self.frameOn	  '1-1=0 / 1-0=1
		Endif
		
		If Self.frameOn = 1 Then
			Self.SetScale(+0.01,True) 'Expand
		Else
			Self.SetScale(-0.01,True) 'Contract
		Endif
	End
End

'***************************************
' The cGame class controls the app
Class cGame Extends App
	' Create a field to store the instance of the cEngine class, which is an instance
	' of the ftEngine class itself
	Field fE:cEngine
	
	'------------------------------------------
	Method OnCreate:Int()
		' Set the update rate of Mojo's OnUpdate events to 60 FPS
		SetUpdateRate(60)
		
		' Seed the random number generator
		Seed = Millisecs()
		
		' Create an instance of the fantomEngine, which was created via the cEngine class
		fE = New cEngine
		
		' Load a bitmap font
		Local font:ftFont = fE.LoadFont("font.txt")		
		
		' Create some objects and text labels
		 'obj1 - Outer flashing box
		Local obj1 := fE.CreateBox(100, 100, 100, 150, New myObject) '(width, height, x, y, Object)
		obj1.SetID(3)
		obj1.ActivateRenderEvent(True)		'Activates "ftEngine.OnObjectRender"
		obj1.ActivateUpdateEvent(False) 	'Deactivates "ftEngine.OnObjectUpdate" for this object
		
		Local txtObj1 := fE.CreateText(font, "obj1", 100, 150, fE.taCenterCenter)	'(Font, "txt", x, y, alignment)
		txtObj1.ActivateUpdateEvent(False)
		
		 'obj2 - Flashing box
		Local obj2 := fE.CreateBox(100, 100, 300, 150, New myObject)
		obj2.SetID(2)
		obj2.CreateTimer(0, 1000, -1)		'(timerID, duration, repeatCount[-1 = run forever]) 	'Utilizes "ftEngine.OnObjectTimer"
		obj2.ActivateUpdateEvent(False)

		Local txtObj2 := fE.CreateText(font, "obj2", 300, 150, fE.taCenterCenter)	
		txtObj2.ActivateUpdateEvent(False)
		
		 'obj3 - Fade IN and OUT circle
		Local obj3 := fE.CreateCircle(50, 100, 320, New myObject) 	'(radius, x, y, New myObject)
		obj3.CreateTransAlpha(0, 1675, False, 1)			'(transAlpha, duration, relative, transID)  	'Utilizes "ftEngine.OnObjectTransition"
		obj3.ActivateUpdateEvent(False)

		Local txtObj3 := fE.CreateText(font, "obj3", 100, 320, fE.taCenterCenter)	
		txtObj3.ActivateUpdateEvent(False)
		txtObj3.SetAlpha(0.2)
		
		 'obj4 - Shrink and Expand circle
		Local obj4 := fE.CreateCircle(50, 300, 320, New myObject)   
		'obj4.ActivateUpdateEvent(True) 	'Activates "ftEngine.OnObjectUpdate" 	**DEFAULT ACTION command not required**

		Local txtObj4 := fE.CreateText(font, "obj4", 300, 320, fE.taCenterCenter)	
		txtObj4.ActivateUpdateEvent(False)
		txtObj4.SetAlpha(0.2)
		
		 'obj5 - Combine Shrink & Expand with Fade IN & OUT circle
		Local obj5 := fE.CreateCircle(50, 200, 410, New myObject)
		obj5.CreateTransAlpha(0, 1675, False, 1)
		
		Local txtObj5 := fE.CreateText(font, "obj5", 200, 410, fE.taCenterCenter)
		txtObj5.ActivateUpdateEvent(False)
		txtObj5.SetAlpha(0.2)
				
		 'alpha1 - Outer flashing circle
		Local alpha1 := fE.CreateCircle(50, 500, 180, New myObject)
		alpha1.SetID(4)
		alpha1.SetColor(0,255,255)
		alpha1.ActivateRenderEvent(True)
		alpha1.ActivateUpdateEvent(False)
		alpha1.SetAlpha(1.0)
		
		Local txtAlpha1 := fE.CreateText(font, "Alpha=1", 500, 180, fE.taCenterCenter)
		txtAlpha1.ActivateUpdateEvent(False)
		
		 'alphaLess - Flashing alpha from 0.2 to 1.0 circle
		Local alphaLess := fE.CreateCircle(50, 500, 320, New myObject)
		alphaLess.SetColor(0,255,255)
		alphaLess.SetAlpha(0.2)
		alphaLess.SetID(2)
		alphaLess.CreateTimer(0, 1000, -1)
		alphaLess.ActivateUpdateEvent(False)
		
		Local txtAlphaLess := fE.CreateText(font, "Alpha=.2", 500, 320, fE.taCenterCenter)
		txtAlphaLess.ActivateUpdateEvent(False)
		txtAlphaLess.SetAlpha(0.2)
		
		Return 0
	End
	'------------------------------------------
	Method OnUpdate:Int()
		If KeyHit( KEY_CLOSE ) fE.ExitApp()
		' Determine the delta time and the update factor for the engine
		Local d:Float = Float(fE.CalcDeltaTime())/60.0

		' Update all objects of the engine
		If fE.GetPause() = False Then
			fE.Update(d)
		Endif
		Return 0
	End
	'------------------------------------------
	Method OnRender:Int()
		' Check if the engine is not paused
		If fE.GetPause() = False Then
			' Clear the screen 
			Cls 
		
			' Render all visible objects of the engine
			fE.Render()
		Endif
		Return 0
	End
End	

'***************************************
' The cEngine class extends the ftEngine class to override the On... methods
Class cEngine Extends ftEngine
	'------------------------------------------
	Method OnObjectRender:Int(obj:ftObject)		'--obj1-- & --alpha1--
		' This method is called when an object was being rendered
		Local o:myObject = myObject(obj)
		Local px:Float = o.GetPosX()
		Local py:Float = o.GetPosY()
		
		o.frameOnTime -= 1
		If o.frameOnTime < 0
			o.frameOnTime = 60
			o.frameOn = 1 - o.frameOn	'1-1=0 / 1-0=1
		Endif
		
		If o.frameOn = 1 Then
			If o.GetID() = 3 Then	'--obj1--
			DrawLine(px-55, py-55, px+55, py-55)	'Top       '(x1, y1, x2, y2)
			DrawLine(px-55, py+55, px+55, py+55)	'Bottom
			DrawLine(px-55, py-55, px-55, py+55)	'Left
			DrawLine(px+55, py-55, px+55, py+55)	'Right
			Endif
			
			If o.GetID() = 4 Then	'--alpha1--
			DrawCircle(px, py, 60)	'(x, y, radius)
			SetColor(0,0,0)			'Black
			DrawCircle(px, py, 58)
			SetColor(0,255,255)		'Aqua
			DrawCircle(px, py, 50)
			Endif
		Endif
		Return 0
	End
	'------------------------------------------
	Method OnObjectTimer:Int(timerId:Int, obj:ftObject) 
		' This method is called when an objects' timer was being fired
		If obj.GetID() = 2 Then  	'--obj2-- & --alphaLess--
			obj.SetAlpha(1-obj.GetAlpha())
		Endif
		Return 0
	End	
	'------------------------------------------
	Method OnObjectTransition:Int(transId:Int, obj:ftObject) 	'--obj3--
		' This method is called when an object finishes its transition
		obj.CreateTransAlpha(1.0-obj.GetAlpha(), 1675, False,1)	'(transAlpha, duration, relative, transID)
		Return 0
	End
	'------------------------------------------
	Method OnObjectUpdate:Int(obj:ftObject)		'--obj4-- & --obj5--
		' This method is called when an object finishes its update
		myObject(obj).myUpdate()
		Return 0
	End
End

'***************************************
Function Main:Int()
	' Create an instance of the cGame class and store it inside the global var 'g'
	_g = New cGame
	
	Return 0
End

MikeHart

(Posted 2013) [#16]

Thanks, I will include this sample inside the distribution.

ordigdug

(Posted 2013) [#17]

I noticed a few comment mistakes I made...they are fixed in above post.