Monk or ted don't seem to be importing mojo

Monkey Forums/Monkey Programming/Monk or ted don't seem to be importing mojo

gstrekkie

(Posted 2012) [#1]

i'm not sure why this started happening but I keep getting the error "Type 'App' not found" when building/running any project that imports mojo. the console output at the bottom of ted reads below.

"/Applications/MonkeyPro/bin/trans_macos" -target=html5 -config=Debug -run "/Volumes/Data/Monkey Projects/Billiards/Billiards.monkey"
TRANS monkey compiler V1.36
Parsing...
Semanting...
/Volumes/Data/Monkey Projects/Billiards/Billiards.monkey<8> : Error : Type 'App' not found
Done.

the error is occurring at

Import mojo

Global Circles:List <circle>

Class Pool Extends App <<<<<<<<<<<<<compile stops here.

i have verified that mojo exists in the modules Directory and I have even recopied the folder as well. additionally I checked to see if ted is pointing to the monkey directory and it is. I'm currently running on a Mac pro with 10.7.4 any thoughts on this would be appreciated.

Jesse

(Posted 2012) [#2]

which version of monkey are you using?
have you updated to the latest version?

gstrekkie

(Posted 2012) [#3]

it is version 60 from about a month ago

therevills

(Posted 2012) [#4]

Can you redownload Monkey and put it in another location (eg MonkeyPro60) and try again from fresh?

gstrekkie

(Posted 2012) [#5]

I will give that a try

gstrekkie

(Posted 2012) [#6]

Still not working.. is it possible that updating to 10.7.4 caused something to break?
is it advisable to edit some config files or something?

Jesse

(Posted 2012) [#7]

do any of the demos that come with monkey work?

gstrekkie

(Posted 2012) [#8]

sorry for delay was traveling a few days. anyway the demos do indeed work and I tried to copy them to the same directory I have the other projects in and the demos still work. Curiouser and Curiouser...

therevills

(Posted 2012) [#9]

Can you create a small mojo example?

For example:
[monkeycode]Strict

Import mojo

Function Main:Int()
New MojoApp()
Return 0
End

Class MojoApp Extends App
Method OnCreate:Int()
SetUpdateRate(30)
Return 0
End

Method OnUpdate:Int()
Return 0
End

Method OnRender:Int()
DrawText("Hello Mojo", 10, 10)
Return 0
End
End[/monkeycode]
Does this work?

gstrekkie

(Posted 2012) [#10]

that particular example worked and oddly enough I tried placing the strict directive at the beginning and this caused the error to change as a result I removed the strict directive and Viola ! it compiled and ran. not sure why this would occur but i will include the source I was using below.

gstrekkie

(Posted 2012) [#11]

 

' By Joseph 'Phish' Humfrey

Import mojo

Global Circles:List <circle>

Class Pool Extends App

	Method OnCreate ()
		SetUpdateRate 60
		Circles = New List <circle>
		Seed = Millisecs ()
		Setup
	End

	Method OnUpdate ()

		UpdateCirclePhysics

		If MouseHit ()

			For Local c:circle = Eachin Circles
				Circles.Clear
			Next

			Setup

		Endif
		
	End

	Method OnRender ()

		Cls
		
		RenderCircles()
		
		DrawText "Press a mouse button to reset.", 10, 10
		DrawText "Press Esc to exit.", 10, 25

	End

End




'------------------------------------------
' Main DATA Class
'------------------------------------------
' This exact Class isn't supposed to be used
' Instead, you should use some of the fields
' in your own Class, Or just use this one
' For reference, To see what each Field does
Class circle
	Field x#, y#		'position
	Field dx#, dy#		'x And y speeds
	
	Field radius#		'radius of circle
	Field mass#			'mass of circle
End


'------------------------------------------
' SET UP BALLS INTO A POOL STYLE ARRANGEMENT
' For DEMO
'------------------------------------------
Function Setup ()

	Local ballTriangleSize=5

	For Local xloop = ballTriangleSize To 1 Step -1
		For Local yloop = 1 To xloop
			Local c:circle = New circle
			c.x = (5-xloop)*27 + 200
			c.y = yloop*31-(xloop*31)/2.0 + 300
			c.dx=0
			c.dy=0
			c.radius = 15
			c.mass = 50
			Circles.AddLast c
		Next
	Next

	'Cue ball (smaller so you know which it is :)
	Local cue:circle = New circle
	cue.x = 800
	cue.y = 300 +20
	cue.dx = -20
	cue.dy = Rnd(4)-2
	cue.radius = 14
	cue.mass = 50
	Circles.AddLast cue

End

Function Main ()
	New Pool
End









'------------------------------------------
Function UpdateCirclePhysics()
'------------------------------------------
' This is the Main physics Function For the
' circles. It contains the very basic
' movement physics as well as the collision
' response code.
'------------------------------------------

	For Local c:circle = Eachin Circles
	
		'update positions
		c.x=c.x+c.dx
		c.y=c.y+c.dy
		
		'gradually slow down
		c.dx=c.dx*0.99
		c.dy=c.dy*0.99
		
		'------------------------------------------
		'COLLISION CHECKING
		'------------------------------------------
		' Check each circle in the loop against
		' every other (c against c2)
		For Local c2:circle = Eachin Circles
		
			Local collisionDistance# = c.radius+c2.radius
			Local actualDistance# = Sqrt(Pow(c2.x-c.x, 2)+Pow(c2.y-c.y, 2))
			
			'Collided Or Not?
			If actualDistance<collisionDistance Then
				
				Local collNormalAngle#=ATan2(c2.y-c.y, c2.x-c.x)

				'Position exactly touching, no intersection
				Local moveDist1#=(collisionDistance-actualDistance)*(c2.mass/Float((c.mass+c2.mass)))
				Local moveDist2#=(collisionDistance-actualDistance)*(c.mass/Float((c.mass+c2.mass)))
				c.x=c.x + moveDist1*Cos(collNormalAngle+180)
				c.y=c.y + moveDist1*Sin(collNormalAngle+180)
				c2.x=c2.x + moveDist2*Cos(collNormalAngle)
				c2.y=c2.y + moveDist2*Sin(collNormalAngle)
				
				
				'------------------------------------------
				'COLLISION RESPONSE
				'------------------------------------------
				'n = vector connecting the centers of the circles.
				'we are finding the components of the normalised vector n
				Local nX#=Cos(collNormalAngle)
				Local nY#=Sin(collNormalAngle)
				
				'now find the length of the components of each movement vectors
				'along n, by using dot product.
				Local a1# = c.dx*nX  +  c.dy*nY
				Local a2# = c2.dx*nX +  c2.dy*nY
				
				'optimisedP = 2(a1 - a2)
				'             ----------
				'              m1 + m2
				Local optimisedP# = (2.0 * (a1-a2)) / (c.mass + c2.mass)
				
				'now find out the resultant vectors
				'r1 = c1.v - optimisedP * mass2 * n
				c.dx = c.dx - (optimisedP*c2.mass*nX)
				c.dy = c.dy - (optimisedP*c2.mass*nY)
				
				'r2 = c2.v - optimisedP * mass1 * n
				c2.dx = c2.dx + (optimisedP*c.mass*nX)
				c2.dy = c2.dy + (optimisedP*c.mass*nY)

			End If

		Next
		'------------------------------------------
		'------------------------------------------
		
		
		'Simple Bouncing off walls.
		If c.x<c.radius Then
			c.x=c.radius
			c.dx=c.dx*-0.9
		End If
		If c.x>DeviceWidth()-c.radius Then
			c.x=DeviceWidth()-c.radius
			c.dx=c.dx*-0.9
		End If
		If c.y<c.radius Then
			c.y=c.radius
			c.dy=c.dy*-0.9
		End If
		If c.y>DeviceHeight()-c.radius Then
			c.y=DeviceHeight()-c.radius
			c.dy=c.dy*-0.9
		End If
		
	Next

End





'------------------------------------------
Function RenderCircles()
'------------------------------------------
' Simple Function draws all the circles
' on the screen.
'------------------------------------------

	For Local c:circle = Eachin Circles
		If c.radius=15 Then SetColor 200, 50, 50 Else SetColor 255, 255, 255
		DrawOval c.x-c.radius, c.y-c.radius, c.radius*2, c.radius*2
	Next
	
End

therevills

(Posted 2012) [#12]

I tried placing the strict directive at the beginning and this caused the error to change as a result I removed the strict directive and Viola

Are you saying your code now compiles okay?

BTW edit you previous post and wrap your code in [ codebox ] [ /codebox ] tags (without the spaces).

BlackD

(Posted 2012) [#13]

The reason it doesn't work when Strict is on is because you're not declaring the types for your methods/functions.

eg:

Method OnCreate:Int()
Function RenderCircles:Void()

For each function, you need to determine its type based on what it returns.
:int (function returns integer)
:float (function returns float)
:void (function returns nothing)
:bool (function returns TRUE or FALSE)

An exception is your main() function, which MUST be an INT. Actually, all the built-in methods must be int. OnUpdate(), OnCreate(), OnRender() and any others that escape my attention.

Your variables are also missing :int :float, etc, although some have # which substitutes for :float. Example:

Local ballTriangleSize:int = 5
For Local xloop:int = ballTriangleSize To 1 Step - 1
For Local yloop:int = 1 To xloop

Finally, your code fixed, with Strict enabled.

Strict

Import mojo

Global Circles:List <circle>

Class Pool Extends App

Method OnCreate:Int()
SetUpdateRate 60
Circles = New List <circle>
Seed = Millisecs ()
Setup
Return 0
End

Method OnUpdate:Int()

UpdateCirclePhysics()

If MouseHit ()

For Local c:circle = Eachin Circles
Circles.Clear
Next

Setup

Endif
Return 0
End

Method OnRender:Int()

Cls

RenderCircles()

DrawText "Press a mouse button to reset.", 10, 10
DrawText "Press Esc to exit.", 10, 25
Return 0
End

End




'------------------------------------------
' Main DATA Class
'------------------------------------------
' This exact Class isn't supposed to be used
' Instead, you should use some of the fields
' in your own Class, Or just use this one
' For reference, To see what each Field does
Class circle
Field x#, y# 'position
Field dx#, dy# 'x And y speeds

Field radius# 'radius of circle
Field mass# 'mass of circle
End


'------------------------------------------
' SET UP BALLS INTO A POOL STYLE ARRANGEMENT
' For DEMO
'------------------------------------------
Function Setup:Void()

Local ballTriangleSize:int = 5

For Local xloop:int = ballTriangleSize To 1 Step - 1
For Local yloop:int = 1 To xloop
Local c:circle = New circle
c.x = (5-xloop)*27 + 200
c.y = yloop*31-(xloop*31)/2.0 + 300
c.dx=0
c.dy=0
c.radius = 15
c.mass = 50
Circles.AddLast c
Next
Next

'Cue ball (smaller so you know which it is :)
Local cue:circle = New circle
cue.x = 800
cue.y = 300 +20
cue.dx = -20
cue.dy = Rnd(4)-2
cue.radius = 14
cue.mass = 50
Circles.AddLast cue

End

Function Main:Int()
	New Pool
	Return 0
End









'------------------------------------------
Function UpdateCirclePhysics:Void()
'------------------------------------------
' This is the Main physics Function For the
' circles. It contains the very basic
' movement physics as well as the collision
' response code.
'------------------------------------------

For Local c:circle = Eachin Circles

'update positions
c.x=c.x+c.dx
c.y=c.y+c.dy

'gradually slow down
c.dx=c.dx*0.99
c.dy=c.dy*0.99

'------------------------------------------
'COLLISION CHECKING
'------------------------------------------
' Check each circle in the loop against
' every other (c against c2)
For Local c2:circle = Eachin Circles

Local collisionDistance# = c.radius+c2.radius
Local actualDistance# = Sqrt(Pow(c2.x-c.x, 2)+Pow(c2.y-c.y, 2))

'Collided Or Not?
If actualDistance<collisionDistance Then

Local collNormalAngle#=ATan2(c2.y-c.y, c2.x-c.x)

'Position exactly touching, no intersection
Local moveDist1#=(collisionDistance-actualDistance)*(c2.mass/Float((c.mass+c2.mass)))
Local moveDist2#=(collisionDistance-actualDistance)*(c.mass/Float((c.mass+c2.mass)))
c.x=c.x + moveDist1*Cos(collNormalAngle+180)
c.y=c.y + moveDist1*Sin(collNormalAngle+180)
c2.x=c2.x + moveDist2*Cos(collNormalAngle)
c2.y=c2.y + moveDist2*Sin(collNormalAngle)


'------------------------------------------
'COLLISION RESPONSE
'------------------------------------------
'n = vector connecting the centers of the circles.
'we are finding the components of the normalised vector n
Local nX#=Cos(collNormalAngle)
Local nY#=Sin(collNormalAngle)

'now find the length of the components of each movement vectors
'along n, by using dot product.
Local a1# = c.dx*nX + c.dy*nY
Local a2# = c2.dx*nX + c2.dy*nY

'optimisedP = 2(a1 - a2)
' ----------
' m1 + m2
Local optimisedP# = (2.0 * (a1-a2)) / (c.mass + c2.mass)

'now find out the resultant vectors
'r1 = c1.v - optimisedP * mass2 * n
c.dx = c.dx - (optimisedP*c2.mass*nX)
c.dy = c.dy - (optimisedP*c2.mass*nY)

'r2 = c2.v - optimisedP * mass1 * n
c2.dx = c2.dx + (optimisedP*c.mass*nX)
c2.dy = c2.dy + (optimisedP*c.mass*nY)

End If

Next
'------------------------------------------
'------------------------------------------


'Simple Bouncing off walls.
If c.x<c.radius Then
c.x=c.radius
c.dx=c.dx*-0.9
End If
If c.x>DeviceWidth()-c.radius Then
c.x=DeviceWidth()-c.radius
c.dx=c.dx*-0.9
End If
If c.y<c.radius Then
c.y=c.radius
c.dy=c.dy*-0.9
End If
If c.y>DeviceHeight()-c.radius Then
c.y=DeviceHeight()-c.radius
c.dy=c.dy*-0.9
End If

Next

End





'------------------------------------------
Function RenderCircles:Void()
'------------------------------------------
' Simple Function draws all the circles
' on the screen.
'------------------------------------------

For Local c:circle = Eachin Circles
If c.radius=15 Then SetColor 200, 50, 50 Else SetColor 255, 255, 255
DrawOval c.x-c.radius, c.y-c.radius, c.radius*2, c.radius*2
Next

End

It's a good idea to keep Strict on whenever possible. :)

+BlackD

therevills

(Posted 2012) [#14]

OT: Welcome BlackD to Monkey... I'm guessing you are BlackD from TOG, as Samah recalls talking to you about BlitzMax :) (I'm DangerMouse on TOG)

BlackD

(Posted 2012) [#15]

Thanks! Haha, yeah - one and the same. :) Finally trying to get my Monkey on to start making my mark on the mobile world. ^^ Or at the very least, to get some Flash games up on my currently empty website. :)

gstrekkie

(Posted 2012) [#16]

Sorry I didnt use the [ codebox ] in the body that I posted. I was windering how everyone was doing that and I thank everyone for their valuable insights I'm not sure why the code began working seemingly in a spontaneous manner other than the obvious error I got when merely adding strict to the top the code remained unchanged and began working the way it should once I removed the offending "Strict" mode. so all is well in the monkey universe now. Now I can get back to learning....