Map that uses objects as keys?

Monkey Forums/Monkey Programming/Map that uses objects as keys?

NoOdle

(Posted 2011) [#1]

Basically I want to try and have a Map that uses objects as a key, for example a predefined Class. The value would be a List.

Something like:

Map < myClassA, List< myClassB >>

Is this possible or am I trying to achieve the impossible?

NoOdle

(Posted 2011) [#2]

well some more fiddling and tinkering and this appears to work but I have no idea how or why....

Import mojo

Class NodeObject

	Field id : Int
	
	Method New( newID : Int )
		Self.id = newID
	End Method
	
End Class



Class Action
	
	Field id : Int
	
	Method New( newID : Int )
		Self.id = newID
	End Method
	
End Class




Class CustomMap<V> Extends Map< NodeObject, V>

	Method Compare : Int( a : NodeObject, b : NodeObject )
		If a < b Then Return 1
		If a > b Then Return -1
		If a = b Then Return 0
		Return -1
	End Method

End








Class MyApp Extends App

	

	Field myMap : CustomMap< List< Action >>
	
	Field node1 : NodeObject
	Field node2 : NodeObject

	
	Method OnCreate()


		SetUpdateRate 60
		
		
		Local testList : List<Action>
		Local testAction : Action


		myMap = New CustomMap< List<Action> >
				
		
		
		
		node1 = New NodeObject( 1 )
		testList = New List<Action>
		
		myMap.Set( node1, testList )
		
		testAction = New Action( 5 )	
		testList.AddLast( testAction )
		testAction = New Action( 6 )	
		testList.AddLast( testAction )	
				
		
		
		node2 = New NodeObject( 2 )
		testList = New List<Action>
		myMap.Set( node2, testList )	
		
			
		testAction = New Action( 10 )	
		testList.AddLast( testAction )
		testAction = New Action( 6 )	
		testList.AddLast( testAction )		
		
		
		
	End Method
	


	Method OnUpdate()




	End Method
	



	Method OnRender()
		Cls 255, 255, 255

		
		Local testL : List<Action> = myMap.Get( node1 )
		
		Local testA : Action
		Local y : Int = 10
		
		For testA = Eachin testL
			DrawText testA.id, 10, y
			y = y + 20
		Next
		


	End Method
	

End Class



Function Main()
	New MyApp()
End Function

AdamRedwoods

(Posted 2011) [#3]

In my opinion it works because your object has an "id" member which is a number value. This is how map can work by using numbered values. If "id" were an actual object like Image, it wouldn't work.

NoOdle

(Posted 2011) [#4]

Well thats what I initially thought, but im not using the id value in the compare method...

AdamRedwoods

(Posted 2011) [#5]

You're right, but I couldn't compile your version without converting Compare to:

Method Compare : Int( a : Object, b : Object )

And then if I use Image Classes for keys in NodeObject, it works. This is very important and interesting find. Good job!

my thought is I wonder if the Object type is allowed to be compared by pointer...

NoOdle

(Posted 2011) [#6]

my thought is I wonder if the Object type is allowed to be compared by pointer...

Yea that was what I was wondering as well...

marksibly

(Posted 2011) [#7]

Hi,

> And then if I use Image Classes for keys in NodeObject, it works. This is very important and interesting find. Good job!

This is a bug - Monkey should not be letting you use < and > with objects! The C++ targets support object 'pointer' comparisons, but none of the others do.

To use objects as keys, you'll need to implement some way to compare keys, eg:

Class Key
Public	
	Method New()
		id=cnt
		cnt+=1
	End
Private
	Field id
	Global cnt
End

Class KeyMap<T> Extends Map<Key,T>
	Method Compare( x:Key,y:Key )
		Return x.id-y.id
	End
End

NoOdle

(Posted 2011) [#8]

Thank you for clearing that up Mark, I was concerned with the use of < and > on objects. It felt wrong!

AdamRedwoods

(Posted 2011) [#9]

Doh!