Moon Patrol?(scrap idea)

Monkey Forums/Monkey Code/Moon Patrol?(scrap idea)

Jesse

(Posted 2016) [#1]

Hi, everybody. I haven't been programming for a while since my time have been very limited. so now that I had some time because of some personal reasons. I decided to entertain myself by doing a clone of "Moon Patrol". I don't have much free time anymore
so I am going to post here what I have so far if anybody want to mess with it. It might help
or not but it will be here. the code will be divide into three post:

main file : "moonpatro.monkey"

Import mojo2
Import mojo
Import common
Import entity

Function Main:Int()
  New Game
End Function

Class Game Extends App  
  Field terrain:Terrain
  Field speed:Float
  Field player:Vehicle
  Field collided:Bool = False
  Field playerBulletStore:Store<Bullet>
  Field playerBulletList:List<Bullet>
  Field ufoBulletStore:Store<Bullet>
  Field ufoBulletList:List<Bullet>
  Field ufoManager:UfoManager
'  Field snake:Snake
  
  Method OnCreate:Int()
    canvas = New Canvas
    terrain = New Terrain()
    player = New Vehicle(50,400)
    playerBulletStore = New Store<Bullet>(100)
    playerBulletStore.Fill(100)
    playerBulletList = New List<Bullet>
    ufoBulletStore = New Store<Bullet>(20)
    ufoBulletList =  New List<Bullet>
    speed = .5
    ufoManager = New UfoManager
 '   snake = New Snake(-350.0,50.0,GenerateSnakeTile(),18)
    SetUpdateRate 30
    Return True
  End Method
  
  Method OnUpdate:Int()
    ufoManager.Update()
    If collided = False
      If player.jumping = False
        If KeyDown(KEY_RIGHT) 
          If player.pos.x < 350
            player.pos.x += 5
            If speed < 2.00 Then speed += .1
          Elseif speed < 2 
            speed += .1
          Endif
        Endif
        If KeyDown(KEY_LEFT) 
          If player.pos.x > 50
            player.pos.x -= 5
            speed -= .1
          Elseif speed > .3 
            speed -= .1
          Endif
        Endif
        If KeyDown(KEY_UP)
          player.SetJump()
        Endif
        collided =  player.CollidedClif(terrain)
        If KeyHit(KEY_SPACE)
          player.ShootBullet(playerBulletStore,playerBulletList)
          
        Endif
      Endif
      
      player.BulletCollidedUfo(ufoManager.ufoActiveList,playerBulletList)
      terrain.Shift(speed)
      player.AdjustWheels(terrain)
      ufoManager.ShootBullet(ufoBulletStore,player)
      ufoManager.Collided(player)
     Endif
    
   Local bn:list.Node<Bullet> = playerBulletList.FirstNode()
    Local oldbn:list.Node<Bullet> = Null
    While bn
      Local b:Bullet =  Bullet(bn.Value())
      b.Update()
      If b.pos.x > 640 Or b.pos.y < 10
        oldbn = bn
      End
      bn = bn.NextNode
      If oldbn 
        oldbn.Remove()
        player.RestoreBullet(playerBulletStore,oldbn)
        oldbn = Null
      Endif
    Wend
'    snake.Update()
    Return True
  End Method
  
  Method OnRender:Int()
    canvas.Clear(.2,.6,9)
    canvas.SetColor(1,1,1,1)
    terrain.Render()
    player.Render()
    ufoManager.Render()
'    snake.Render()
    canvas.Flush()
    Local bn:list.Node<Bullet> = playerBulletList.FirstNode()
    While bn
      Local b:Bullet = Bullet(bn.Value())
      b.Render()
      bn = bn.NextNode()
    Wend
    Return True
  End Method
  
End Class

Jesse

(Posted 2016) [#2]

file name "common.monkey"

Import mojo2
Import entity

Global canvas:Canvas
Global displayHitBox:Int = false

Function GenerateTerrainTile:mojo2.Image()
    Local tile:mojo2.Image = New mojo2.Image(64,64)
    Local icanvas:Canvas = New Canvas(tile)
    icanvas.Clear(0,0,0,0)
    For Local x:Int = 0 Until tile.Width
      icanvas.Flush()
      icanvas.SetColor(0,$78/Float($ff),0)
      For Local y:Int = 0 Until x
        icanvas.DrawPoint(y,x)
      Next
    Next
    icanvas.Flush()
    Return tile
    
    
End Function

Function GenerateCarTile:mojo2.Image()
  Local tile:mojo2.Image = New mojo2.Image(64,32)
  Local icanvas:Canvas = New Canvas(tile)
  icanvas.Clear(0,0,0,0)
  icanvas.SetColor(.8,.4,.0,1)
  icanvas.DrawRect(10,20,48,10)
  icanvas.SetColor(.4,.8,.0,1)
  icanvas.DrawPoly([15.0,10.0,40.0,10.0,50.0,20.0,10.0,20.0])
  icanvas.SetColor(.8,.1,.1)
  icanvas.DrawPoly([20.0,-10.0,25.0,-10.0,25.0,10.0,20.0,10.0])
  icanvas.DrawRect(58,25, 6,3)
  icanvas.Flush()
  Return tile
End Function

Function RenderCircle:Void(x:Float,y:Float,radius:Float,stps:Int = 24,ang:Float = 0)
		'start angle
		Local angle:Float = ang
		Local arcs:Float[stps*2]
		' distance between each point
		Local stp:Float = 360.0 / stps
		For Local indx:Float = 0 Until stps*2 Step 2 
      arcs[indx  ] = x + Cos(angle) * radius
      arcs[indx+1] = y + Sin(angle) * radius
      angle += stp
    Next
		canvas.DrawPoly arcs
		canvas.DrawLine(x,y,arcs[0],arcs[1])
End Function

Function GenerateSnakeTile:mojo2.Image()
	Local tile:mojo2.Image = New mojo2.Image(64,32)
	Local icanvas:Canvas = New Canvas(tile)
	icanvas.Clear(0,0,0,0)
	icanvas.SetColor (.1,.1,.1,1)
	tile.SetHandle(0,0)
	icanvas.DrawCircle(16,16,13)
	icanvas.SetColor (.9,.1,.1,1)
	icanvas.DrawOval(16-13,16-8,26,16)
	icanvas.SetColor(0.1,.4,.9,1)
	icanvas.DrawPoly([10.0,1, 15,1, 25,16, 15,32,10,32])
	icanvas.SetColor(0.1,.1,.9,1)
	icanvas.DrawPoly([11.0,1, 16,1, 24,16, 16,31,11,31])
	icanvas.Flush()
	Return tile
End Function
	

'*********************************************************
'*														  *
'* 				Vector class 							  *
'*********************************************************

Class PVector2D
	Field x:Float
	Field y:Float
	
	Method New(x:Float,y:Float)
		Set(x,y)
	End Method
	
	Method New(x1:Float,y1:Float,x2:Float,y2:Float)
		Set(x2-x1,y2-y1)
	End Method
	
	Method New(v:PVector2D)
		Set(v)
	End Method
	
	Method Set:PVector2D(v:PVector2D)
		x = v.x
		y = v.y
		Return Self
	End Method

	Method Set:PVector2D(x:Float,y:Float)
		Self.x = x
		Self.y = y
		Return Self
	End Method
		
	Method Add:PVector2D(x:Float,y:Float)
		Self.x += x
		Self.y += y
		Return Self
	End Method
	
	Method Add:PVector2D(v:PVector2D)
		Self.x += v.x
		Self.y += v.y
		Return Self
	End Method
	
	Method Add:PVector2D(value:Float)
		Self.x += value
		Self.y += value
		Return Self
	End Method
	
	Method Subtract:PVector2D(x:Float,y:Float)
		Self.x -= x
		Self.y -= y
		Return Self
	End Method
	
	Method Subtract:PVector2D(v:PVector2D)
		Self.x -= v.x
		Self.y -= v.y
		Return Self
	End Method
	
	Method Subtract:PVector2D(value:Float)
		Self.x -= value
		Self.y -= value
		Return Self
	End Method
	
	Method Multiply:PVector2D(x:Float,y:Float)
		Self.x *= x
		Self.y *= y
		Return Self
	End Method
	
	Method Multiply:PVector2D(v:PVector2D)
		Self.x *= v.x
		Self.y *= v.y
		Return Self
	End Method
	
	Method Multiply:PVector2D(value:Float)
		Self.x *= value
		Self.y *= value
		Return Self
	End Method
	
	Method Divide:PVector2D(x:Float,y:Float)
		Self.x /= x
		Self.y /= y
		Return Self
	End Method
	
	Method Divide:PVector2D(v:PVector2D)
		Self.x /= v.x
		Self.y /= v.y
		Return Self
	End Method
	
	Method Divide:PVector2D(value:Float)
		Self.x /= value
		Self.y /= value
		Return Self
	End Method
	
	Method DotProduct:Float(x:Float,y:Float)
		Return Self.x * x + Self.y * y
	End Method
	
	Method DotProduct:Float(v:PVector2D)
		Return Self.x * v.x + Self.y * v.y
	End Method
	
	Method PerpDotProduct:Float(x:Float,y:Float)
		Return Self.x * y - Self.y * x
	End Method
	
	Method PerpDotProduct:Float(v:PVector2D)
		Return Self.x * v.y - Self.y * v.x
	End Method
	
	Method MagnitudeSquare:Float()
		Return Self.x * Self.x + Self.y * Self.y
	End Method
	
	Method Magnitude:Float()
		Return Sqrt(MagnitudeSquare())
	End Method
	
	Method LeftNormal:Float()
		Local n:Float = y
		y = -x 
		x = n
	End Method
	
	Method RightNormal:Float()
		Local n:Float = y
		y = x
		x = -n
	End Method
	
	Method Normalize:PVector2D()
		Divide(Magnitude())
		Return Self
	End Method
		
	Method GetAngle:Float()
		Return ATan2(y,x)
	End Method
	
	Method ToString:String()
		Return x+"  "+y
	End Method
	
	Method Draw:Void(x:Float,y:Float)
		DrawLine(x,y,x+Self.x,y+Self.y)
	End Method
	
End Class

Function Projection:PVector2D(this:PVector2D,into:PVector2D,destination:PVector2D=Null)
	
	If destination = Null destination = New PVector2D
		
	Return destination.Set(into).Normalize().Multiply(destination.DotProduct(this))
	
End Function

Function CrossProjection:PVector2D(this:PVector2D,into:PVector2D,destination:PVector2D=Null)
	
	If destination = Null destination = New PVector2D
	
	Return destination.Set(into.y,-into.x).Normalize().Multiply(destination.DotProduct(this))
		
End Function



'***********************************************************
'*			collision										"
'***********************************************************

Class HitBox
  Field pos:PVector2D
  Field off:PVector2D
  Field width:Float
  Field height:Float
  
  Method New()
    off = New PVector2D
  End Method
  
  Method New(p:PVector2D,x:Float,y:Float,width:Float,height:float)
     off = New PVector2D
     Set(p,x,y,width,height)
  End Method
  
  Method Set(pos:PVector2D,ox:Float,oy:Float,width:Float,height:Float)
    Self.pos = pos
    off.Set(ox,oy)
    Self.width = width
    Self.height = height
  End method
  
  Method Collided:Bool(box:HitBox)
    Local b1x1:Float = pos.x + off.x
    Local b1y1:Float = pos.y + off.y
    Local b1x2:Float = pos.x + width
    Local b1y2:Float = pos.y + height
    Local b2x1:Float = box.pos.x + box.off.x
    Local b2y1:Float = box.pos.y + box.off.y
    Local b2x2:Float = box.pos.x + box.width
    Local b2y2:Float = box.pos.y + box.height
    If b1x1 > b2x2 Return False
    If b1x2 < b2x1 Return False
    If b1y1 > b2y2 Return False
    If b1y2 < b2y1 Return False 	
    Return True
  End method
  
  Method Render()
    graphics.MoveTo(pos.x+off.x,pos.y+off.y)
    graphics.LineTo(pos.x+off.x+width,pos.y+off.y)
    graphics.LineTo(pos.x+off.x+width,pos.y+off.y+height)
    graphics.LineTo(pos.x+off.x,pos.y+off.y+height)
    graphics.Close()
  End Method
  
End Class



'*******************************************************
'*			Store										*
'*******************************************************

Class Store<T>
	Field last:T
	Field total:int
		
	Method New(count:Int)
		Fill(count)
	End Method	

	Method Fill:Void(total:Int)
		For Local i:Int = 0 Until total
			Local c:T = New T()
			c._pred = last
			last = c
		Next
		Self.total = total
	End Method
	
	Method Count:Int()
		Return total
	End Method
	
	Method GetItem:T()
		If last
			Local c:T = last
			last = T(last._pred)
			c._pred = Null
			total -= 1
			Return c
		Endif
		Return New T()
	End Method
	
	Method ReturnItem:Void(obj:T)
		obj._succ = Null
		obj._pred = last
		last = obj
		total += 1
	End Method
	
End Class

Class StoreObject
	Field _pred:StoreObject
	Field _succ:StoreObject
	
	Function Separate:Void(obj:StoreObject)
		If obj._pred
			If obj._succ
				obj._pred._succ = obj._succ
				obj._succ._pred = obj._pred
			Else
				obj._pred._succ = Null
			Endif
		Elseif obj._succ
			obj._succ._pred = Null
		Endif
			
	End Function
	
End Class

'***************************************************
'			graphics								*
'***************************************************

Global graphics:Graphics = New Graphics()
 
Class Graphics
  Field startX:Float
  Field startY:Float
  Field currentX:Float
  Field currentY:Float
  Field lastX:Float
  Field lastY:Float
  

  Method MoveTo(x:Float,y:Float)
    startX = x
    startY = y
    lastX = x
    lastY = y
  End Method
  
  Method LineTo(x:Float,y:Float)
    currentX = x
    currentY = y
    canvas.DrawLine(lastX,lastY,x,y)
    lastX=x
    lastY=y
  End 
  
  Method Close()
    canvas.DrawLine(lastX,lastY,startX,startY)
    lastX = startX
    lastY = startY
  End Method
    
End Class

Function TileImageAcross:Void(c:Canvas,image:Image,x:Float,y:Float,width:Float)
	Local w:Float = width-1
	Local ox:Float = -w+1
	Local px:Float = x
	Local fx:Float = px - Int(px)
	Local tx:Float = Int(px) - ox
	

	If (tx >= 0)
		tx=tx Mod w + ox
	Else
		tx=w + tx Mod w + ox
	Endif
	Local vr:Float = 680.0
	Local ix:Float = tx
	While(ix < vr)
		c.DrawImage(image,ix+fx,y)
		ix=ix+w
	Wend
End Function

Jesse

(Posted 2016) [#3]

it's not letting me post any code beyond this post. so I guess I can't load it.
Funny! Code Section and cant post any code.

therevills

(Posted 2016) [#4]

Testing code

rIKmAN

(Posted 2016) [#5]

therevills code test = successful!

Jesse

(Posted 2016) [#6]

maybe size of the code. 150 lines of code too much?

I just tried posting 100 lines of code and got this error :

Internal Server Error

The server encountered an internal error or misconfiguration and was unable to complete your request.

Please contact the server administrator at webmaster@... to inform them of the time this error occurred, and the actions you performed just before this error.

More information about this error may be available in the server error log.

Additionally, a 404 Not Found error was encountered while trying to use an ErrorDocument to handle the request.

Apache/2.4.10 (Unix) OpenSSL/1.0.1e-fips mod_bwlimited/1.4 Server at www.monkey-x.com Port 80

the first time I tried it. I think I crashed the server yesterday for a couple of hours.

muddy_shoes

(Posted 2016) [#7]

I don't know why you'd want to post a multi-file project as a bunch of inline pastes anyway. Surely it's easier for everyone if you just link to a zip hosted somewhere? If you want the code to be easily browsed online then put it on GitHub/BitBucket or other source repo.

Jesse

(Posted 2016) [#8]

yes, it's easier and I cant post a zip file. but this being the code section I thought I would post the code. It doesn't need any images. besides if I post a zip sooner or later it will probably get removed. but this way the code is here permanently.

here is a zip file anyway:
https://drive.google.com/open?id=0B1A_QyoaSAVocmZoM3NFQVo5dmc