MonkeyGL

Monkey Forums/Monkey Programming/MonkeyGL

AdamRedwoods

(Posted 2011) [#1]

OpenGL module for monkey. TOTALLY EXPERIMENTAL! TOTALLY AWESOME!
Updated: Nov 3,2011

Updated: Dec 17, 2011
*****
NOW THAT OPENGL IS IN MONKEY v51 BY DEFAULT, this version will be here for curiosity coders and archeologists.

Working Targets: GLFW/MINGW (pc, mac) and Android and iOS
Perhaps: Flash11(alchemy offers possible connection), WebGL (ES 2.0 minimum)
Not: XNA (would need a different command set since it's not openGL)

I'll update this thread when I get the other targets working and expand capabilities. See examples in post below.

** NOTES & LIMITATIONS **
- incomplete set, but easily extendable
- Mr. Sibly has the right to remove any of this
- depth buffer in glfw and iOS needs to be manually added :(
-- perhaps I can discuss with MSibly to see if I can't get these switches added in the config file
-- for glfw targets in your monkey folder/targets (ex, main.cpp at the very bottom)
-- glfwOpenWindow( w,h, 8,8,8,8,16,8, WINDOW_MODE )
-- for iOS depth buffer see post below

*******************
monkeyGL.monkey

''
'' monkeyGL
'' exposing opengl commands to monkey
''
'' targets: glfw, mingw, macos, win, android
'' inprogress: ios, webgl, flash11
''
'' 2011 - Adam Piette

'
Import mojo.graphics

Import "monkeyGL.${LANG}"


''OpenGL Constants
''

Const GL_POINTS				= $0000
Const GL_LINES					= $0001
Const GL_LINE_LOOP				= $0002
Const GL_LINE_STRIP				= $0003
'Const GL_TRIANGLES				= $0004 ''just testing
Const GL_TRIANGLE_STRIP			= $0005
Const GL_TRIANGLE_FAN			= $0006
Const GL_QUADS					= $0007
Const GL_QUAD_STRIP				= $0008
Const GL_POLYGON				= $0009

Const GL_VERTEX_ARRAY			= $8074
Const GL_NORMAL_ARRAY			= $8075
Const GL_COLOR_ARRAY			= $8076
Const GL_INDEX_ARRAY			= $8077
Const GL_TEXTURE_COORD_ARRAY		= $8078
Const GL_EDGE_FLAG_ARRAY			= $8079

Const GL_DEPTH_BUFFER_BIT			= $00000100
Const GL_ACCUM_BUFFER_BIT			= $00000200
Const GL_STENCIL_BUFFER_BIT			= $00000400

Const GL_TEXTURE_1D					= $0DE0
Const GL_TEXTURE_2D					= $0DE1

Const GL_RENDER					= $1C00
Const GL_FEEDBACK					= $1C01
Const GL_SELECT					= $1C02

Const GL_FLAT						= $1D00
Const GL_SMOOTH					= $1D01

Const GL_KEEP						= $1E00
Const GL_REPLACE					= $1E01
Const GL_INCR						= $1E02
Const GL_DECR						= $1E03

Const GL_VENDOR					= $1F00
Const GL_RENDERER					= $1F01
Const GL_VERSION					= $1F02
Const GL_EXTENSIONS					= $1F03

Const GL_S						= $2000
Const GL_T						= $2001
Const GL_R						= $2002
Const GL_Q						= $2003
Const GL_MODULATE					= $2100
Const GL_DECAL						= $2101

Const GL_TEXTURE_ENV_MODE			= $2200
Const GL_TEXTURE_ENV_COLOR			= $2201

Const GL_TEXTURE_ENV				= $2300

Const GL_EYE_LINEAR					= $2400
Const GL_OBJECT_LINEAR				= $2401
Const GL_SPHERE_MAP					= $2402

Const GL_TEXTURE_GEN_MODE			= $2500
Const GL_OBJECT_PLANE				= $2501
Const GL_EYE_PLANE					= $2502

Const GL_NEAREST					= $2600
Const GL_LINEAR					= $2601

Const GL_NEAREST_MIPMAP_NEAREST			= $2700
Const GL_LINEAR_MIPMAP_NEAREST			= $2701
Const GL_NEAREST_MIPMAP_LINEAR			= $2702
Const GL_LINEAR_MIPMAP_LINEAR				= $2703

Const GL_TEXTURE_MAG_FILTER				= $2800
Const GL_TEXTURE_MIN_FILTER				= $2801
Const GL_TEXTURE_WRAP_S					= $2802
Const GL_TEXTURE_WRAP_T					= $2803
Const GL_CLAMP							= $2900
Const GL_REPEAT						= $2901
Const GL_CLAMP_TO_EDGE					= $812F
Const GL_GENERATE_MIPMAP					= $8191
Const GL_GENERATE_MIPMAP_HINT				= $8192
	
Const GL_PERSPECTIVE_CORRECTION_HINT		= $0C50
Const GL_POINT_SMOOTH_HINT				= $0C51
Const GL_LINE_SMOOTH_HINT				= $0C52
Const GL_POLYGON_SMOOTH_HINT				= $0C53
Const GL_FOG_HINT						= $0C54
	
Const GL_ALPHA_TEST					= $0BC0
Const GL_ALPHA_TEST_FUNC				= $0BC1
Const GL_ALPHA_TEST_REF				= $0BC2

Const GL_DITHER					= $0BD0
Const GL_LIGHTING					= $0B50
Const GL_COLOR_MATERIAL				= $0B57

Const GL_EMISSION					= $1600
Const GL_SHININESS					= $1601
Const GL_AMBIENT_AND_DIFFUSE			= $1602
Const GL_COLOR_INDEXES				= $1603

Const GL_BLEND_DST					= $0BE0
Const GL_BLEND_SRC					= $0BE1
Const GL_BLEND						= $0BE2

Const GL_DEPTH_RANGE				= $0B70
Const GL_DEPTH_TEST					= $0B71
Const GL_DEPTH_WRITEMASK				= $0B72
Const GL_DEPTH_CLEAR_VALUE			= $0B73
Const GL_DEPTH_FUNC					= $0B74

Const GL_ZERO						= 0
Const GL_ONE						= 1
Const GL_SRC_COLOR					= $0300
Const GL_ONE_MINUS_SRC_COLOR			= $0301
Const GL_SRC_ALPHA					= $0302
Const GL_ONE_MINUS_SRC_ALPHA			= $0303
Const GL_DST_ALPHA					= $0304
Const GL_ONE_MINUS_DST_ALPHA			= $0305

Const GL_DST_COLOR					= $0306
Const GL_ONE_MINUS_DST_COLOR			= $0307
Const GL_SRC_ALPHA_SATURATE			= $0308

Const GL_MODELVIEW				= $1700
Const GL_PROJECTION				= $1701
Const GL_TEXTURE				= $1702

Const GL_BYTE						= $1400
Const GL_UNSIGNED_BYTE				= $1401
Const GL_SHORT						= $1402
Const GL_UNSIGNED_SHORT				= $1403
Const GL_INT						= $1404
Const GL_UNSIGNED_INT				= $1405
Const GL_FLOAT						= $1406
Const GL_2_BYTES					= $1407
Const GL_3_BYTES					= $1408
Const GL_4_BYTES					= $1409
Const GL_DOUBLE					= $140A
Const GL_DOUBLE_EXT					= $140A

Const GL_ARRAY_BUFFER				= $8892
Const GL_STREAM_DRAW				= $88E0
Const GL_STREAM_READ				= $88E1
Const GL_STREAM_COPY				= $88E2
Const GL_STATIC_DRAW				= $88E4
Const GL_STATIC_READ				= $88E5
Const GL_STATIC_COPY				= $88E6
Const GL_DYNAMIC_DRAW				= $88E8
Const GL_DYNAMIC_READ				= $88E9
Const GL_DYNAMIC_COPY				= $88EA

Const GL_AMBIENT					= $1200
Const GL_DIFFUSE					= $1201
Const GL_SPECULAR					= $1202
Const GL_POSITION					= $1203
Const GL_SPOT_DIRECTION				= $1204
Const GL_SPOT_EXPONENT				= $1205
Const GL_SPOT_CUTOFF				= $1206
Const GL_CONSTANT_ATTENUATION			= $1207
Const GL_LINEAR_ATTENUATION			= $1208
Const GL_QUADRATIC_ATTENUATION		= $1209

Const GL_NONE						= 0
Const GL_FRONT_LEFT					= $0400
Const GL_FRONT_RIGHT				= $0401
Const GL_BACK_LEFT					= $0402
Const GL_BACK_RIGHT					= $0403
Const GL_FRONT						= $0404
Const GL_BACK						= $0405
Const GL_LEFT						= $0406
Const GL_RIGHT						= $0407
Const GL_FRONT_AND_BACK				= $0408
Const GL_AUX0						= $0409
Const GL_AUX1						= $040A
Const GL_AUX2						= $040B
Const GL_AUX3						= $040C


Const GL_NO_ERROR					= 0
Const GL_INVALID_ENUM				= $0500
Const GL_INVALID_VALUE				= $0501
Const GL_INVALID_OPERATION			= $0502
Const GL_STACK_OVERFLOW			= $0503
Const GL_STACK_UNDERFLOW			= $0504
Const GL_OUT_OF_MEMORY				= $0505

Const GL_NEVER					= $0200
Const GL_LESS						= $0201
Const GL_EQUAL					= $0202
Const GL_LEQUAL					= $0203
Const GL_GREATER					= $0204
Const GL_NOTEQUAL					= $0205
Const GL_GEQUAL					= $0206
Const GL_ALWAYS					= $0207

#if TARGET = "glfw" Or TARGET = "mingw" Or TARGET = "ios"

''OpenGL 1.4, OpenGL ES 1.1


Extern

Class Pointer = "Pointer" 
	Field buffer:Int
	'Field fbuffer:Int
	Field sbuffer:Int
	Field stringBuffer:Int = "buffer"
End

Class TexturePointer
	Field texture:Int
End

Global GL_TRIANGLES = "GL_TRIANGLES" ''just experimenting


Function FloatPtr:Pointer(a:Float[]) = "CreateArrayFloatPointer"
Function IntPtr:Pointer(a:Int[]) = "CreateArrayIntPointer"
Function ShortPtr:Pointer(a:Int[]) = "CreateArrayShortPointer"
Function StringPtr:Pointer(a:String) = "CreateStringPointer"
Function LoadTextureGL:TexturePointer(path:String) = "LoadTexture"
Function RestoreMonkey2D()

#if HOST="macos" Or TARGET = "ios"
Function StopRenderFlush() = " app->GraphicsDevice()->primCount=0; //"
#else
Function StopRenderFlush() = " app->GraphicsDevice()->vertCount=0; //"
#endif

#if TARGET="ios"

Function InitMonkeyGL() = "[EAGLContext setCurrentContext:app->appDelegate->view->context]; glBindBuffer( GL_ARRAY_BUFFER, 0 );//"
Function glOrtho(left:Float, right:Float, bottom:Float, top:Float, near:Float, far:Float) = "glOrthof"
Function glFrustum(left:Float, right:Float, bottom:Float, top:Float, zNear:Float, zFar:Float) = "glFrustumf"
#else
#if HOST="winnt"
Function InitMonkeyGL() = "//" ''opengl 1.4 for intel desktop integrated chips
#else
Function InitMonkeyGL() = "glBindBuffer( GL_ARRAY_BUFFER, 0 );//" ''opengl 1.5 for macmini
#endif
Function glOrtho(left:Float, right:Float, bottom:Float, top:Float, near:Float, far:Float) = "glOrtho"
Function glFrustum(left:Float, right:Float, bottom:Float, top:Float, zNear:Float, zFar:Float) = "glFrustum"
#endif

Function glClearDepth(depth:Float) = "glClearDepth"
Function glClear(bits:Int) = "glClear"
Function glColor3f(x:Float,y:Float,z:Float) = "glColor3f"
Function glColor4f(x:Float,y:Float,z:Float, a:Float) = "glColor4f"
Function glBegin(glEnum:Int) = "glBegin"
Function glVertex3f(x:Float,y:Float,z:Float) = "glVertex3f"
Function glEnd() = "glEnd"
Function glEnable(glEnum:Int) = "glEnable"
Function glDisable(glEnum:Int) = "glDisable"
Function glTranslatef(x:Float,y:Float,z:Float) = "glTranslatef"
Function glRotatef(x:Float,y:Float,z:Float,w:Float) = "glRotatef"
Function glScalef(x:Float, y:Float, z:Float) = "glScalef"
Function glNormal3f(x:Float, y:Float, z:Float) = "glNormal3f"
Function glBlendFunc(src:Int, dst:Int ) = "glBlendFunc"
Function glHint(target:Int, mode:Int) = "glHint"

Function glPopMatrix()= "glPopMatrix"
Function glPushMatrix()= "glPushMatrix"

Function glEnableClientState(glEnum:Int) = "glEnableClientState"
Function glDisableClientState(glEnum:Int) = "glDisableClientState"
Function glMatrixMode(glEnum:Int) = "glMatrixMode"
Function glLoadIdentity() = "glLoadIdentity"

'Function gluPerspective(i:Float, ratio:Float, near:Float, far:Float)= "gluPerspective"

Function glBindTexture(target:Int, texture:Int) = "glBindTexture"
Function glTexEnvf(target:Int, pname:Int, param:Float) = "glTexEnvf"
Function glTexEnvi(target:Int, pname:Int, param:Int) = "glTexEnvi"
Function glTexParameterf(target:Int, pname:Int, param:Float) = "glTexParameterf"
Function glTexParameteri(target:Int, pname:Int, param:Int) = "glTexParameteri"

Function glVertexPointer(size:Int, type:Int, stride:Int, bufferPointer:Int) = "glVertexPointer"
Function glColorPointer(size:Int, type:Int, stride:Int, bufferPointer:Int) = "glColorPointer"
Function glTexCoordPointer(size:Int, type:Int, stride:Int, bufferPointer:Int) = "glTexCoordPointer"
Function glNormalPointer(type:Int, stride:Int, bufferPointer:Int) = "glNormalPointer"
Function glDrawArrays(mode:Int, first:Int, count:Int) ="glDrawArrays"
Function glDrawElements(mode:Int, count:Int, type:Int, bufferindices:Int) ="glDrawElements"
Function glBindBuffer(target:Int, buffer:Int) = " //glBindBuffer" '' not available in opengl 1.4?
Function glBufferData(target:Int, size:Int, bufferdata:Int, usage:Int) = "glBufferData"

Function glLightf(light:Int, pname:Int, param:Float) = "glLightf"

Function glFlush()  = "glFlush"
Function glCullFace(mode:Int) = "glCullFace"
Function glFogf(pname:Int, param:Float) = "glFogf"
Function glGetError:Int() = "glGetError"
Function glDepthFunc(param:Int) = "glDepthFunc"
Function glClearColor(r:Float, g:Float, b:Float, a:Float) = "glClearColor"


#endif

#if TARGET = "android" Or TARGET= "html5"

'' OpenGL ES 1.1

Extern

#if TARGET = "android"

Class Pointer
	Field buffer:Int
	Field fbuffer:Int
	Field ibuffer:Int
	Field stringBuffer:Int
End

Class TexturePointer
	Field surf:Int
	Field texture:Int
End

Global GL_TRIANGLES = "GL10.GL_TRIANGLES"

Function InitMonkeyGL() = "GL11 gl = (GL11)MonkeyGame.app.GraphicsDevice().gl; gl.glBindBuffer( gl.GL_ARRAY_BUFFER, 0 ); //" ''need this For android, may need For others
Function StopRenderFlush() = "MonkeyGame.app.GraphicsDevice().vcount =0; //"
Function FloatPtr:Pointer(a:Float[]) = "Pointer.CreateFloat"
Function IntPtr:Pointer(a:Int[]) = "Pointer.CreateInt"
Function ShortPtr:Pointer(a:Int[]) = "Pointer.CreateShort"
Function StringPtr:Pointer(a:String) = "Pointer.CreateString"
Function LoadTextureGL:TexturePointer(path:String) = "TexturePointer.Load"
Function RestoreMonkey2D() = "RestoreMonkey2D.Restore"

#else

''webgl stuff goes here


#endif

Function glClear(bits:Int) = "gl.glClear"
Function glClearDepth(depth:Float) = "gl.glClearDepthf"
Function glColor3f(x:Float,y:Float,z:Float) = "gl.glColor3f"
Function glColor4f(x:Float,y:Float,z:Float, a:Float) = "gl.glColor4f"
Function glBegin(glEnum:Int) = "gl.glBegin" ''not in opengl es
Function glVertex3f(x:Float,y:Float,z:Float) = "gl.glVertex3f"
Function glEnd() = "gl.glEnd"
Function glEnable(glEnum:Int) = "gl.glEnable"
Function glDisable(glEnum:Int) = "gl.glDisable"
Function glTranslatef(x:Float,y:Float,z:Float) = "gl.glTranslatef"
Function glRotatef(x:Float,y:Float,z:Float,w:Float) = "gl.glRotatef"
Function glScalef(x:Float, y:Float, z:Float) = "gl.glScalef"
Function glNormal3f(x:Float, y:Float, z:Float) = "gl.glNormal3f"
Function glBlendFunc(src:Int, dst:Int ) = "gl.glBlendFunc"
Function glHint(target:Int, mode:Int) = "gl.glHint"

Function glPopMatrix()= "gl.glPopMatrix"
Function glPushMatrix()= "gl.glPushMatrix"

Function glEnableClientState(glEnum:Int) = "gl.glEnableClientState"
Function glDisableClientState(glEnum:Int) = "gl.glDisableClientState"
Function glMatrixMode(glEnum:Int) = "gl.glMatrixMode"
Function glLoadIdentity() = "gl.glLoadIdentity"
Function glOrtho(left:Float, right:Float, bottom:Float, top:Float, near:Float, far:Float) = "gl.glOrthof" ''opengles
Function glFrustum(left:Float, right:Float, bottom:Float, top:Float, zNear:Float, zFar:Float) = "gl.glFrustumf"
'Function gluPerspective(i:Float, ratio:Float, near:Float, far:Float)= "gluPerspective"

Function glBindTexture(target:Int, texture:Int) = "gl.glBindTexture"
Function glTexEnvf(target:Int, pname:Int, param:Float) = "gl.glTexEnvf"
Function glTexEnvi(target:Int, pname:Int, param:Int) = "gl.glTexEnvi"
Function glTexParameterf(target:Int, pname:Int, param:Float) = "gl.glTexParameterf"
Function glTexParameteri(target:Int, pname:Int, param:Int) = "gl.glTexParameteri"

Function glVertexPointer(size:Int, type:Int, stride:Int, bufferPointer:Int) = "gl.glVertexPointer"
Function glColorPointer(size:Int, type:Int, stride:Int, bufferPointer:Int) = "gl.glColorPointer"
Function glTexCoordPointer(size:Int, type:Int, stride:Int, bufferPointer:Int) = "gl.glTexCoordPointer"
Function glNormalPointer(type:Int, stride:Int, bufferPointer:Int) = "gl.glNormalPointer"
Function glDrawArrays(mode:Int, first:Int, count:Int) ="gl.glDrawArrays"
Function glDrawElements(mode:Int, count:Int, type:Int, bufferindices:Int) ="gl.glDrawElements"
Function glBindBuffer(target:Int, buffer:Int) = "gl.glBindBuffer"
Function glBufferData(target:Int, size:Int, bufferdata:Int, usage:Int) = "gl.glBufferData"

Function glLightf(light:Int, pname:Int, param:Float) = "gl.glLightf"

Function glFlush()  = "gl.glFlush"
Function glCullFace(mode:Int) = "gl.glCullFace"
Function glFogf(pname:Int, param:Float) = "gl.glFogf"
Function glGetError:Int() = "gl.glGetError"
Function glDepthFunc(param:Int) = "gl.glDepthFunc"
Function glClearColor(r:Float, g:Float, b:Float, a:Float) = "gl.glClearColor"

#endif

Extern



Public

**********************
monkeyGL.cpp

//
// monkeyGL
// exposing opengl commands to monkey
//
//2011 adam piette

//
//Fake Pointers-- takes an array and returns a buffer
//
class Pointer : public Object {
	public:
	char * buffer;
	float * fbuffer;
	short * sbuffer;

	Array<short> d;
	
	virtual void nullfunction();
	
	Pointer() {
	}
	~Pointer() {
	}
	void mark(); //seems we dont need this
};
void Pointer::mark(){
	Object::mark();
	gc_mark(d);

}

//Object needs this for vtable
void Pointer::nullfunction() {
};


Pointer * CreateArrayFloatPointer(Array<float> t) {
	Pointer * p = new Pointer;
	p->buffer = (char*)&t.At(0);
	return p;
};
Pointer * CreateArrayIntPointer(Array<int> t) {
	Pointer * p = new Pointer;

	p->buffer = (char*)&t.At(0);
	return p;
};	
Pointer * CreateArrayShortPointer(Array<int> t) {
	Pointer * p = new Pointer;

	p->d = Array<short>(t.Length());
	for(int i=0; i<t.Length(); i++) {
		p->d[i] = t[i];
	}
	p->buffer = (char*)&p->d.At(0);
	return p;
};
Pointer * CreateStringPointer(String t) {
	Pointer * p = new Pointer;
	char* ascii = new char[wcslen( t.Data() ) + 1];
	wcstombs( ascii, t.Data(), wcslen( t.Data() ) );
	p->buffer = (char*)ascii;
	return p;
};	



//
//load a texture, then return texturepointer
// a kindof hack, because of private fields in monkey (ahem!)
//gxtkSurface* xsurf;
//
class TexturePointer : public Object {
	public:
	gxtkSurface* surf;
	int texture;
	
	virtual void nullfunction();
	TexturePointer() {
	};
	~TexturePointer() {
	};
	void mark();
};

void TexturePointer::mark(){
	Object::mark();
	gc_mark_q(surf);
	
}

//Object needs virtual for vtable
void TexturePointer::nullfunction() {
};

TexturePointer * LoadTexture( String path) {
	//gxtkSurface* xsurf;
	TexturePointer * t = new TexturePointer;

	t->surf = app->GraphicsDevice()->LoadSurface(path);
	
	if (t->surf) {
		t->texture = t->surf->texture;
	}
	return t;
}



//
//restore the default monkey2d settings
//
void RestoreMonkey2D() {
	app->GraphicsDevice()->BeginRender();
}

//end monkeyGL

******************
monkeyGL.java

//
// monkeyGL
// exposing opengl commands to monkey
//
//2011 adam piette

//
//Java Pointers-- takes an array and returns a buffer
//
class Pointer {

	public ByteBuffer buffer;
	public FloatBuffer fbuffer;
	public IntBuffer ibuffer;
	public ShortBuffer sbuffer;
	public String stringBuffer;
	
	public static Pointer CreateFloat(float[] arr) {
		Pointer p = new Pointer();

		p.buffer = ByteBuffer.allocateDirect( arr.length * 4 ).order( ByteOrder.nativeOrder() );

		p.fbuffer = p.buffer.asFloatBuffer();
		p.fbuffer.put( arr );

		p.buffer.position(0);
		p.fbuffer.position(0);
		return p;
	}
	public static Pointer CreateInt(int[] arr) {
		Pointer p = new Pointer();

		p.buffer = ByteBuffer.allocateDirect( arr.length * 4 ).order( ByteOrder.nativeOrder() );

		p.ibuffer = p.buffer.asIntBuffer();
		p.ibuffer.put(arr);
		p.buffer.position(0);
		p.ibuffer.position(0);
		return p;
	}
	
	public static Pointer CreateShort(int[] arr) {
		Pointer p = new Pointer();

		p.buffer = ByteBuffer.allocateDirect( arr.length * 4 ).order( ByteOrder.nativeOrder() );

		p.sbuffer = p.buffer.asShortBuffer();
		for(int i = 0; i < arr.length; i++) {
            p.sbuffer.put((short) arr[i]);
        }

		p.buffer.position(0);
		p.sbuffer.position(0);
		return p;
	}
	
	public static Pointer CreateString(String arr) {
		Pointer p = new Pointer();

		p.stringBuffer = arr;
		return p;
	}	

}


//
//load a texture, then return texturepointer
// a kindof hack, because of private fields in monkey (ahem!)
//gxtkSurface* xsurf;
//
class TexturePointer {
	public int texture;
	public gxtkSurface surf;
	
	static TexturePointer Load(String path) {
		TexturePointer t = new TexturePointer();
		t.texture = 0;
		
		t.surf = MonkeyGame.app.GraphicsDevice().LoadSurface(path);
		
		if (t.surf != null) {
			t.surf.Bind( (GL11)MonkeyGame.app.GraphicsDevice().gl );
			t.texture = t.surf.texId;
		}
		return t;
	}
}


//
//restore the default monkey2d settings
//
class RestoreMonkey2D {
	static void Restore() {
		MonkeyGame.app.GraphicsDevice().BeginRender( (GL11)MonkeyGame.app.GraphicsDevice().gl );
	}
}

AdamRedwoods

(Posted 2011) [#2]

Here's a simple example, two non-textured triangles:

Import mojo
Import monkeyGL

Function Main()
	Local myGame:Game = New Game
End Function

Class Game Extends App
	
	Field yrot:Float
	
	Method OnCreate()	
		SetUpdateRate 60
	End
	
	Method OnUpdate()
		Local ms:Int	
		If KeyHit(KEY_ESCAPE) Then Error ""
	End
	
	Method OnRender()
		Cls
		InitMonkeyGL() ''need this for android before any gl commands
		
	
		''switch to zdepth viewport
		glMatrixMode (GL_PROJECTION)
		glLoadIdentity ()
		glFrustum(0.0, 0.5, 0.5, 0.0, 1.0, 100.0)
		glMatrixMode (GL_MODELVIEW)
		glLoadIdentity ()
		
		glTranslatef(0.75,0.75,-3)
		glRotatef(yrot,0,1,1)
		'glTranslatef(DeviceWidth*0.5,DeviceHeight*0.5,-5)
		
		glColor4f(1.0,0.0,0.0,1.0)
		
		Local vertices:Float[] = [-0.5,-0.125,0.0, -0.25,-0.125,0.0, -0.375,0.125,0.0, 
			0.25,-0.125,0.0, 0.5,-0.125,0.0, 0.375,0.125,0.0]
		
		glBindBuffer( GL_ARRAY_BUFFER, 0 ) 
		glDisableClientState(GL_COLOR_ARRAY)
		glDisable( GL_TEXTURE_2D )
		glDisable( GL_BLEND )
		glDisableClientState(GL_TEXTURE_COORD_ARRAY )
		
		glEnableClientState(GL_VERTEX_ARRAY)
		glVertexPointer(3, GL_FLOAT, 0, FloatPtr(vertices).buffer ) ''What a pretty hack, eh?
		
		glDrawArrays(GL_TRIANGLES, 0, vertices.Length()/3) 
		glDisableClientState(GL_VERTEX_ARRAY)
		
		yrot +=2
		If yrot >360 Then yrot =0


		''switch back to 2d viewport
		glMatrixMode (GL_PROJECTION)
		glLoadIdentity ()
		glOrtho(0.0, DeviceWidth(), DeviceHeight(), 0.0, -1.0, 1.0)
		glMatrixMode (GL_MODELVIEW)
		glLoadIdentity ()
		
		RestoreMonkey2D() ''bring us back to do some drawing
		DrawText( "monkeyGL ", 1,0)
		
		
	End	
End

******************

Here's a major example of a textured cube:

Import mojo
Import monkeyGL

Function Main()
	Local myGame:Game = New Game
End Function

Class Game Extends App

	Field two_triangles_vertices:Float[] = [-0.5,-0.125,0.0, -0.25,-0.125,0.0, -0.375,0.125,0.0, 
			0.25,-0.125,0.0, 0.5,-0.125,0.0, 0.375,0.125,0.0]
	
	
	 Field cube_vertices:Float[] = [
		-1.0,-1.0,-1.0,		 -1.0, 1.0,-1.0,		  1.0, 1.0,-1.0,		  1.0,-1.0,-1.0,	
		 -1.0,-1.0, 1.0,		 -1.0, 1.0, 1.0,		  1.0, 1.0, 1.0,		  1.0,-1.0, 1.0,	
		 -1.0,-1.0, 1.0,		 -1.0, 1.0, 1.0,		  1.0, 1.0, 1.0,		 1.0,-1.0, 1.0,
		 -1.0,-1.0,-1.0,		 -1.0, 1.0,-1.0,		  1.0, 1.0,-1.0,		  1.0,-1.0,-1.0,
		 -1.0,-1.0, 1.0,		 -1.0, 1.0, 1.0,		  1.0, 1.0, 1.0,		  1.0,-1.0, 1.0,	
		 -1.0,-1.0,-1.0,		 -1.0, 1.0,-1.0,		  1.0, 1.0,-1.0,		  1.0,-1.0,-1.0  ]

	Field cube_indices:Int[] = [
		0,1,2,	0,2,3,	6,5,4,
		7,6,4,	14,13,9,	10,14,9,
		8,12,15,	8,15,11,	22,18,19,
		23,22,19,	16,17,21,	16,21,20 ]
	
	''0,1,2,	0,2,3,	6,5,4,	7,6,4,	14,13,9,	10,14,9,	8,12,15,	8,15,11,	22,18,19,	23,22,19,	16,17,21,	16,21,20 ]

	
	Field cube_uvs:Float[] = [
		0.0,1.0,	0.0,0.0,  1.0,0.0,  1.0,1.0,		
		1.0,1.0,  1.0,0.0,  0.0,0.0,  0.0,1.0,		
		0.0,1.0,  0.0,0.0,  1.0,0.0,  1.0,1.0,			
		0.0,0.0,  0.0,1.0,  1.0,1.0,  1.0,0.0,	
		0.0,1.0,  0.0,0.0,  1.0,0.0,  1.0,1.0,				
		1.0,1.0,  1.0,0.0,  0.0,0.0,  0.0,1.0 ]
	
	Field cube_normals:Float[] = [
		0.0,0.0,-1.0,		 0.0,0.0,-1.0,		0.0,0.0,-1.0,		 0.0,0.0,-1.0,
		0.0,0.0,1.0,		 0.0,0.0,1.0,		 0.0,0.0,1.0,		 0.0,0.0,1.0,		
		0.0,-1.0,0.0,		 0.0,1.0,0.0,		 0.0,1.0,0.0,		 0.0,-1.0,0.0,				
		0.0,-1.0,0.0,		 0.0,1.0,0.0,		 0.0,1.0,0.0,		 0.0,-1.0,0.0,	
		-1.0,0.0,0.0,		 -1.0,0.0,0.0,		 1.0,0.0,0.0,		1.0,0.0,0.0,				
		-1.0,0.0,0.0,		 -1.0,0.0,0.0,		 1.0,0.0,0.0,		 1.0,0.0,0.0	]
	
	Field cube_colors:Float[] = [
		0.0, 0.0, 0.0,1.0,   0, 0, 1,1,   0, 1, 1,1,   0, 1, 0,1,
		1, 0, 0,1,   1, 0, 1,1,   1, 1, 1,1,   1, 1, 0,1,
		0, 0, 0,1,   0, 0, 1,1,   1, 0, 1,1,   1, 0, 0,1,
		0, 1, 0,1,   0, 1, 1,1,   1, 1, 1,1,   1, 1, 0,1,
		0, 0, 0,1,   0, 1, 0,1,   1, 1, 0,1,   1, 0, 0,1,
		0, 0, 1,1,   0, 1, 1,1,   1, 1, 1,1,   1, 0, 1,1   ]
	
	Field yrot:Float
	Field mytex:TexturePointer
	Field myimage:Image
	Field verticesptr:Pointer
	Field colorptr:Pointer
	Field indicesptr:Pointer
	Field uvptr:Pointer
	Field normalptr:Pointer
	
	
	Method OnCreate()
		
		SetUpdateRate 60
		'myimage = LoadImage("copper.jpg")
		'Print myimage.Width()
		mytex = LoadTextureGL("copper.jpg")
		'Print mytex.texture
		
		InitMonkeyGL()
		glBindTexture(GL_TEXTURE_2D, mytex.texture )
		glTexEnvi( GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_MODULATE )
		glTexParameteri( GL_TEXTURE_2D,GL_TEXTURE_MAG_FILTER,GL_LINEAR )
		glTexParameteri( GL_TEXTURE_2D,GL_TEXTURE_MIN_FILTER,GL_LINEAR )

		glTexParameteri( GL_TEXTURE_2D,GL_TEXTURE_WRAP_S,GL_CLAMP_TO_EDGE )
		glTexParameteri( GL_TEXTURE_2D,GL_TEXTURE_WRAP_T,GL_CLAMP_TO_EDGE )
		glBindTexture(GL_TEXTURE_2D, 0 )
		
		verticesptr = FloatPtr(cube_vertices) ''What a pretty hack, eh?
		colorptr = FloatPtr(cube_colors)
		uvptr = FloatPtr(cube_uvs)
		normalptr = FloatPtr(cube_normals)
		indicesptr = ShortPtr(cube_indices)
		
	End
	
	Method OnUpdate()
		Local ms:Int

		If KeyHit(KEY_ESCAPE) Then Error ""
	End
	
	Method OnRender()
		Cls
		InitMonkeyGL() ''need this for android before any gl commands, includes a glBindBuffer(0)
		
		
		glClear(GL_DEPTH_BUFFER_BIT)
		glEnable( GL_DEPTH_TEST)
		glEnable( GL_BLEND )
		glBlendFunc( GL_ONE,GL_ONE_MINUS_SRC_ALPHA )
		
		''switch to zdepth viewport
		glMatrixMode (GL_PROJECTION)
		glPushMatrix()
		glLoadIdentity ()
		glFrustum(0.0, 0.5, 0.5, 0.0, 1.0, 100.0)
		glMatrixMode (GL_MODELVIEW)
		glLoadIdentity ()
		
		
		glTranslatef(2.0,2.0,-8)
		glRotatef(yrot,0,1,1)
			
		'glDisable( GL_TEXTURE_2D )
		glEnable( GL_TEXTURE_2D )
		glEnableClientState(GL_VERTEX_ARRAY)
		glEnableClientState(GL_TEXTURE_COORD_ARRAY )
		
		'glEnableClientState(GL_NORMAL_ARRAY)
		glDisableClientState(GL_NORMAL_ARRAY)
		glEnableClientState(GL_COLOR_ARRAY)
		'glDisableClientState(GL_COLOR_ARRAY )
		
		glNormal3f(0.0, 0.0, 1.0)
		'glColor4f(1.0,1.0,1.0,1.0)
		
		glBindTexture(GL_TEXTURE_2D, mytex.texture )

		glVertexPointer(3, GL_FLOAT, 0, verticesptr.buffer ) 
		glTexCoordPointer(2, GL_FLOAT, 0, uvptr.buffer )
		'glNormalPointer(GL_FLOAT, 0, normalptr.buffer )
		glColorPointer(4, GL_FLOAT, 0, colorptr.buffer ) ''rgba

		glDrawElements(GL_TRIANGLES, cube_indices.Length(), GL_UNSIGNED_SHORT, indicesptr.buffer )
		
		''disable states
		glDisableClientState(GL_VERTEX_ARRAY)
		glDisableClientState(GL_TEXTURE_COORD_ARRAY )
		glDisableClientState(GL_COLOR_ARRAY )
		glBindTexture(GL_TEXTURE_2D, 0 )
		glDisable( GL_TEXTURE_2D )
		glDisable( GL_DEPTH_TEST)
		glEnable( GL_BLEND )
		
		yrot +=2
		If yrot >360 Then yrot =0
		
		
		''switch back to 2d viewport
		glMatrixMode (GL_PROJECTION)
		glPopMatrix()
		'glOrtho(0.0, DeviceWidth(), DeviceHeight(), 0.0, -1.0, 1.0)
		glMatrixMode (GL_MODELVIEW)
		glLoadIdentity ()

		'StopRenderFlush() ''a hack to block monkey2d flush, may/may not need
		
		RestoreMonkey2D() ''bring us back to do some drawing
		SetColor(255,255,255)
		DrawText( "monkeyGL ", 10,10)
		
		
	End	
End

Uncle

(Posted 2011) [#3]

Yay youre a star. Will test this today :)

Just perfect :) Works very nicely on android.

outsider

(Posted 2011) [#4]

This is great. Works very good on my android Samsung i5800

therevills

(Posted 2011) [#5]

Cool...

Mr. Sibly has the right to remove any of this

I wouldnt worry about it, this is a legit mod :)

BTW change this code:

#if TARGET = "glfw" Or TARGET = "mingw"
'' Or TARGET = "ios"

Import "monkeyGL.cpp"

#elseif TARGET = "android"

Import "monkeyGL.java"

#endif

to this

Import "monkeyGL.${LANG}"

If your iOS code doesnt work you may need another cpp file, then you can use the ${TARGET} tag.

hardcoal

(Posted 2011) [#6]

great news! someone is doing that what ive being waiting for! 3d!!
respect for the first milestone

Aman	(Posted 2011) [#7]

Wonderful. For an experiment, I expected some serious performance issues. it is really good. Keep it up

AdamRedwoods

(Posted 2011) [#8]

Big update tomorrow, really tired right now but it's rockin. I think I've hacked Monkey to pieces. :D

MikeHart

(Posted 2011) [#9]

Awesome! Keep it up!

hardcoal

(Posted 2011) [#10]

Thumbs up for Adam!! doing a holly job :)

AdamRedwoods

(Posted 2011) [#11]

***MAJOR UPDATE*** Nov 1, 2011

As you can see above, I've changed everything, code examples and all.

Updates:
- textures
- glDrawElements()
- combined monkeyGL/ monkey 2D drawing
- enhanced pointers; you can now allocate buffers before the render routine (faster)
- expanded gl set

**Notes**
Whew! This overall was a bit of work to hack through monkey and all. Although I hacked it, I tried diligently to keep the interfacing clean for any changes that Mr. Sibly may want to make in his backend-- shouldn't effect monkeyGL at all.... except the garbage collector, as that was the hardest to figure out, but I'll keep an eye on that.

Don't forget-- you need to turn on the depth buffer for glfw and iOS to work. See above. Ask questions.

You're welcome to see how I extended monkey and made several trans.exe tricks to get code into various places. Notably the line:

Global GL_TRIANGLES = "GL_TRIANGLES" ''just experimenting

you can look at the exported code to see what that above is doing differently than the other gl constants.
The platform specific code are "pointers" which are just exposing arrays to the gl backend. Interesting stuff. The cpp code was notably challenging.

I didn't add all the gl constants and functions, but the rest should be very easy to add. If anyone does the complete set, send me the code and I'll post it.
Shaders? Probably doable, with a string pointer backend. Advanced users can give it a try. I just need to chill for a while then I'll look into it.

**Future**
I've only tested on Monkeyv44, so if others can verify it works on latest targets, thanks.
WebGL is slow as a dog, so we'll see if I can get to it-- but overall I'm not impressed by it.The demos use heavy GLSL shaders, which isn't available to all on the web. Flash 11/Stage3D looks better.
iOS-- I'll make sure it works when I get my MacMini upgraded to OSX10.6, about a week. I'll test on the simulator, but then would have to find a device to test on (future direction). Someone else could start and let me know what errors they're getting, I can usually work around it.

....and where does this lead me to next? Why miniB3D, of course!

//Adam of the Redwoods
www.adam.piettes.com
www.twopisoftware.com

Shinkiro1

(Posted 2011) [#12]

Ok, I just tested this and wow ... it worked. Never thought it would be so easy to implemenet an extra OpenGL module.
Btw: when using your 2nd example ios throws an error on line 3285 ("glFrustum was not declared in this scope")

Now just wrap it in a nice package, like miniB3D (like you said) and you shall become a hero ...

Hima	(Posted 2011) [#13]

This is brilliant! I was thinking about buying Blitzmax, considering how Monkey still not really that good at making PC games yet, but maybe I should wait for this instead? :D

AdamRedwoods

(Posted 2011) [#14]

Slight problems with osx and ios, but after I clear them up, everything should be solid.
My short buffer pointer is getting chewed up...

AdamRedwoods

(Posted 2011) [#15]

**** Update Nov 3 ****
Mac, iOS are working (on simulator). I haven't tested an actual iOS device.
Seems solid.

**** iOS Depth Buffer Note: ****
You'll need to turn the depth buffer on, which is a bit "codey". It may also decrease performance in 2D games on older hardware.

In the file: monkey/targets/ios/main.h
just under the "GLuint colorDepthbuffer;" add:

GLuint depthRenderbuffer;

In the file: monkey/targets/ios/main.mm
just after "glBindRenderBufferOES( ......, colorRenderbuffer);" add:

		// Depth buffer
		if (true) {
			glGenRenderbuffersOES(1, &depthRenderbuffer);

		}

in same file, just after "glGetRenderbufferParameterivOES(.... &backingHeight );" add:

	// Depth buffer
	if (true) {
		glBindFramebufferOES( GL_FRAMEBUFFER_OES,defaultFramebuffer );
		glBindRenderbufferOES(GL_RENDERBUFFER_OES, depthRenderbuffer);
		glRenderbufferStorageOES(GL_RENDERBUFFER_OES, GL_DEPTH_COMPONENT24_OES, backingWidth, backingHeight);
		glFramebufferRenderbufferOES(GL_FRAMEBUFFER_OES, GL_DEPTH_ATTACHMENT_OES, GL_RENDERBUFFER_OES, depthRenderbuffer);
		
		glBindRenderbufferOES( GL_RENDERBUFFER_OES,colorRenderbuffer );
		glFramebufferRenderbufferOES( GL_FRAMEBUFFER_OES,GL_COLOR_ATTACHMENT0_OES,GL_RENDERBUFFER_OES,colorRenderbuffer );
	}

in same file, just after "dealloc ...etc.... colorRenderbuffer = 0; }" add:

	if (depthRenderbuffer) {
		glDeleteRenderbuffersOES(1, &depthRenderbuffer);
		depthRenderbuffer = 0;
	}

enjoy!

charlie

(Posted 2011) [#16]

Oooh! This is interesting!

Looking forward to seeing how this progresses :)

Cheers
Charlie

Virtech

(Posted 2011) [#17]

Apologies for dumb question, but were am I supposed to put the monkeyGL.monkey, monkeyGL.java and monkeyGL.cpp files?

Right now I have all files including examples inside the same folder on the desktop. When trying to run either examples for html5 target I get the following error:

Parsing...
H:/Monkey/Projects/MonkeyGL/monkeyGL.monkey<13> : Error : File 'H:/Monkey/Projects/MonkeyGL/monkeyGL.js' not found.
Abnormal program termination. Exit code: -1

AdamRedwoods

(Posted 2011) [#18]

you can put the files in the same folder as your project, or you can create a new module folder "monkeyGL" in the monkey install folder (monkey/modules/monkeyGL).

There's no HTML5 target yet (webGL).

Hima	(Posted 2011) [#19]

You should put this up on some kind of version control. Github, Google Project, SVN, etc. I think it'd be much easier for us to follow all the changes :)

MikeHart

(Posted 2011) [#20]

On google code, a lot of us have our modules there. Join in please!