MouseHit problems

Monkey Forums/Monkey Programming/MouseHit problems

degac

(Posted 2011) [#1]

This is a simple code: click for the first coords, and the click for the 'end' coords.


'Monkey program : 21 May 2011 13:26:50
'Template       : template_new

Strict
Import mojo

Function Main:Int()
	New MyApp
	Return 0
End Function


Class MyApp Extends App
		Global x1:Float,y1:Float
		Global x2:Float,y2:Float
		
		Method OnCreate:Int()
			Print "Starting here..."
		
			SetUpdateRate 60
			Return 0
		End
		
		Method OnUpdate:Int()
			
			If MouseHit(MOUSE_LEFT)
				x1=MouseX()
				y1=MouseY()
				Local newpos:Int=0
				Print "Start: "+x1+" "+y1
				'GetLast()	'<---- try to uncomment - MouseHit seems to be ignored
				Print "Finish: "+x2+" "+y2
				
			End If
			
			Return 0
		End 
		
		Method GetLast:Int()
				Print "get last..."
				Local newpos:Int=0
				While newpos=0
					x2=MouseX()
					y2=MouseY()
'					If x1<>x2 Or y1<>y2 And MouseHit(MOUSE_LEFT) Then newpos=1 'tried this
					If x1<>x2 Or y1<>y2 Then newpos=1
					
					
				Wend
				Print "Last..."
		End Method 
		
		Method OnRender:Int()
			Cls
			DrawLine x1,y1,x2,y2
			Return 0
		End
End Class

For me it doesn't work.
If you comment out the GetLast() call OnUpdate() seems to be never catched...
Tested in HTML5 (FF and Chrome) and Flash (it bombs out!)

Soap	(Posted 2011) [#2]

You can't use the While loop like that. It will not continue drawing and picking up input. You need to think outside a single frame.


'Monkey program : 21 May 2011 13:26:50
'Template       : template_new

Strict
Import mojo

Function Main:Int()
	New MyApp
	Return 0
End Function


Class MyApp Extends App
		Global x1:Float,y1:Float
		Global x2:Float,y2:Float
		Field isMouseDown? = False
		
		Method OnCreate:Int()
			Print "Starting here..."
		
			SetUpdateRate 60
			Return 0
		End
		
		Method OnUpdate:Int()
			
			If MouseHit(MOUSE_LEFT)
				x1=MouseX()
				y1=MouseY()
				Local newpos:Int=0
				Print "Start: "+x1+" "+y1
				isMouseDown = True
			End If
			
			If Not MouseDown(MOUSE_LEFT) And isMouseDown = True Then
				isMouseDown = False
				Print "Stop: "+x2+" "+y2
			Endif
			
			If isMouseDown = True Then
				isMouseDown = True	
				x2=MouseX()
				y2=MouseY()			
			End
			
			Return 0
		End 
		
		Method OnRender:Int()
			Cls
			DrawLine x1,y1,x2,y2
			Return 0
		End
End Class

This code works for sure in HTML5, and I doubt it'll have any problems in anything else.

degac

(Posted 2011) [#3]

Ok, thanks for you help!