link a button to an object?

Monkey Forums/Monkey Programming/link a button to an object?

slenkar

(Posted 2011) [#1]

If I had 3 different classes,
dog,horse,cat

and then I had 3 buttons on screen with the same name as the classes,

Could I get monkey to create a new dog when I press the 'dog' button without explicitly programming it?

i.e.
without having to type
if button_pushed.name='dog'
local d:dog=new dog()
endif

could this be done with generics or interfaces?

Gerry Quinn

(Posted 2011) [#2]

No, but there's a guy selling a reflection solution.

Oh wait...

Samah

(Posted 2011) [#3]

You could do some kind of mapped templating...

Strict

Interface Cloneable
	Method Clone:Cloneable()
End

Class Dog Implements Cloneable
	Field foo:String = "asdfasdf"
	
	Method Clone:Cloneable()
		Return New Dog(Self)
	End
	
	Method New(template:Dog)
		' copy parameters from the template to the new instance (Self)
		Self.foo = template.foo
	End
End

Class Horse Implements Cloneable
	Field bar:String
	
	Method Clone:Cloneable()
		Return New Horse(Self)
	End
	
	Method New(template:Horse)
		' copy parameters from the template to the new instance (Self)
		Self.bar = template.bar
	End
End

Class Cat Implements Cloneable
	Field foobar:String
	
	Method Clone:Cloneable()
		Return New Cat(Self)
	End
	
	Method New(template:Cat)
		' copy parameters from the template to the new instance (Self)
		Self.foobar = template.foobar
	End
End

Global cloneables:StringMap<Cloneable> = New StringMap<Cloneable>

Function Main:Int()
	cloneables.Set("dog", New Dog)
	cloneables.Set("horse", New Horse)
	cloneables.Set("cat", New Cat)
	
	Local o:Cloneable = ButtonPressed("dog")
	' o is an instance of Dog, but you don't know that at runtime
	If Dog(o) <> Null Then
		' it's a dog
		Print "Dog!"
	Else
		Print "Not a dog!"
	End
	
	Return 0
End

Function ButtonPressed:Cloneable(buttonName:String)
	Return cloneables.Get(buttonName).Clone()
End

slenkar

(Posted 2011) [#4]

thanks samah,nice little example

where does template:dog come from?

Samah

(Posted 2011) [#5]

Since there's no way of getting the "class" from a string (at runtime), you'll need to make an instance of any type of class that you think might be needed and put it in a map. As long as that class has an instance method to create a new object, you can do it that way.

Simpler example:

Strict

Interface Creator
	Method Create:Object()
End

Class Dog Implements Creator
	Method Create:Object()
		Return New Dog
	End
End

Class Horse Implements Creator
	Method Create:Object()
		Return New Horse
	End
End

Class Cat Implements Creator
	Method Create:Object()
		Return New Cat
	End
End

Global classes:StringMap<Creator> = New StringMap<Creator>

Function Main:Int()
	classes.Set("dog", New Dog)
	classes.Set("horse", New Horse)
	classes.Set("cat", New Cat)
	
	Local o:Object = classes.Get("dog").Create()
	If Dog(o) <> Null Then
		' do something if it's a dog
	ElseIf Horse(o) <> Null Then
		' do something if it's a horse
	ElseIf Cat(o) <> Null Then
		' do something if it's a cat
	End
	Return 0
End