How to check for double click?

Monkey Forums/Monkey Programming/How to check for double click?

Jeit	(Posted 2012) [#1]

Likely some simple command, but I have no idea how to check for double clicking. Just need to use it for an if statement

if doubleclick Then ...

Thanks

Jesse

(Posted 2012) [#2]

I don't know if this will be helpful to you. I created a mouse class that take care of double clicks as well as the frame at which the mouse was pressed and the frame at which the mouse was released.
there is probably somebody out here who has a better example
maybe you can extract something from here that can help you:


Import mojo


Global 	mouse			:Mouse = New Mouse

Const 	BUTTONLOCKED	:Int =  2
Const	BUTTONPRESSED	:Int =  1
Const	BUTTONFREE		:Int =  0

Const	REPEATTIME	:Int =250 'in milliseconds

Class Mouse
	Field 	x					:Int,
			y					:Int,
			pressed				:Int,
			pressed1			:Int,
			DoublePressed		:Int
	
	Field	oldx				:Int,
			oldy				:Int,
			oldpressed			:Int,
			oldpressed1			:Int
	
	Field	state				:Int,
			ClickCount			:Int,
			endTime				:Int

	Method Update:Void()
		oldx = x
		oldy = y
		oldpressed = pressed
		oldpressed1 = pressed1
		
		x = MouseX()
		y = MouseY() 
		pressed1 = MouseDown(0)  
		pressed = pressed1
		
		If oldpressed
			If pressed
				state = BUTTONLOCKED
			Else
				state = BUTTONFREE
			Endif
		Elseif pressed
			state = BUTTONPRESSED
		Endif
		
		DoublePressed = False
		
		If state = BUTTONPRESSED
			If ClickCount = 0
				ClickCount = 1 'first click
				endTime = Millisecs() + REPEATTIME
			Else'second click
				If Millisecs() < endTime 
					DoublePressed = True 
				Endif
				ClickCount = 0
			Endif
		Elseif Millisecs() > endTime
			ClickCount = 0
		Endif

	End Method
	
	Method InArea:Int(h:Int, v:Int, width:Int, height:Int)	
		If x < h Return False
		If x > (h+Width) Return False
		If y < v Return False
		If y > (v + Height) Return False
		Return True
	End Method

	Method DoubleClick:Int()
		Return DoublePressed
	End Method
	
	Method ButtonInUse:Int() 
		Return state = BUTTONLOCKED 
	End Method
	
	Method ButtonActivated:Int() 
		Return state = BUTTONPRESSED
	End Method
	
	Method ButtonReleased:Int()
		Return state = BUTTONFREE
	End Method
	
	Method moved:Int()
		Return  oldx <> x Or oldy <> y
	End Method
	
	Method MovedX:Int()
		Return oldx <> x
	End Method 
	
	Method MovedY:Int()
		Return oldy <> y
	End Method
	
	Method ThrustX:Int()
		Return x - oldx
	End Method
	
	Method ThrustY:Int()
		Return y - oldy
	End Method
	
End Class

you need to add mouse.Update() to the top of the "OnCreate" method.
and use mouse.DoubleClick() to check.

you can adjust the double click sensitivity by adjusting the value of "REPEATTIME".

Ferdi

(Posted 2012) [#3]

Here is my solution for double clicking. There is a BUT to this code though. Now your single click has a delay of 200ms. Well whatever number you put here:

If (Millisecs() - mouseHitTime) > 200 Then

May be someone has a solution that can do it without the delay. Anyway here is the code:

Import mojo

Class ClickGame Extends App

	Field mouseHit:Int = 0
	Field mouseHitTime:Int = 0

	Method OnCreate ()
		SetUpdateRate 60
	End Method

	Method OnUpdate ()

		If MouseHit(MOUSE_LEFT) > 0 Then
		
			mouseHit += 1
			mouseHitTime = Millisecs()
		
		End If
		
		If (Millisecs() - mouseHitTime) > 200 Then

			If mouseHit >= 4 Then
			
				Print "Quad Hit"
			
			Else If mouseHit >= 3 Then
			
				Print "Triple Hit"
				
			Else If mouseHit >= 2 Then

				Print "Double Hit"
		
			Else If mouseHit = 1 Then
		
				Print "Single Hit"
				
			End If
			
			mouseHit = 0

		End If

	End Method

	Method OnRender ()
		Cls 0, 0, 0
	End Method

End Class

Function Main ()
	New ClickGame
End Function

impixi

(Posted 2012) [#4]

Here's my solution (similar to Ferdi's):

Strict

Import mojo

Function Main:Int()
	
	New MyApp

	Return 0
End

Class MyApp Extends App

	Field clickCount:Int			'Click counter variable.
	Field clickStartMs:Int			'Starting click milliseconds variable.
	Field clickTimeout:Int = 250	'Timeout in milliseconds. (sensitivity).

	Method OnCreate:Int()

		'Initialise click handler variables.
		clickCount = 0
		clickStartMs = -1
		
		SetUpdateRate 60
		Return 0
	End
	
	Method OnUpdate:Int()

		If MouseHit(MOUSE_LEFT)
			'Set the starting milliseconds of the click if necessary.
			If (clickStartMs <= 0) 
				clickStartMs = Millisecs()
			Endif
			'Increment the click counter.
			clickCount += 1
		Endif
	
		'Check for click timeout. If it happens, then perform an action.
		If ((Millisecs() - clickStartMs) >= clickTimeout)
		
			If clickCount = 1 
				'Handle single click
				Print "Single click."
			Else
				If clickCount >= 2
					'Handle double click
					Print "Double click."
				Endif
			Endif
			
			'Reset click handler variables
			clickStartMs = -1
			clickCount = 0
			
		Endif
	
		Return 0
	End
	
	Method OnRender:Int()
	
		Cls 0, 0, 0
	
		Return 0
	End

End

Basically, count the number of clicks within a click-initiated time period, and handle accordingly.

TheRedFox

(Posted 2012) [#5]

I has something similar to do when looking for a double touch. I went for something general in the form of an EventRecorder and that allows for recording all kind of sequential behaviors that in turn trigger a condition.

[monkeycode]
Import diddy
Import geometry
Import monkey.math
Import debug

Class RecordEntry

Field location:HOPoint
Field pointer:Int
Field occuredOn:Int

Method New(x:Int,y:Int,pointer:Int)
Self.location = New HOPoint(x,y)
Self.pointer = pointer
Self.occuredOn = Millisecs()
End

End

Class EventRecorder

Field recordedQueue: ArrayList<RecordEntry>
Field doubleClickDetectionEnabled:Bool

Const DOUBLE_CLICK_SPATIAL_TOLERANCE := 20 '20 Pixels should be ok. To test.
Const DOUBLE_CLICK_TEMPORAL_TOLERANCE := 500 'in millisecs

Method New()
recordedQueue = New ArrayList<RecordEntry>

Self.Clear() 'Maybe Overkill FIXME
Self.DisableDoubleClickDetection()
End

Method Clear:Void()
recordedQueue.Clear()
End

Method EnableDoubleClickDetection()
Self.doubleClickDetectionEnabled = True
End

Method DisableDoubleClickDetection()
Self.doubleClickDetectionEnabled = False
End

Method Record(x,y,pointer)
recordedQueue.AddLast(New RecordEntry(x,y,pointer))
End

Method DoubleClickDetected:Bool(pointer:Int)
'RULE for double click: two last events recorded are
'more or less on the same place and close enough in time
'and for the same pointer
'and for the specified pointer // TODO

Local occured := false

If (doubleClickDetectionEnabled and (recordedQueue.Size > 1)) Then 'We need to have at least 2 things in the queue

Local last:RecordEntry = recordedQueue.Get(recordedQueue.Size-1)
Local penultimate:RecordEntry = recordedQueue.Get(recordedQueue.Size-2)

If (last.pointer = penultimate.pointer) Then
If ((last.occuredOn - penultimate.occuredOn) < DOUBLE_CLICK_TEMPORAL_TOLERANCE) Then
If (last.location.CloseEnough(penultimate.location,
DOUBLE_CLICK_SPATIAL_TOLERANCE)) Then
occured = true
'Consume
Self.Clear() 'Check how well this works...
EndIf
EndIf
EndIf

EndIf

Return occured

End
End
[/monkeycode]

Gerry Quinn

(Posted 2012) [#6]

Good idea taking into account the spatial tolerance. You might want to try to get it in terms of phyical distance (say 5mm) although in some cases that might have to be estimated.