sort a list

Monkey Forums/Monkey Programming/sort a list

slenkar

(Posted 2011) [#1]

how do you sort a list?

i want to do z-ordering so i want to sort people by their y coordinate

therevills

(Posted 2011) [#2]

Ive managed to do it but by making my own list class, copying the monkey code and merging it with the BlitzMax list code... its not very generic and would be quite slow for Android...

Samah

(Posted 2011) [#3]

This will have sorting very soon (once I get my arse in to gear and actually add it):

http://code.google.com/p/diddy/source/browse/#svn%2Ftrunk%2Fsrc%2Fdiddy%2Fcollections

Edit: Quicksort added to ArrayList. Go for it! ;)
By default it will only sort Ints and Floats automatically. You need to provide your own AbstractComparator class to tell it how to sort your own objects. The wrapper classes are incomplete at the moment, so you'll need to declare ArrayList<IntObject> etc.
I'll finish the wrappers and add string sorting soonish.

Strict

Import diddy.collections

Function Main:Int()
	' create a list with a comparator
	Local lst:ArrayList<Person> = New ArrayList<Person>
	lst.Comparator = New PersonComparator
	
	' add some people
	For Local i:Int = 0 To 9
		lst.Add(New Person(Int(Rnd()*100)))
	Next
	
	' print them
	Print("Before sort")
	For Local p:Person = EachIn(lst)
		Print(p.y)
	Next
	
	' sort ascending
	Print("Sort ascending")
	lst.Sort()
	
	' print them
	For Local p:Person = EachIn(lst)
		Print(p.y)
	Next
	
	' sort descending
	Print("Sort descending")
	lst.Sort(True)
	
	' print them
	For Local p:Person = EachIn(lst)
		Print(p.y)
	Next
	
	Return 0
End

' person class
Class Person
	Field y:Int
	Method New(y:Int)
		Self.y = y
	End
End

' person comparator
Class PersonComparator Extends AbstractComparator
	' returns: o1<o2 negative, o1>o2 positive, o1=o2 zero
	Method Compare:Int(o1:Object, o2:Object)
		Return Person(o1).y - Person(o2).y
	End
End