Bullet Firing with Diddy - phone safe GC wise?

Monkey Forums/Monkey Programming/Bullet Firing with Diddy - phone safe GC wise?

Amon	(Posted 2011) [#1]

I'm a little stuck. Everything in my game so far is fine except bullet firing, it all seems to be borking bad because I'm not yet fully understanding everything about Monkey + Diddy.

Could I get a code example of a method of firing bullets from a ship using Diddy and also ensuring it is Phone safe GC wise i.e. not really New()ing a fresh bullet each time thus if you were doing this 100 times or so to account for enemies the GC wouldn't C64 a phones backside?

Please!

therevills

(Posted 2011) [#2]

Very quickly done:

Strict
Import diddy

Global gameScreen:GameScreen = New GameScreen()

Function Main:Int()
	game = New MyGame()
	Return 1
End

Class MyGame Extends DiddyApp
	Method OnCreate:Int()
		Super.OnCreate()
		gameScreen.PreStart()	
		Return 0
	End
End

Class GameScreen Extends Screen
	Field player:Player = New Player()
	
	Method New()
		name = "GameScreen"
	End
	
	Method Start:Void()
		player.x = SCREEN_WIDTH2
		player.y = SCREEN_HEIGHT - 20
		' create 10 bullets
		For Local i:Int = 0 To Bullet.maxBullets - 1
			player.bulletList.AddLast(New Bullet())
		Next
		game.screenFade.Start(50, False)
	End
	
	Method Render:Void()
		Cls
		player.Draw()
	End
	
	Method Update:Void()
		player.Controls()
		player.Update()
	End
End

Class Player Extends Sprite
	Field bulletList:ArrayList<Bullet> = New ArrayList<Bullet>

	Method Draw:Void()
		DrawRect x,y,10,10
		' draw bullets
		For Local i:Int = 0 To Bullet.maxBullets - 1
			Local b:Bullet = bulletList.Get(i)
			If Not b.dead
				b.Draw()
			End
		End
	End
	
	Method Update:Void()
		' move the bullets
		For Local i:Int = 0 To Bullet.maxBullets - 1
			Local b:Bullet = bulletList.Get(i)
			If Not b.dead
				b.Update()
			End
		End
	End
	
	Method Controls:Void()
		If KeyDown(KEY_LEFT)
			x = x - 2 * dt.delta
		End
		If KeyDown(KEY_RIGHT)
			x = x + 2 * dt.delta
		End
		If KeyHit(KEY_SPACE)
			For Local i:Int = 0 To Bullet.maxBullets - 1
				Local b:Bullet = bulletList.Get(i)
				If b.dead
					b.dead = False
					b.x = x
					b.y = y
					Exit
				End
			End
		End
	End
End

Class Bullet Extends Sprite
	Field dead:Bool = True
	Global maxBullets:Int = 10
	
	Method Draw:Void()
		If Not dead
			SetColor 255, 0, 0
			DrawOval x, y, 10, 10
			SetColor 255, 255, 255
		End
	End
	
	Method Update:Void()
		y = y - 4 * dt.delta
		If y < 0
			dead = True
		End
	End
End

Amon	(Posted 2011) [#3]

Love it, thanks! :)