Move from point A to B: best practice

Monkey Forums/Monkey Programming/Move from point A to B: best practice

mteo77

(Posted 2013) [#1]

Hello all, it's still me.
I am writing code to make objects move in different ways, and one of them is from A to B.
I have this code:

Class AtoB
	Field x:Float
	Field y:Float
	Field x1:Float
	Field y1:Float
	Field x2:Float
	Field y2:Float
	Field speed:Float
	Field angle:Float
	Method init()
		x1 = 100.0			'A position X
		y1 = 100.0			'A position Y
		x2 = 200.0				'B position X
		y2 = 400.0				'B position Y
		x = 0.0				'bullet position X
		y = 0.0				'bullet position Y
		speed = 6.0			'bullet speed
		angle = 0.0			'angle
		angle = ATan2( (y2 - y1), (x2 - x1))	'do it only one time in the setup
	End Method
	Method update()
		x = (x + (Cos(angle) * speed))
		y = (y + (Sin(angle) * speed))
	End Method
	Method render()
		DrawCircle x, y, 40
	End Method
End Class

Is it the best way to do it?
Problem is since i am going to use this code to move little bullets, and i know sin and cos and atan2 are cpu intensive,is there another way to do it?
I can't use arrays because the position is changed at update time based on where i am.

GfK	(Posted 2013) [#2]

If the bullet has a constant direction and speed, you can calculate an xStep and yStep from sin/cos and use that to move the bullet. That way you only need to use sin and cos once.

Jesse

(Posted 2013) [#3]

this should be more efficiently(same as what GFK said):

Strict

Class AtoB
	Field x:Float
	Field y:Float
	Field x1:Float
	Field y1:Float
	Field x2:Float
	Field y2:Float
	Field speed:Float
	Field angle:Float
	Field vx:Float
	Field vy:Float
	Method init()
		x1 = 100.0			'A position X
		y1 = 100.0			'A position Y
		x2 = 200.0				'B position X
		y2 = 400.0				'B position Y
		x = 0.0				'bullet position X
		y = 0.0				'bullet position Y
		speed = 6.0			'bullet speed
		angle = 0.0			'angle
		angle = ATan2( (y2 - y1), (x2 - x1))	'do it only one time in the setup
		vx = Cos(angle) * speed 'do it only one time in the setup  ******************************************
		vy = Sin(angle) * speed 'do it only one time in the setup  ******************************************
	End Method
	Method update()
		x = x + vx '**********************************************
		y = y + vy '**********************************************
	End Method
	
	Method render()
		DrawCircle x, y, 40
	End Method
End Class

mteo77

(Posted 2013) [#4]

Oh yes haven't thought about that!
Also i am wondering if i can store the results in an array, since i am going to use same direction everytime, so i can do the calculation during setup, and use the array with fixed results, so i can create my classes during run time with the fixed direction thats been done during setup,if it make any sense.
Trying it now.
Thanks for the help!

mteo77

(Posted 2013) [#5]

Hello.
I tried to put in an array the results and it worked wonderfully.
But now i have encountered another problem, i tried to port over some of the code i had ages ago in blitz3d over monkey, and while in blitz 3d is very fast (although not optimised) in monkey is really slow!

#rem
simple waypoint movement,
10/4/2013
#end

Import mojo

Global max_path_points:int = 10
Global pathx:Int[10]				' set up 20 path points
Global pathy:Int[10]				' -1 because arrays start at zero
Global current_path:Int
Global curveSmoothness:Int
Global ANGLE					'used to check for position
Global dist:Float			'distance between current and next coords
Global ang:Float				'used to check for path points	

Function Main()
	New Game
End Function
	
Class Game Extends App
	Field nemico:= New enemy
	Field movement_started:Bool
	Method OnCreate()
		movement_started = False
		current_path = 0
		curveSmoothness = 4
		arrayFilling()
		nemico.init(pathx[0], pathy[0])
		SetUpdateRate(60)
	End Method
	Method OnRender()
		Cls
		SetColor 200, 200, 200
		DrawText "Waypoints player....for testing enemy movements!Space to start, enter to stop!", 0, 0
		DrawText "Press up&down arrows keys To increase/decrease speed", 0, 30
		DrawText "Press right&left arrow keys to increase/decrease curve smoothness", 0, 40
		DrawText "Speed: " + nemico.speed, 200, 60
		DrawText "Curve smoothness: " + curveSmoothness, 300, 60
		draw_path_points()
		nemico.render()
	End Method
	Method OnUpdate()
		If KeyHit(KEY_RIGHT) Then nemico.speed = nemico.speed + 1
		If KeyHit(KEY_LEFT) Then nemico.speed = nemico.speed - 1
		If KeyHit(KEY_UP) Then curveSmoothness = curveSmoothness + 1
		If KeyHit(KEY_DOWN) Then curveSmoothness = curveSmoothness - 1
		If KeyHit(KEY_SPACE) And movement_started = False Then       'And path_counter>0 Then; if spacebar pressed then move rectangle
			current_path = 0                         		    'reset the current path to 0
			nemico.nextx = pathx[0]									'set the rectangles coords To the first path point
			nemico.nexty = pathy[0]
			movement_started = True								'set flag for movement started
			nemico.posx = pathx[0]
			nemico.posy = pathy[0]
		End If
		If KeyHit(KEY_ENTER) Then								'if the enter key is pressed then stop movement
			movement_started = False								'clear flag for movement
			nemico.nextx = pathx[0]									'set rectangle coords to the first path point
			nemico.nexty = pathy[0]
			current_path = 0  								'set current path to none exsistant
		End If
		If movement_started = True Then nemico.update() 							'draw the moving rectangle and move it
	End Method
End Class

Class actor
	Field nextx:Float
	Field nexty:Float
	Field posx:Float		'x coord
	Field posy:Float		'y coord
	Field speed:float		'speed
	Const Lbound:Int=0		'left boundary
	Const Rbound:Int = 640	'right boundary
	Const Ubound:Int=0		'up boundary
	Const Dbound:Int=480	'down boundary
End Class

Class enemy Extends actor
	Field ANGLE:Float			'used to check for position
	Field dist:Float			'distance between current and next coords
	Field ang:Float				'used to check for path points	
	Method init(x:Float, y:Float)
		posx = x 	'x position is equal from start position,otherwise everything will start at 0
		posy = y 	'same as above
		speed = 5
	End Method
	Method update()
		If current_path < max_path_points - 1
			ang = ATan2(pathy[current_path + 1] - pathy[current_path], pathx[current_path + 1] - pathx[current_path])
			nextx = nextx + Cos(ang) * speed
			nexty = nexty + Sin(ang) * speed
			If Abs(nextx - pathx[current_path + 1]) < 15 And Abs(nexty - pathy[current_path + 1]) < 15
				current_path = current_path + 1
				nextx = pathx[current_path]
				nexty = pathy[current_path]
			EndIf
		EndIf
		ANGLE = ATan2(nexty - posy, nextx - posx)
		dist = Sqrt( (posx - nextx) * (posx - nextx) + (posy - nexty) * (posy - nexty))	
		posx = posx + (Cos(ANGLE) / curveSmoothness) * (dist / curveSmoothness)
		posy = posy + (Sin(ANGLE) / curveSmoothness) * (dist / curveSmoothness)
	End Method
	Method render()
		DrawCircle posx, posy, 20									'function for drawing the pathpoints
	End Method
End Class

Function draw_path_points()
	Local loop
	For loop = 0 To 9										'loop through all the path points
		SetColor 100, 100, 200
		DrawRect pathx[loop], pathy[loop], 2, 2
		If loop < 9 Then								'do this loop while the loop value is less than the highest path value
			DrawRect pathx[loop + 1] - 1, pathy[loop + 1] - 1, 2, 2				'draw a rectangle at the path point so its central
			SetColor 50, 50, 150												'change drawing color
			DrawLine pathx[loop], pathy[loop], pathx[loop + 1], pathy[loop + 1]	'draw a line between the current point and the next one
		End If
	Next
End Function

Function arrayFilling()
	pathx[0] = 186
	pathy[0] = 89
	pathx[1] = 383
	pathy[1] = 153
	pathx[2] = 623
	pathy[2] = 204
	pathx[3] = 670
	pathy[3] = 272
	pathx[4] = 663
	pathy[4] = 384
	pathx[5] = 534
	pathy[5] = 435
	pathx[6] = 431
	pathy[6] = 415
	pathx[7] = 428
	pathy[7] = 357
	pathx[8] = 505
	pathy[8] = 296
	pathx[9] = 587
	pathy[9] = 323
End Function

Does anybody have an idea why the ball is moving in steps and not smooth?
Is it because the functions i am using are cpu intensive or because i am using the wrong ones(tried to copy the code from blitz3d)?

Jesse

(Posted 2013) [#6]

I think there is something you have to understand about Monkey. Monkey produces code that is native to the specific platform. That is, if you compile for html5 it will produce javascript and then the code is run by the native platform in this case the browser. now the javascript code will run at about the same speed whether it is produced by Monkey or you code it your self. so I hope you understand that it's not monkey that is slow but the target. try the code in Flash or GLFW and you will know what I mean.

Jesse

(Posted 2013) [#7]

AdamRedwoods

(Posted 2013) [#8]

HTML5 DrawText is slow. remove those lines and it's fast again.

muddy_shoes

(Posted 2013) [#9]

It's more to do with the SetColor before the text drawing. DrawText is just a bunch of image renders and colour filtering of images on the HTML5 target is slow.

mteo77

(Posted 2013) [#10]

Oh didn't know that SetColor was going to slow everything to a crawl.
Taking it off solved the problem.
Wasn't sure if it was because of my usage of those instructions or if i was missing something (in this case target specific commands).
Thanks for pointing it out.
Hopefully i can use that function to move waves of objects.
Trying it now.

mteo77

(Posted 2013) [#11]

Hello. I am trying to modify the move code to make the object stop when it reach destination and return a value.
I can't find a way to do it, every solution i have tried it doesnt work in a way or another.
The move code is:

	Method MoveTowards2:Bool(_x1, _y1, _x2, _y2)
		x1 = _x1				'start X
		y1 = _y1				'start Y
		x2 = _x2				'end X
		y2 = _y2				'end Y
		angle = ATan2( (y2 - y1), (x2 - x1))
		xstep = Cos(angle) * speed
		ystep = Sin(angle) * speed
		posx = posx + xstep
		posy = posy + ystep
		If posx > x2 Then posx = x2'not working!
		If posy > y2 Then posy = y2'not working!
	End Method

As you can see the last 2 statements should stop the movement...but it doesnt work for example if the destination is already lesser than the start.
Also i cant figure out how to return true once the method is finished (when object has reached destination).
Any suggestion?
Thanks.

Jesse

(Posted 2013) [#12]

keep track of the starting position, figure out the distance from the starting position to the destination. if the distanceTraveld >= destinationDistance set distanceTraveld = destinationDistance and return true else return false (or visa-versa which ever works for you) .

mteo77

(Posted 2013) [#13]

Oh haven't thought about comparing the distances!
That means a couple of sqrt computations extra...
Modified code here:

	Method MoveTowards2:Bool(_x1, _y1, _x2, _y2)
		x1 = _x1				'start X
		y1 = _y1				'start Y
		x2 = _x2				'end X
		y2 = _y2				'end Y
		angle = ATan2( (y2 - y1), (x2 - x1))
		xstep = Cos(angle) * speed
		ystep = Sin(angle) * speed
		posx = posx + xstep
		posy = posy + ystep
		'If posx > x2 Then posx = x2	'not working
		'If posy > y2 Then posy = y2	'not working
		TotDistance = Sqrt( (x2 - x1) * (x2 - x1) + (y2 - y1) * (y2 - y1))				'distance between start and end
		ActDistance = Sqrt( (posx - x1) * (posx - x1) + (posy - y1) * (posy - y1))		'distance between start and actual
		If ActDistance >= TotDistance		'if actual distance is equal or greater than total distance then  reset the actual pos to the target pos
			posx = x2
			posy = y2
		EndIf
	End Method

Thank you very much for the help.
Sadly those computations have to be done realtime as part of a proactive kind of movement, so can't really save them in a array.

Jesse

(Posted 2013) [#14]

but you don't have to do square root. keep the distance squared.


	Method MoveTowards2:Bool(_x1, _y1, _x2, _y2)
		x1 = _x1				'start X
		y1 = _y1				'start Y
		x2 = _x2				'end X
		y2 = _y2				'end Y
		angle = ATan2( (y2 - y1), (x2 - x1))
		xstep = Cos(angle) * speed
		ystep = Sin(angle) * speed
		posx = posx + xstep
		posy = posy + ystep
		'If posx > x2 Then posx = x2	'not working
		'If posy > y2 Then posy = y2	'not working
		TotDistance = ( (x2 - x1) * (x2 - x1) + (y2 - y1) * (y2 - y1))				'distance between start and end
		ActDistance = ( (posx - x1) * (posx - x1) + (posy - y1) * (posy - y1))		'distance between start and actual
		If ActDistance >= TotDistance		'if actual distance is equal or greater than total distance then  reset the actual pos to the target pos
			posx = x2
			posy = y2
		EndIf
	End Method

mteo77

(Posted 2013) [#15]

*thump* (head banging noise)
I think i am overdoing the calculations atm...
Again thanks for pointing it out!