Rotation Backwards?

Monkey Forums/Monkey Programming/Rotation Backwards?

therevills

(Posted 2011) [#1]

When I rotate using the drawImage rotation parameter its seems backwards...

When I rotate my ship by adding to rotation, in Monkey it rotates left, in BlitzMax it rotates right... I am doing something wrong?

BlitzMax code:

Strict

Global SCREEN_WIDTH% = 800
Global SCREEN_HEIGHT% = 600

Graphics SCREEN_WIDTH, SCREEN_HEIGHT
AutoMidHandle 1

Local player:TPlayer = New TPlayer
player.x = SCREEN_WIDTH / 2
player.y = SCREEN_HEIGHT / 2
player.image = LoadImage("ship.png")

Repeat

	player.update()

	Cls
	player.draw()
	DrawText "x = " + player.x, 10, 10
	DrawText "y = " + player.y, 10, 20
	DrawText "r = " + player.rotation, 10, 30	
	DrawText "s = " + player.speed, 10, 40		
	Flip
	
Until KeyHit(KEY_ESCAPE)

Type TPlayer
	Field x#, y#
	Field dx#, dy#, speed#
	Field rotation#
	Field scaleX# = 1, scaleY# = 1
	Field frame% = 0
	Field image:TImage
		
	Method update()
		If KeyDown(KEY_UP)
			Self.speed:+0.4
		End If
		If KeyDown(KEY_DOWN)
			Self.speed:-0.4
		End If
		If speed < -5 speed = -5
		If speed > 8 speed = 8
		
		
		If KeyDown(KEY_LEFT)
			Self.rotation:-2
		End If
		If KeyDown(KEY_RIGHT)
			Self.rotation:+2
		End If
		
		dx = Sin(rotation) * speed
        	dy = -Cos(rotation) * speed
		x:+dx
		y:+dy
		
		If x < 0 x = SCREEN_WIDTH
		If x > SCREEN_WIDTH x = 0
		If y < 0 y = SCREEN_HEIGHT
		If y > SCREEN_HEIGHT y = 0
	End Method
	
	Method draw()
		SetRotation rotation
		DrawImage(image, x, y)
		SetRotation 0
	End Method
	
End Type

Monkey code:

Strict

import mojo

Global SCREEN_WIDTH%
Global SCREEN_HEIGHT%

Function Main:int()
	new MyGame
	return 0
End Function

Class MyGame extends App
	Field player:Player
	
	Method OnCreate:Int()
		SCREEN_WIDTH = DeviceWidth()
		SCREEN_HEIGHT = DeviceHeight()
		
		player = new Player(LoadImage("ship.png", 1, Image.MidHandle), SCREEN_WIDTH / 2, SCREEN_HEIGHT / 2)
		
		SetUpdateRate 60
		return 0
	End Method
	
	Method OnLoading:Int()
		return 0
	End Method
	
	Method OnUpdate:Int()
		player.update()
		return 0
	End Method
	
	Method OnRender:Int()
		Cls
		player.draw()
		
		DrawText "x = " + player.x, 10, 10
		DrawText "y = " + player.y, 10, 20
		DrawText "r = " + player.rotation, 10, 30	
		DrawText "s = " + player.speed, 10, 40	
			
		return 0
	End Method
end class

Class Player
	Field x#, y#
	Field dx#, dy#, speed#
	Field rotation#
	Field scaleX# = 1, scaleY# = 1
	field frame% = 0
	Field image:Image
	
	Method New(img:Image, x#, y#)
		self.image = img
		self.x = x
		self.y = y
		self.rotation = 0
	End Method
	
	Method update:Void()
		If KeyDown(KEY_UP)
			self.speed+=0.4
		End If
		If KeyDown(KEY_DOWN)
			Self.speed-=0.4
		End If
		If speed < -5 speed = -5
		If speed > 8 speed = 8
		
		If KeyDown(KEY_LEFT)
			self.rotation-=2
		End If
		If KeyDown(KEY_RIGHT)
			self.rotation+=2
		End If
		
		dx = Sin(rotation) * speed
		dy = -Cos(rotation) * speed
		x+=dx
		y+=dy
		
		If x < 0 x = SCREEN_WIDTH
		If x > SCREEN_WIDTH x = 0
		If y < 0 y = SCREEN_HEIGHT
		If y > SCREEN_HEIGHT y = 0
	End Method
	
	Method draw:Void()
		DrawImage(image, x, y, rotation, scaleX, scaleY, frame)
	End Method
	
End Class

Yahfree

(Posted 2011) [#2]

I use these functions for rotation:

Function SetRotation (X:Float, Y:Float, angle:Float)
	PushMatrix
	Translate X, Y
	Rotate angle
	Translate -X, -Y
End

Function ResetRotation ()
	PopMatrix
End

therevills

(Posted 2011) [#3]

**** duplicate post ****

therevills

(Posted 2011) [#4]

Yeah Ive altered the Monkey code to "fix" this, but is it a bug or is it BlitzMax that is backwards?

DGuy	(Posted 2011) [#5]

I believe it's because the code is using global transformations in BlitzMax, but local transformations in Monkey.

Monkey has global (affects all) and local (affects one) transformations, while BlitzMax only has global transformations:

BlitzMax Global Transformations (Max2D):
----------------------------------------
SetRotation
SetScale
SetTransform


Monkey Global Transformations (mojo):
-------------------------------------
Rotate
Scale
SetMatrix
Transform
Translate


Monkey Local Transformations (mojo):
------------------------------------
DrawImage     => the rotation, scaleX, scaleY parameters
DrawImageRect => the rotation, scaleX, scaleY parameters

Try using mojo.Rotate instead of the DrawImage rotation parameter; that should give the effect your expecting.

therevills

(Posted 2011) [#6]

Ive tried both global and local:

Strict

import mojo

Global SCREEN_WIDTH%
Global SCREEN_HEIGHT%

Function Main:int()
	new MyGame
	return 0
End Function

Class MyGame extends App
	Field player:Player
	
	Method OnCreate:Int()
		SCREEN_WIDTH = DeviceWidth()
		SCREEN_HEIGHT = DeviceHeight()
		
		player = new Player(LoadImage("ship.png", 1, Image.MidHandle), 200, 100)
		
		SetUpdateRate 60
		return 0
	End Method
	
	Method OnLoading:Int()
		return 0
	End Method
	
	Method OnUpdate:Int()
		player.update()
		return 0
	End Method
	
	Method OnRender:Int()
		Cls
		player.draw()

		DrawImage(player.image, 100, 100, player.rotation, player.scaleX, player.scaleY, player.frame)
		
		DrawText "x = " + player.x, 10, 10
		DrawText "y = " + player.y, 10, 20
		DrawText "r = " + player.rotation, 10, 30	
		DrawText "s = " + player.speed, 10, 40	
			
		return 0
	End Method
end class

Class Player
	Field x#, y#
	Field dx#, dy#, speed#
	Field rotation#
	Field scaleX# = 1, scaleY# = 1
	field frame% = 0
	Field image:Image
	
	Method New(img:Image, x#, y#)
		self.image = img
		self.x = x
		self.y = y
		self.rotation = 0
	End Method
	
	Method update:Void()
		If KeyDown(KEY_UP)
			self.speed+=0.4
		End If
		If KeyDown(KEY_DOWN)
			Self.speed-=0.4
		End If
		If speed < -5 speed = -5
		If speed > 8 speed = 8
		
		If KeyDown(KEY_LEFT)
			self.rotation-=2
		End If
		If KeyDown(KEY_RIGHT)
			self.rotation+=2
		End If
		
		dx = Sin(rotation) * speed
		dy = -Cos(rotation) * speed
		x+=dx
		y+=dy
		
		If x < 0 x = SCREEN_WIDTH
		If x > SCREEN_WIDTH x = 0
		If y < 0 y = SCREEN_HEIGHT
		If y > SCREEN_HEIGHT y = 0
	End Method
	
	Method draw:Void()
		PushMatrix
		Translate x, y
		Rotate rotation
		DrawImage(image, 0, 0)
		PopMatrix
	End Method
	
End Class

Both looks backwards to me???

DGuy	(Posted 2011) [#7]

Hmmm, ... guess we need some clarification on what direction of rotation to expect from a positive angle.

Currently, a positive angle is producing a counter-clockwise rotation.

therevills

(Posted 2011) [#8]

http://en.wikipedia.org/wiki/Rotation_(mathematics)

Mathematically, using a positive angle it's counter clockwise from right, in Blitzmax it's clockwise from top.

I guess we are doing it the proper way now...

Jesse

(Posted 2011) [#9]

No Blitzmax is clockwise from right. 0 degrees is at 3 o'clock on Blitzmax.

therevills

(Posted 2011) [#10]

0 degrees is at 3 o'clock on Blitzmax.

Yep, my mistake - ta!