TexturePacker

Monkey Archive Forums/Digital Discussion/TexturePacker

ziggy

(Posted 2013) [#1]

Is it worth it?

Tri|Ga|De

(Posted 2013) [#2]

Yes!

ziggy

(Posted 2013) [#3]

thnx!

rIKmAN

(Posted 2013) [#4]

It's free isn't it, or do you mean time and effort?

Next time post less info, that took ages to read. :P

MikeHart

(Posted 2013) [#5]

The pro version isn't free but it is worth every cent! Imho it is the best tool on the market for creating spritesheets.

Tibit

(Posted 2013) [#6]

It is great!

Before I copied images manually to my monkey/graphics/ dir and did an optimized export to png before, cropped the image. Had to do this with every slight change made to an image.

Now I have a /Art/Game Projects/SuperCoolGame/ folder. In here I have all my images as fireworks layered pngs & psd files. I have added that folder to texture packer. After changing the "heavy" image I open texturepacker, click publish and the new texture (all textures!) is in game, optimized, trimmed edges (yet I still know the actual w/h).

What you get is:

1. Easier workflow
2. Game Loads faster
3. Reduce Render Calls (you still have to think about it, but it often makes it simple!)

I only wish I had been recommended it sooner. A must for all projects I do these day, even use it for projects in Flash Air.

ziggy

(Posted 2013) [#7]

The only thing that worries me a bit is if there's any good loader for Monkey (I don't mind writing my own). I mean a loader that does not rely on a XML parser that creates garbage when it parses the document. Maybe a simple cvs file could do it?
I'll be purchasing it anyway, as it is damn cheap for the work it does.

therevills

(Posted 2013) [#8]

There's a couple of loaders on here, including Diddy. Also the XML parsers don't really create garbage the Diddy one and Skn ones at least don't, which you can tell by the speed the parsing talked place.

Playniax

(Posted 2013) [#9]

Ignition has also basic support for TexturePacker.

Tri|Ga|De

(Posted 2013) [#10]

I use fantomEngine but if you look at this you can se my own code.

Skn3	(Posted 2013) [#11]

yeah therevills is right, the diddy and my xml module wont spam the gc. The only garbage created is with the disposable xml node structure. It would be pretty easy to make them keep a pool of reusable xml nodes. Probably not worth the optimization as you don't tend to constantly reload xml files during runtime.

Rushino

(Posted 2013) [#12]

Interesting. I should have a look to this before my images getting too big.

ziggy

(Posted 2013) [#13]

Thanks to all of you! I'll be packaing my game into textures very soon.

ziggy

(Posted 2013) [#14]

Can't find a working TexturePacker loader. The one based on skn config.monkey xml loader seems to not be working becouse of the <? and ?> xml header. Before I spend some hours fixing it, does anybody have a working current-version texturepacker loader that works with some of the available texturepacker exports and is working with latest monkey version?

Beaker

(Posted 2013) [#15]

You can strip the xml header (first line) and it should work fine.

ziggy

(Posted 2013) [#16]

I know that, but it was also refusing to load. Not sure what's wrong yet. ?? Maybe something in my code.

Tibit

(Posted 2013) [#17]

Standalone loader, from someone here in the community, not me.

textureLoader.monkey


Import mojo.app
Import mojo.graphics
Import monkey

'' libgdx sprite sheet loader
'' 
''this is best used in loading all textures, don't create during the game time, as it would create lag

Function LoadAtlas:TextureLoader(fn:String)
	Local atlas:TextureLoader = New TextureLoader
	If Not atlas.LoadTex(fn) Then Return Null
	Return atlas
End'CTextureAtlas

Class TextureLoader

Private

	Field tmap:StringMap<CSubTextureAtlas> = New StringMap<CSubTextureAtlas>
	Field texture:Image
	Field total:Int =0
	Field subimage:CSubTextureAtlas[]

	Method LoadTex:Int(fn:String)
		'Print "******BEGIN"
			If Not fn Return 0
		Local txtfile:String = fn[..(fn.FindLast("."))]+".txt"
		Local str:String=LoadString(txtfile)
			If Not str Then Return 0
		
		Local all:String[] = str.Split("~n")
			texture = LoadImage(all[0].Trim() ,1)
		If Not texture Then Return
		
		''count total
		For Local i:Int = 0 To all.Length()-1
			If all[i].Contains("xy:") Then total += 1
		Next
		
		''create sub images
		subimage = New CSubTextureAtlas[total+1]
		Local si:Int = 0
		Local nextimage:Int=0
		Local xy:String[] =["",""] '= New String[10]
		Local row:String = ""
		
		For Local i:Int = 4 To all.Length()-1
			
			row = all[i].Trim()

			If row.Contains(":")
			
				If row.Contains("xy")
					xy = row[ (row.FindLast(":")+1)..].Split(",")
					
					subimage[si].x = Int(xy[0].Trim())
					subimage[si].y = Int(xy[1].Trim())
					'Print xy[0]+":"+xy[1]
				Elseif row.Contains("size")
					xy = row[ (row.FindLast(":")+1)..].Split(",")
					subimage[si].w = Int(xy[0].Trim())
					subimage[si].h = Int(xy[1].Trim())
					'Print xy[0]+":"+xy[1]
				Elseif row.Contains("offset")
					xy = row[ (row.FindLast(":")+1)..].Split(",")
					subimage[si].offsetx = Int(xy[0].Trim())
					subimage[si].offsety = Int(xy[1].Trim())
					'Print xy[0]+":"+xy[1]
				Elseif row.Contains("index")
					Local ind:String = row[ (row.FindLast(":")+1)..]
					subimage[si].index = Int(ind.Trim() )
					

				Endif
				
			Else
				
				If row = "" Then Continue
				'' nextimage=0 is used for first time through
				If nextimage
					If subimage[si].index >-1 Then subimage[si].file = subimage[si].file+"_"+String(subimage[si].index)
					tmap.Set((subimage[si].file), subimage[si])
					si += 1
				Endif

				''start new image
				subimage[si] = New CSubTextureAtlas
				subimage[si].file = row
				
				nextimage = 1
				
			Endif
		Next
	
		If si>0 Or total <=1
			''add last image
			If subimage[si].index >-1 Then subimage[si].file = subimage[si].file+"_"+String(subimage[si].index)
					'Print subimage[si].file
			tmap.Set((subimage[si].file), subimage[si])
		Endif
		
		total = si
		'Print total
		
		Return 1
	End
	
	Method GetSubTexture:CSubTextureAtlas(fn:String, index:Int=0)
		Local noindexfn:String
		
		''drop any .png ext
		If fn.Contains(".") Then fn = fn[..(fn.FindLast(".")) ]
		noindexfn = fn.Trim()
		If index>0 Then fn=fn+"_"+String(index)

		Local subimage:CSubTextureAtlas = tmap.Get(fn)
		If Not subimage
			''try without index
			subimage = tmap.Get(noindexfn)
			If Not subimage
				Print "**atlas not found:"+fn
				Return Null
			Endif
		Endif

		Return subimage
	End
	
	Method Grab:Image(fn:String, index:Int=0, flags:Int=Image.DefaultFlags)
	
		Local subimage:CSubTextureAtlas = GetSubTexture(fn,index)
		
		Return texture.GrabImage(subimage.x,subimage.y,subimage.w, subimage.h, 1, flags)
	End
	
	Method GrabSet:Image[](fn:String, w:Int, h:Int, frames:Int=0, flags:Int=Image.DefaultFlags, index:Int=0)
		Local imgs:Image[frames+1]
		imgs[0] = Null
		
		Local subimage:CSubTextureAtlas = GetSubTexture(fn,index)

		Local newx:Int =0 , newy:Int=0
		For Local i:=0 To frames-1
			imgs[i] = texture.GrabImage(subimage.x+newx,subimage.y+newy,w, h, 1, flags)
			newx += w+1
			If newx >= subimage.w-2
				newx=0
				newy += h+1
				If newy>subimage.h
					Exit
				Endif
			Endif
			
		Next
		Return imgs
	End

End

Class CSubTextureAtlas
	Field file:String = ""
	Field x:Int, y:Int, offsetx:Int, offsety:Int
	Field w:Int, h:Int
	Field index:Int
	Field totalframes:Int
End

Use like this:
[monkeycode]
Import textureLoader

Local ImageBank:TextureLoader = LoadAtlas("imageAtlas.png")
Local Player:Image = ImageBank.Grab("marine_shotgun", 0, Image.MidHandle)
[/monkeycode]

ziggy

(Posted 2013) [#18]

Thanks Tibit!
While I was fighting how to use it I came up with this:

Import mojo
Import xmlloader

Class TexturePackerLoader
	Field images:StringMap<Image>

	Method New(path:String, filename:String)

		Local error:= New XMLError
		path = path.Replace("\", "/")
		If path.EndsWith("/") = False Then path += "/"

		Local buffer:String = LoadString(path + filename)
		Local doc:= ParseXML(buffer, error)
		If error.error = True Then Error Error(error.ToString)
		
		texture = LoadImage(path + doc.GetAttribute("imagePath"))
		If images = Null Then
			images = New StringMap<Image>
		Else
			images.Clear()
		EndIf
		For Local child:XMLNode = EachIn doc.GetChildren("subtexture")
			Local posX:Int = Int(child.attributes.ValueForKey("x").value)
			Local posY:Int = Int(child.attributes.ValueForKey("y").value)
			Local height:Int = Int(child.attributes.ValueForKey("height").value)
			Local width:Int = Int(child.attributes.ValueForKey("width").value)
			Local name:String = child.attributes.ValueForKey("name").value
			Local image:Image = texture.GrabImage(posX, posY, width, height)
			images.Add(name, image)
		Next		
	End
	
	Field texture:Image
	
End

And the xmlload import is just skn3 single-file xml parser that seems to work pretty well.