Collisions?

Monkey Forums/Monkey Programming/Collisions?

Amon	(Posted 2012) [#1]

What is everyone else using for collisions?

Tri|Ga|De

(Posted 2012) [#2]

fantomEngine works like a charm.
And a lot of other stuff.

Amon	(Posted 2012) [#3]

A non framework method would be nice!

therevills

(Posted 2012) [#4]

Mostly rect collisions via hitboxes and ray casting for fast moving objects.

Amon	(Posted 2012) [#5]

Example?

therevills

(Posted 2012) [#6]

Check out Diddy's platformer example :P

http://code.google.com/p/diddy/source/browse/#svn%2Ftrunk%2Fexamples%2FPlatformer

Amon	(Posted 2012) [#7]

Have no idea wots goin on Phil!

NoOdle

(Posted 2012) [#8]

I've just implemented SAT Separating Axis Theorem in monkey. Works for all convex shapes including circles. It was fairly easy to implement and is really quick due to the algorithms early exit. I've also implemented AABB Axis Aligned Bounding Box and Orientated Bounding Box OBB for intersection tests. I'll be posting the code soon when I have cleaned it up and made some better examples showing how to use it. I will also make it completely framework independent to allow for easier integration into your projects.

There is also Box2D, this can be used for collision detection, you don't have to use the physics if you don't wan't to.

therevills

(Posted 2012) [#9]

Heres a really quick ray cast example:

Strict

Import mojo

' Store the device width and height
Global SCREEN_WIDTH%
Global SCREEN_HEIGHT%

' Game Width and Height
Const WIDTH#=512
Const HEIGHT#=256

Global game:MyGame

Function Main:Int()
	game = New MyGame
	Return 0
End

Class MyGame Extends App
	Field player:Player
	Field level:Level
	
	Method OnCreate:Int()
		level = New Level()
		player = New Player(level.playerX, level.playerY)
		
		' Store the device width and height
		SCREEN_WIDTH = DeviceWidth()
		SCREEN_HEIGHT = DeviceHeight()
		
		SetUpdateRate(60)
		Return 1
	End
	
	Method OnUpdate:Int()
		player.Update()
		Return 1
	End
	
	Method OnRender:Int()
		Cls
		PushMatrix 
		Scale SCREEN_WIDTH/WIDTH, SCREEN_HEIGHT/HEIGHT
		level.Draw()
		player.Draw()
		PopMatrix
		Return 1
	End
End

Class Level
	Const TILE_SIZE% = 16
	Field map:Tile[][]
	Field width%, height%
	Field playerX%, playerY%
	Field pixelWidth% = 0
	Field pixelHeight% = 0
	
	' 32 across
	Global level1:=[
		150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,
		150,0,0,0,0,0,0,0,0,0,0,0,0,0,0,124,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,150,
		150,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,150,
		150,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,124,0,0,0,0,0,0,0,0,0,0,0,0,0,0,150,
		150,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,150,
		150,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,124,0,0,0,0,0,0,0,0,0,0,0,0,0,150,
		150,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,150,
		150,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,150,
		150,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,150,
		150,0,0,0,0,0,0,0,0,0,0,124,0,0,0,16,124,16,124,16,0,0,0,0,0,0,0,0,0,0,0,150,
		150,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,150,
		150,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,150,
		150,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,150,
		150,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,150,
		150,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,150,
		150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150,150]
		
	Method New()
		width = 32
		height = 16
		
		pixelWidth = width * TILE_SIZE
		pixelHeight = height * TILE_SIZE
			
		map = TileArray(width, height)
		
		For Local x:Int = 0 To width - 1
			For Local y:Int = 0 To height - 1
				map[x][y] = New Tile((level1 [ x + y * width ] ))
			Next
		Next
		
		playerX = 50
		playerY = 200
	End
	
	Method Draw:Void()
		For Local x% = 0 To width - 1
			For Local y% = 0 To height - 1
				If map[x][y].frame > 0
					SetColor map[x][y].red, map[x][y].green, map[x][y].blue
					DrawRect Int(x * TILE_SIZE), Int(y * TILE_SIZE), TILE_SIZE, TILE_SIZE
				End
			Next
		Next
	End
	
	Method CheckCollision:Int(startX:Float, startY:Float, endX:Float, endY:Float)
		Local x1:Int = startX
		Local y1:Int = startY
		Local x2:Int = endX
		Local y2:Int = endY

		Local deltax:Int = Abs(x2 - x1)
		Local deltay:Int = Abs(y2 - y1)
		
		Local numpixels:Int, d:Int, dinc1:Int, dinc2:Int, xinc1:Int, xinc2:Int, yinc1:Int, yinc2:Int, x:Int, y:Int, i:Int
		Local xx:Int, cx:Int
		Local yy:Int, cy:Int
		Local tile:Int
		
		If deltax >= deltay 
			numpixels = deltax + 1
			d = (2 * deltay) - deltax
			dinc1 = deltay Shl 1
			dinc2 = (deltay - deltax) Shl 1
			xinc1 = 1
			xinc2 = 1
			yinc1 = 0
			yinc2 = 1
		Else 
			numpixels = deltay + 1
			d = (2 * deltax) - deltay
			dinc1 = deltax Shl 1
			dinc2 = (deltax - deltay) Shl 1
			xinc1 = 0
			xinc2 = 1
			yinc1 = 1
			yinc2 = 1
		End
		
		If x1 > x2
			xinc1 = -xinc1
			xinc2 = -xinc2
		End
		
		If y1 > y2 
			yinc1 = -yinc1
			yinc2 = -yinc2
		End
		
		x = x1
		y = y1

		For i = 1 To numpixels
			tile = GetCollisionTile(x, y)

			' exit when we have a collision
			If tile <> 0 Then
				cx = x
				cy = y
				Exit
			End
			
			If d < 0 
				d = d + dinc1
				x = x + xinc1
				y = y + yinc1
			Else
				d = d + dinc2
				x = x + xinc2
				y = y + yinc2
			End
		Next
		Return tile
	End
	
	Method GetCollisionTile:Int(x:Float, y:Float)
		If x < 0 Or x >= pixelWidth Or y < 0 Or y >= pixelHeight Then Return 0
		
		Local xx% = (Floor(x / TILE_SIZE)) 
		Local yy% = (Floor(y / TILE_SIZE))
		
		Return map[xx][yy].frame
	End
End

Class Tile
	Field frame:Int
	Field red%, green%, blue%	
	
	Method New(frame:Int=0)
		Self.frame = frame
		red = 255 - frame
		green = 255 - frame
		blue = 255 - frame
	End
End

Function TileArray:Tile[][](x_size:Int, y_size:Int)
	Local map:Tile[x_size][]
	For Local x:Int=0 Until x_size
	   map[x]=New Tile[y_size]
	Next
	Return map
End

Class Player
	Field x#, y#
	Field dx#, dy#
	Field speedX#, speedY#
	Field width%, height%
	
	Method New(x#, y#)
		Self.x = x
		Self.y = y
		speedX = 4
		speedY = 5
		width = 16
		height = 16
	End
	
	Method Draw:Void()
		SetColor 0,255,0
		DrawRect x - width / 2, y - height / 2, width, height
		SetColor 255, 255, 255
	End
	
	Method Update:Void()
		Local tempx:Float
		Local tempy:Float
		
		If KeyDown(KEY_UP)
			tempy = y - speedY
			If game.level.CheckCollision(x, y - height / 2, x, tempy) = 0
				y = tempy
			End
		Elseif KeyDown(KEY_DOWN)
			tempy = y + speedY
			If game.level.CheckCollision(x, y + height / 2, x, tempy) = 0
				y = tempy
			End
		End
		If KeyDown(KEY_RIGHT)
			tempx = x + speedX
			If game.level.CheckCollision(x + width / 2, y, tempx, y) = 0
				x = tempx
			End
		Elseif KeyDown(KEY_LEFT)
			tempx = x - speedX
			If game.level.CheckCollision(x - width / 2, y, tempx, y) = 0
				x = tempx
			End
		End
	End
End

Nobuyuki

(Posted 2012) [#10]

AABB collision is pretty straightforward to implement. If you want a very simple concept of collision to use, circle-to-circle collision is easy. If the distance between 2 circles is less than their combined radius lengths, then you can assume they're colliding. It's not the fastest thing in the world but it's easy to implement and can be explained in one sentence.

You'll need some faster stuff later on, so look into AABB collision. There are examples for polygon, ray-cast, and pixel-mask collision in the code examples, too, but they're a bit more complicated and cost more per frame to perform checks with.

Samah

(Posted 2012) [#11]

@Nobuyuki: It's not the fastest thing in the world but it's easy to implement and can be explained in one sentence.

How is that not fast?
[monkeycode]dx = x1-x2
dy = y1-y2
r = r1+r2
If dx*dx+dy*dy <= r*r Then ' collided[/monkeycode]

Amon	(Posted 2012) [#12]

How come after more than a year we still don't have an official solution regarding collisions for Monkey?

I know 3rd party methods do the job fine but an official solution would be better.

Raz	(Posted 2012) [#13]

I think collisions are too subjective to be included as a "thing" within Monkey.

Amon	(Posted 2012) [#14]

Well, similar collisions to blitzmax would be welcome.

therevills

(Posted 2012) [#15]

IMO there are too many different collision routines to be able to add them to Monkey. Use the right tool for the right job.

For general use rectangles overlap and circle-to-circle collisions should be fine for "most" games, and they are not hard to use and are very quick.

Amon	(Posted 2012) [#16]

Without using a framework like diddy or some other, how would I proceed to having these 2 recommended collision routines placed in a module that can be used much like AutoFit or the delta timer?

Erm! Yes! I need everyone to do it for me because I am lazy. :)

therevills

(Posted 2012) [#17]

2 recommended collision routines

I guess you are talking about rectangles overlap and circle-to-circle(?), these are two very simple functions:

[monkeycode]Function RectsOverlap:Bool(x1#, y1#, w1#, h1#, x2#, y2#, w2#, h2#)
If x1 > (x2 + w2) Or (x1 + w1) < x2 Then Return False
If y1 > (y2 + h2) Or (y1 + h1) < y2 Then Return False
Return True
End[/monkeycode]

[monkeycode]Function CircleOverlap:Bool(x1#, y1#, r1#, x2#, y2#, r2#)
dx = x1-x2
dy = y1-y2
r = r1+r2
If dx*dx+dy*dy <= r*r Then ' collided
Return True
End
Return False
End
[/monkeycode]

Amon	(Posted 2012) [#18]

Thanks Dude! Just tested this and it works a treat! :)

therevills

(Posted 2012) [#19]

And if you want you can do Circle-to-Rects too:

[monkeycode]Function CircleRectsOverlap:Bool(x1:Float, y1:Float, w1:Float, h1:Float, cx:Float, cy:Float, r:Float)
Local testX:Float = cx
Local testY:Float = cy
If testX < x1 Then testX = x1
If testX > (x1 + w1) Then testX = (x1 + w1)
If testY < y1 Then testY = y1
If testY > (y1 + h1) Then testY = (y1 + h1)
Return ((cx-testX) * (cx-testX) + (cy-testY) * (cy-testY)) < r * r
End
[/monkeycode]

Amon	(Posted 2012) [#20]

Lovely! Thanks Dude!

Nobuyuki

(Posted 2012) [#21]

@Samah: Oh, oops. I guess I could be doing a comparison without a square root operation, huh?

Samah

(Posted 2012) [#22]

@Nobuyuki�Oh, oops. I guess I could be doing a comparison without a square root operation, huh?

Sqrt is eeeeeeeeevil! ;-)