error in HTML5 only.

Monkey Forums/Monkey Programming/error in HTML5 only.

Jesse

(Posted 2011) [#1]

some how an object becomes null after a certain amount of time of being executed.
this same code works fine executed for different platforms. It works as expected in GLFW and Flash.

tested on my Mac with google chrome and safari, fails with both on MonkeyPro V33.

Strict
Import mojo

'Create game Object
Class Tpoint
	Field x:Float
	Field y:Float
End Class


Class Tvector
	Field p0:Tpoint
	Field p1:Tpoint
	Field dx:Float
	Field dy:Float
	Field vx:Float
	Field vy:Float
	Field length:Float
	Field rx:Float
	Field ry:Float
	Field lx:Float
	Field ly:Float
	Field b:Float
	Field f:Float
	Field airf:Float
	Field lastTime:Float
	Field timeFrame:Float
	
	Method New()
		p0 = New Tpoint
		p1 = New Tpoint
	End Method
	
	Function Create:Tvector(x1:Float,y1:Float,x2:Float,y2:Float,b:Float=1.0,f:Float=1.0,airf:Float=1.0)
		Local v:Tvector = New Tvector
		v.p0.x = x1
		v.p0.y = y1
		v.p1.x = x2
		v.p1.y = y2
		v.b = b
		v.f = f
		v.airf = airf
		Return v
	End Function

	'Find all parameters For the vector
	Method update:Void()
		'x And y components
		'End point coordinate - start point coordinate
		vx = p1.x-p0.x
		vy = p1.y-p0.y
		'length of vector
		length = Sqrt(vx*vx+vy*vy)
		'normalized unti-sized components
		If (length>0)
			dx = vx/length
			dy = vy/length
		Else
			dx = 0
			dy = 0
		Endif
		'Right hand normal
		rx = -vy
		ry = vx
		'Left hand normal
		lx = vy
		ly = -vx
	End Method

	'find intersection point of 2 vectors
	Method findIntersection:Float(v2:Tvector)
		Local t1:Float,t2:Float
		'vector between starting points
		Local v3a:Tvector = New Tvector
		v3a.vx=v2.p0.x-p0.x
		v3a.vy=v2.p0.y-p0.y
		Local v3b:Tvector = New Tvector
		v3b.vx=p0.x-v2.p0.x
		v3b.vy=p0.y-v2.p0.y
		'If they are parallel vectors, Return big number
		If ((dx = v2.dx And dy = v2.dy) Or (dx = -v2.dx And dy = -v2.dy))
			Return 1000000
		Else
			t1 = v3a.perP(v2)/perP( v2)
			t2 = v3b.perP(Self)/v2.perP(Self)
		Endif
		If (t1>0 And t1<=1 And t2>0 And t2<=1)
			Return t2
		Endif
		Return 1000000
	End Method

	'calculate perp product of 2 vectors
	Method perP:Float(vb:Tvector)
		Return vx*vb.vy - vy*vb.vx
	End Method

	'find New vector bouncing from v2
	Method bounce:Tvector(v2:Tvector)
	
		'projection of v1 on v2
		Local proj1:Tvector = project(v2.dx, v2.dy)
		'projection of v1 on v2 normal
		Local proj2:Tvector = project(v2.lx/v2.length, v2.ly/v2.length)
		Local proj:Tvector = New Tvector
		'reverse projection on v2 normal
		proj2.vx *= -1
		proj2.vy *= -1
		'add the projections
		proj.vx = f*v2.f*proj1.vx+b*v2.b*proj2.vx
		proj.vy = f*v2.f*proj1.vy+b*v2.b*proj2.vy
		Return proj
	End Method
	
	'project vector v1 on unit-sized vector dx/dy
	Method project:Tvector(dx:Float, dy:Float)
	
		'find dot product
		Local dp:Float = vx*dx+vy*dy
		Local proj:Tvector = New Tvector
		'projection components
		proj.vx = dp*dx
		proj.vy = dp*dy
		Return proj
	End Method
	
End Class

Class Tgame
	Field stageW:Float
	Field stageH:Float
	Field maxV:Float
	Field gravity:Float
	Field myOb:Tvector
	Field bounce:Tvector
	Field time:Int
	
	Field wall:Tvector[4]
	
	Function Create:Tgame(w:Float,h:Float,maxV:Float,gravity:Float)
		Local g:Tgame = New Tgame
		g.stageW = w
		g.stageH = h
		g.maxV = maxV
		g.myOb = Tvector.Create(150,100,151,100,0.8,0.8,0.99)
		g.myOb.update()
		g.myOb.lastTime=Millisecs()
		g.gravity = gravity
		g.wall[0] = Tvector.Create( 50, 50,250, 50)
		g.wall[1] = Tvector.Create(250, 50,250,130)
		g.wall[2] = Tvector.Create(250,130, 50,130)
		g.wall[3] = Tvector.Create( 50,130, 50, 50)
		Return g
	End Function

	'Method to draw the ball and lines
	Method display:Void()
		For Local n:Tvector = Eachin wall
			DrawLine(n.p0.x, n.p0.y, n.p0.x+n.vx, n.p0.y+n.vy)
		Next
		DrawOval(myOb.p0.x-3,myOb.p0.y-3,6,6)
		DrawText myOb.p0.x+"   "+myOb.p0.y,10,250
		DrawText (myOb.vx +"   "+myOb.vy),10,270
	End Method

	Method update:Void()
	
		'start To calculate movement
		'add air resistance
		myOb.vx *= myOb.airf
		myOb.vy *= myOb.airf
		'dont let it go over Max speed
		If (myOb.vx>maxV)
			myOb.vx = maxV
		Else If (myOb.vx<-maxV)
			myOb.vx = -maxV
		Endif
		If (myOb.vy>maxV)
			myOb.vy = maxV
		Else If (myOb.vy<-maxV)
			myOb.vy = -maxV
		Endif
		'update the vector parameters
		updateObject(myOb)
		'time To collide something big
		time = 1000000
		'prepare collision
		bounce = Null
		'find collisions with walls
		For Local i:Tvector = Eachin wall
			Local t:Float = myOb.findIntersection(i)
			'If this has collision, save it
			If (t<time)
				'which wall To collide with
				bounce = i
				'save time
				time = t
			Endif
		Next
		'we have collision
		If bounce
			'set End point To intersection point
			myOb.p1.x = myOb.p0.x+myOb.vx*time
			myOb.p1.y = myOb.p0.y+myOb.vy*time
			'bounce
			Local newv:Tvector = myOb.bounce(bounce)
			'change movement vector
			myOb.vx = newv.vx
			myOb.vy = newv.vy
			'add New direction To End point
			myOb.p1.x += myOb.vx*(1.0-time)
			myOb.p1.y += myOb.vy*(1.0-time)
			'save the time
			time = 1.0-time
		Endif
		'reset Object To other side If gone out of stage
		If (myOb.p1.x>stageW)
			myOb.p1.x -= stageW
		Elseif (myOb.p1.x<0)
			myOb.p1.x -= stageW
		Endif
		If (myOb.p1.y>stageH)
			myOb.p1.y -= stageH
		Elseif (myOb.p1.y<0)
			myOb.p1.y += stageH
		Endif
		'make End point equal To starting point For Next cycle
		myOb.p0 = myOb.p1
		'save the movement without time
		myOb.vx /= myOb.timeFrame
		myOb.vy /= myOb.timeFrame
	End Method

	Method updateObject:Void(v:Tvector)
		'find time passed from last update
		Local thisTime:Float = Millisecs()
		Local time:Float = (thisTime-v.lastTime)/100.0
		'using time to move so multiply movement vector with time passed
		v.vx *= time
		v.vy *= time
		'add gravity, also based on time
		v.vy = v.vy+time*gravity
		'find End point coordinates
		v.p1.x = v.p0.x+v.vx
		v.p1.y = v.p0.y+v.vy
		'length of vector
		v.length = Sqrt(v.vx*v.vx+v.vy*v.vy)
		'normalized unti-sized components
		v.dx = v.vx/v.length
		v.dy = v.vy/v.length
		'Right hand normal
		v.rx = -v.vy
		v.ry = v.vx
		'Left hand normal
		v.lx = v.vy
		v.ly = -v.vx
		'save the Current time
		v.lastTime = thisTime
		'save time passed
		v.timeFrame = time
	End Method

End Class


Global game:Tgame

Class ball Extends App

	Method OnCreate:Int()
		game = Tgame.Create(300, 180, 10, 0.5)
		'calculate all parameters For the wall vectors
		game.wall[0].update()
		game.wall[1].update()
		game.wall[2].update()
		game.wall[3].update()
	  	SetUpdateRate 60
		Return 1
	End Method
	
	Method OnUpdate:Int()
		game.update()
		Return 1
	End Method
	
	Method OnRender:Int()
		'draw it
		Cls()
		game.display()
		Return 1	
	End Method
End Class




Function Main:Int()
	New ball
	Return 1
End Function

skid	(Posted 2011) [#2]

I think your program needs to be a little more sensitive to when Millisecs returns 0, which it can do on the first Update. If I add this code to the top and call Tick from OnUpdate I can't get it to break, if the Tick call is moved to after game.Update then the code breaks.


Global ftime%

Function Millisecs%()
Return ftime
End

Function Tick:Void()
ftime+=20
End

Jesse

(Posted 2011) [#3]

I don't know if we are talking about the same thing and excuse me if I miss interpret your post.
I know that the code is not logically correct but the problem is that it is returning a "NAN" for a an object variable value that is predefined once at the beginning of the application. It's the object "myOB" in the global "game" object and only values are moved in to it.

in which case it should return at least Zeros but Both of the values for the DrawText are displayed as "NAN" which should not happen at all as if myOb became null after a certain time. sometimes it takes a while sometimes it happens right away.

marksibly

(Posted 2011) [#4]

Hi,

Nans generally indicate a math error such as sqrt(-1). They propagate through any calculations too, so if an expression has just one nan in it, the result is nan.

And it's not unusual to get nans on one target but not another - it'll depend on what FPU modes are in effect.

I don't get what you mean by 'predefined once at the beginning of the application' though - the myOb.p0 and p1 fields are being constaly updated as far as I can tell, as are myOb.vx and vy.

But it's a fairly long piece of code - can you try trimming it down a bit?

marksibly

(Posted 2011) [#5]

Hi,

Well, sort of related to what skid was saying...

If I add this to updateObject:Void(v:TVector) after the "Local time:Float=..." calculation:

If time=0 Return

...it's fixes the nans here.

This may be to do with the new update timing code, which will now execute multiple 'OnUpdates' if necessary to catch up with any lost time. This also appears to happen in flash, and it's something you'll need to allow for. It's probably not happening in glfw/xna because there is much less 'performance noise' compared to browser based stuff.

I'm still a bit confused about why 'delta timing' is so popular - update rate should be reliable (over time anyway, to allow for glitches/spikes - and now that html5 has been fixed!) so 'time delta' should be constant.

Jesse

(Posted 2011) [#6]

I don't get what you mean by 'predefined once at the beginning of the application' though - the myOb.p0 and p1

I meant instantiate it as in "new" sorry.

Thanks Mark. I knew about -1 producing the imaginary number but I completely felt out of my mind.
on the other hand I did some test and it seems that Sqrt(0) is giving me that error of which I don't know if it's correct or not.

Jesse

(Posted 2011) [#7]

Its the division by zero following the sqrt.

solved thanks!

marksibly

(Posted 2011) [#8]

Hi,

You're right, sqrt(0) appears to be giving a nan in javascript and actionscript!

I think this may be because it's actually doing sqrt(-0). In FP, 0 can be positive or negative (I think, it's been a while...). Another source of nans can be 0/0 if I remember correctly.

Jesse

(Posted 2011) [#9]

yea same error.
is there a way to to test if a Sqrt is returning a value or a nan?

marksibly

(Posted 2011) [#10]

Hi,

Actually, I don't think it is the sqrt.

When time is 0, v.vx, v.vy, v.length all become 0.

It's the v.dx=v.vx/v.length stuff that comes a bit later that's causing the nans - ie: 0/0.

marksibly

(Posted 2011) [#11]

Hi,

To fix it, I think you'll have to:

* Check for elapsed time=0 in OnUpdate and do nothing, AND...

* Check for v.length>0 before updating v.dx,v.rx,v.lx etc. eg:

		If v.length>0
			'normalized unti-sized components
			v.dx = v.vx/v.length
			v.dy = v.vy/v.length
			'Right hand normal
			v.rx = -v.vy
			v.ry = v.vx
			'Left hand normal
			v.lx = v.vy
			v.ly = -v.vx
		Else
			v.dx=0
			v.dy=0
			v.rx=0
			v.ry=0
			v.lx=0
			v.ly=0
		Endif

This is because, even if time elapsed is >0, it's still possible for v.length (and therefore v.vx and v.vy) to be 0 - ie: if the ball is at the 'peak' of it's bounce and therefore momentarily stationery.

All in all, I'd say you're getting bitten by the 0/0 nan, not the sqrt nan.

And I still don't get the delta timing...

Jesse

(Posted 2011) [#12]

yea Mark. All of the problems are in the division by zero. I been checking all of the divisions and sooner or later they end up being a nan. it's all my bad logic.

Thanks, Thanks. Thanks......

I would had never created this problem if it had not being that I never expected to deal with "NAN"'s.

there is also an error in the t1 and t2 with the perps division.