MAC address - can you get it?

Monkey Forums/Monkey Programming/MAC address - can you get it?

Leon Brown

(Posted 2012) [#1]

Is it possible to get the MAC address of the computer with Monkey? I'm specifically interested in this for Android, but other platforms will be handy later.

DruggedBunny

(Posted 2012) [#2]

Monkey definitely won't provide this in any way, but I've dabbled in Win32 IP/network adapter stuff before via PureBasic, and this PB code will show the MAC address of the PC it's run on -- very Win32-specific!


; IMPORTANT: Only for Windows XP and above! TURN DEBUGGER ON TO SEE OUTPUT!

; Only taking IPv4 protocol into account here...

; Use command line -> ipconfig to see subnet mask for each network adapter on your system...

Procedure.l IntFromAddress (ip$)
	ProcedureReturn inet_addr_ (@ip$)
EndProcedure

Procedure.s AddressFromInt (ip.l)
	ProcedureReturn PeekS (inet_ntoa_ (ip))
EndProcedure

#MAX_ADAPTER_ADDRESS_LENGTH = 8
#ERROR_ADDRESS_NOT_ASSOCIATED = 1228

#IF_TYPE_OTHER = 1 ; "Some other type of network interface"
#IF_TYPE_ETHERNET_CSMACD = 6 ; "An Ethernet network interface"
#IF_TYPE_ISO88025_TOKENRING = 9 ; "A token ring network interface"
#IF_TYPE_PPP = 23 ; "A PPP network interface"
#IF_TYPE_SOFTWARE_LOOPBACK = 24 ; "A software loopback network interface"
#IF_TYPE_ATM = 37 ; "An ATM network interface"
#IF_TYPE_IEEE80211 = 71 ; "An IEEE 802.11 wireless network interface. On Windows Vista and later, wireless network cards are reported as IF_TYPE_IEEE80211. On earlier versions of Windows, wireless network cards are reported as IF_TYPE_ETHERNET_CSMACD"
#IF_TYPE_TUNNEL = 131 ; "A tunnel type encapsulation network interface"
#IF_TYPE_IEEE1394 = 144 ; "An IEEE 1394 (Firewire) high performance serial bus network interface"

#IP_ADAPTER_DDNS_ENABLED = $1 ; "Dynamic DNS is enabled on this adapter"
#IP_ADAPTER_REGISTER_ADAPTER_SUFFIX = $2 ; "Register the DNS suffix for this adapter"
#IP_ADAPTER_DHCP_ENABLED = $4 ; "The Dynamic Host Configuration Protocol (DHCP) is enabled on this adapter"
#IP_ADAPTER_RECEIVE_ONLY = $8 ; "The adapter is a receive-only adapter"
#IP_ADAPTER_NO_MULTICAST = $10 ; "The adapter is not a multicast recipient" ; 
#IP_ADAPTER_IPV6_OTHER_STATEFUL_CONFIG = $20 ; "The adapter contains other IPv6-specific stateful configuration information"

#IfOperStatusUp = 1 ; "The interface is up and able to pass packets"
#IfOperStatusDown = 2; "The interface is down and not in a condition to pass packets. The IfOperStatusDown state has two meanings, depending on the value of AdminStatus member. If AdminStatus is not set to NET_IF_ADMIN_STATUS_DOWN and ifOperStatus is set to IfOperStatusDown then a fault condition is presumed to exist on the interface. If AdminStatus is set to IfOperStatusDown, then ifOperStatus will normally also be set to IfOperStatusDown or IfOperStatusNotPresent and there is not necessarily a fault condition on the interface."
#IfOperStatusTesting = 3 ; "The interface is in testing mode"
#IfOperStatusUnknown = 4 ; "The operational status of the interface is unknown"
#IfOperStatusDormant = 5 ; "The interface is not actually in a condition to pass packets (it is not up), but is in a pending state, waiting for some external event. For on-demand interfaces, this new state identifies the situation where the interface is waiting for events to place it in the IfOperStatusUp state."
#IfOperStatusNotPresent = 6 ; "A refinement on the IfOperStatusDown state which indicates that the relevant interface is down specifically because some component (typically, a hardware component) is not present in the managed system."
#IfOperStatusLowerLayerDown = 7 ; "A refinement on the IfOperStatusDown state. This new state indicates that this interface runs on top of one or more other interfaces and that this interface is down specifically because one or more of these lower-layer interfaces are down."

Structure IP_ADAPTER_ADDRESSES
	  
	;  union {ULONGLONG Alignment; struct {ULONG Length; DWORD IfIndex; } ; } ;
	
	Length.l ; unsigned
	IfIndex.l
	*Next.IP_ADAPTER_ADDRESSES
	*AdapterName
	*FirstUnicastAddress;.PIP_ADAPTER_UNICAST_ADDRESS
	*FirstAnycastAddress;.PIP_ADAPTER_ANYCAST_ADDRESS
	*FirstMulticastAddress;.PIP_ADAPTER_MULTICAST_ADDRESS
	*FirstDnsServerAddress;.PIP_ADAPTER_DNS_SERVER_ADDRESS
	*DnsSuffix;.PWCHAR
	*Description;.PWCHAR
	*FriendlyName;.PWCHAR
	PhysicalAddress.b [#MAX_ADAPTER_ADDRESS_LENGTH]
	PhysicalAddressLength.l
	Flags.l
	Mtu.l
	IfType.l
	OperStatus.l
	Ipv6IfIndex.l
	ZoneIndices.l [16]
	*FirstPrefix;.PIP_ADAPTER_PREFIX

; Vista-only from here! Ignoring for now...

;	TransmitLinkSpeed.q ; unsigned
;	ReceiveLinkSpeed.q ; unsigned
;	*FirstWinsServerAddress;.PIP_ADAPTER_WINS_SERVER_ADDRESS_LH
;	*FirstGatewayAddress;.PIP_ADAPTER_GATEWAY_ADDRESS_LH
;	Ipv4Metric.l ; unsigned
;	Ipv6Metric.l ; unsigned
;	Luid.IF_LUID
;	Dhcpv4Server.SOCKET_ADDRESS
;	CompartmentId.NET_IF_COMPARTMENT_ID
;	NetworkGuid.NET_IF_NETWORK_GUID
;	ConnectionType.NET_IF_CONNECTION_TYPE
;	TunnelType.TUNNEL_TYPE
;	Dhcpv6Server.SOCKET_ADDRESS
;	Dhcpv6ClientDuid.b [#MAX_DHCPV6_DUID_LENGTH]
;	Dhcpv6ClientDuidLength.l ; unsigned
;	Dhcpv6Iaid.l ; unsigned

; Server 2008-only from here!

;	*FirstDnsSuffix.PIP_ADAPTER_DNS_SUFFIX

EndStructure

Structure SOCKET_ADDRESS
	*lpSockaddr
	iSockaddrLength.l
EndStructure

Structure IP_ADAPTER_PREFIX

	; union { ULONGLONG Alignment; struct { ULONG Length; DWORD Flags; } ; } ;
	
	Length.l
	Flags.l
	
	*Next.IP_ADAPTER_PREFIX
	Address.SOCKET_ADDRESS
	PrefixLength.l

EndStructure  
  
  
dll = OpenLibrary (#PB_Any, "iphlpapi.dll")

If dll

	GetAdaptersAddresses = GetFunction (dll, "GetAdaptersAddresses")
	
	If GetAdaptersAddresses
	
		tablesize = SizeOf (IP_ADAPTER_ADDRESSES)
		*table.IP_ADAPTER_ADDRESSES = AllocateMemory (tablesize)
		
		valid = #False
		
		Repeat
		
			Select CallFunctionFast (GetAdaptersAddresses, #AF_INET, 0, #Null, *table, @tablesize)
				
				Case #NO_ERROR

					; Can exit loop now...
					
					valid = #True
		
				Case #ERROR_ADDRESS_NOT_ASSOCIATED
				
					Debug "Epic fail! Not associated, whatever that means..."
					End
					
				Case #ERROR_BUFFER_OVERFLOW
				
					; Increase buffer size and try again...
					
					*table = ReAllocateMemory (*table, tablesize)
		
				Case #ERROR_INVALID_PARAMETER

					Debug "Epic fail! Invalid parameter passed to GetAdaptersAddresses function!"
					End
							
				Case #ERROR_NOT_ENOUGH_MEMORY

					Debug "Epic fail! Not enough memory!"
					End
		
				Case #ERROR_NO_DATA

					Debug "Epic fail! No data, whatever that means..."
					End
					
				Default

					Debug "Epic fail! Try calling GetError for further information..."
					End
		
			EndSelect
		
		Until valid

	Else
		Debug "Couldn't get GetAdaptersAddresses handle"
	EndIf
	
Else
	Debug "Failed to open iphlpapi.dll"
EndIf

Debug ""

*info.IP_ADAPTER_ADDRESSES = *table

While *info

	Debug "Interface #" + Str (*info\IfIndex)
	Debug "Adapter name/GUID: " + PeekS (*info\AdapterName, -1, #PB_Ascii)
	
	Debug "Description: " + PeekS (*info\Description, -1, #PB_Unicode)
	Debug "Friendly name: " + PeekS (*info\FriendlyName, -1, #PB_Unicode)
	Debug "MTU size: " + Str (*info\Mtu) + " bytes"
	
	Select *info\ifType
		Case #IF_TYPE_OTHER
			iftype$ = "Some other type of network interface"
		Case #IF_TYPE_ETHERNET_CSMACD
			iftype$ = "An Ethernet network interface"
		Case #IF_TYPE_ISO88025_TOKENRING
			iftype$ = "A token ring network interface"
		Case #IF_TYPE_PPP
			iftype$ = "A PPP network interface"
		Case #IF_TYPE_SOFTWARE_LOOPBACK
			iftype$ = "A software loopback network interface"
		Case #IF_TYPE_ATM
			iftype$ = "An ATM network interface"
		Case #IF_TYPE_IEEE80211
			iftype$ = "An IEEE 802.11 wireless network interface. On Windows Vista and later, wireless network cards are reported as IF_TYPE_IEEE80211. On earlier versions of Windows, wireless network cards are reported as IF_TYPE_ETHERNET_CSMACD"
		Case #IF_TYPE_TUNNEL
			iftype$ = "A tunnel type encapsulation network interface"
		Case #IF_TYPE_IEEE1394
			iftype$ = "An IEEE 1394 (Firewire) high performance serial bus network interface"
	EndSelect

	Debug "Interface type: " + iftype$
	
	; Get MAC address:
		
	If *info\PhysicalAddressLength
		mac$ = ""
		For byte = 0 To *info\PhysicalAddressLength - 1
			mac$ = mac$ + RSet (Hex (*info\PhysicalAddress [byte] & 255), 2, "0") + "-"
		Next
		mac$ = Left (mac$, Len (mac$) - 1) ; Strip last "-"
		Debug "MAC or physical address: " + mac$
	EndIf

	If *info\Flags & #IP_ADAPTER_DDNS_ENABLED
		Debug "Dynamic DNS is enabled on this adapter"
	EndIf

	If *info\Flags & #IP_ADAPTER_REGISTER_ADAPTER_SUFFIX
		Debug "Register the DNS suffix for this adapter"
	EndIf

	If *info\Flags & #IP_ADAPTER_DHCP_ENABLED
		Debug "The Dynamic Host Configuration Protocol (DHCP) is enabled on this adapter"
	EndIf

	If *info\Flags & #IP_ADAPTER_RECEIVE_ONLY
		Debug "The adapter is a receive-only adapter"
	EndIf

	If *info\Flags & #IP_ADAPTER_NO_MULTICAST
		Debug "The adapter is not a multicast recipient"
	EndIf

	If *info\Flags & #IP_ADAPTER_IPV6_OTHER_STATEFUL_CONFIG
		Debug "The adapter contains other IPv6-specific stateful configuration information"
	EndIf

	Select *info\OperStatus
		Case #IfOperStatusUp = 1
			status$ = "The interface is up and able to pass packets"
		Case #IfOperStatusDown = 2
			status$ = "The interface is down and not in a condition to pass packets"
		Case #IfOperStatusTesting = 3
			status$ = "The interface is in testing mode"
		Case #IfOperStatusUnknown = 4
			status$ = "The operational status of the interface is unknown"
		Case #IfOperStatusDormant = 5
			status$ = "The interface is not actually in a condition to pass packets (it is not up), but is in a pending state, waiting for some external event"
		Case #IfOperStatusNotPresent = 6
			status$ = "The relevant interface is down specifically because some component is not present in the managed system."
		Case #IfOperStatusLowerLayerDown = 7
			status$ = "This interface runs on top of one or more other interfaces and this interface is down specifically because one or more of these lower-layer interfaces are down"
	EndSelect

	Debug "Status: " + status$
	
	Debug ""

	*info = *info\Next

Wend

FreeMemory (*table)

End

However, this is a more platform-neutral MAC-getter, again in PB, I believe by a guy by the name of Flype:

Procedure.s GetMacAddr(IP.s) 
  n.l = 6
  Dim MacAddr.b(n)
  If SendARP_(inet_addr_(IP), 0, @MacAddr(0), @n) = #NO_ERROR 
    For i = 0 To n - 2
      MAC$ + RSet(Hex(MacAddr(i)&255),2,"0") + ":"
    Next
    ProcedureReturn MAC$ + RSet(Hex(MacAddr(i)&255),2,"0")
  EndIf
EndProcedure

I believe a SendARP-like function is available on most platforms that support TCP/IP, and inet_addr converts a string-IP ("192.168.0.1") to an integer, also available in some way on most platforms.

Anyway, although I can't help directly, perhaps this might help point you in the right direction...

Arthur

(Posted 2012) [#3]

Is there any way to get MAC address of the WiFi point which is used to connect to Internet from iOS device?