Mojo2: Rotate canvas (mid point).

Monkey Forums/Monkey Code/Mojo2: Rotate canvas (mid point).

Richard Betson

(Posted 2015) [#1]

Mojo2: Rotate canvas / images (mid point display). May take a sec for background image to load.
http://www.phoenixusc.com/Personal_Post_Data/mojo2/alienrotate/MonkeyGame.html
Also here:
http://www.phoenixusc.com/board/misc.php?page=PUSC_Monkey
'
~~Edit: On IE all I get is a black screen (app display). Chrome and Firefox are OK. Bug? I do something wrong?~~
Edit- Works in IE now. :)

This is the 'bouncyaliens' included in mojo2 modified to rotate the images and canvas at the display mid point. I added a background image to help with the effect. Neat stuff mojo2.

Modified 'bouncyaliens' code.


'a port of the mojo1 banana...

Import mojo2

Public

Const WIDTH#=320
Const HEIGHT#=240

Class Sprite

	Field x#,vx#
	Field y#,vy#
	Field f#,vf#
	
	Method New()
		x=Rnd( WIDTH )
		y=Rnd( HEIGHT )
		vx=Rnd(1,2);If Rnd(1)>=.5 vx=-vx
		vy=Rnd(1,2);If Rnd(1)>=.5 vy=-vy
		vf=Rnd( .5,1.5 )
	End

	Method Update()
		x+=vx;If x<0 Or x>=WIDTH vx=-vx
		y+=vy;If y<0 Or y>=HEIGHT vy=-vy
		f+=vf;If f>=8 f-=8
	End
	
End

Class MyApp Extends App

	Field canvas:Canvas

	Field utime,uframes,ufps
	Field rtime,rframes,rfps
	
	Field frames1:Image[]
	Field frames2:Image[]
	Field sprites:=New Stack<Sprite>
	Field background_image:Image
	
	Field rot#
	
	Field ums

	Field fullscreen:=False
	
	Method ToggleFullscreen:Void()
		fullscreen=Not fullscreen
		If fullscreen
			SetDeviceWindow DesktopMode.Width,DesktopMode.Height,1
			SetSwapInterval 1
			SetUpdateRate 0
		Else
			SetDeviceWindow 640,480,4
			SetSwapInterval 1
			SetUpdateRate 0
		Endif
	End
	
	Method OnCreate()
	
		canvas=New Canvas
		
		Print "Display modes:"
		For Local mode:=Eachin DisplayModes()
			Print mode.Width+","+mode.Height
		Next

		frames1=Image.LoadFrames( "alien1.png",8 )
		frames2=Image.LoadFrames( "alien2.png",8 )
		background_image=Image.Load( "background.png" ) 'Added background image
		
		
		For Local i=0 Until 100
			sprites.Push New Sprite
		Next

		SetSwapInterval 1
		SetUpdateRate 0
		
		utime=Millisecs()
		rtime=utime
	End
	
	Method OnUpdate()
	
		If KeyHit( KEY_SPACE ) ToggleFullscreen
	
		ums=Millisecs

		uframes+=1
		Local e=Millisecs-utime
		If e>=1000
			ufps=uframes
			uframes=0
			utime+=e
		Endif
	
		If MouseHit(0)
		
			If MouseX()<DeviceWidth/3
				For Local i=0 Until 25
					If Not sprites.IsEmpty() sprites.Pop
				Next
			Else If MouseX()>DeviceWidth*2/3
				For Local i=0 Until 25
					sprites.Push New Sprite
				Next
			Else
				If fullscreen ToggleFullscreen			
				'OpenUrl "http://www.blitzbasic.com"
			Endif
		Endif
	
		For Local sprite:=Eachin sprites
			sprite.Update
		Next
		
		rot+=1
		
		ums=Millisecs-ums;
		
		

 	End
 	
 	Field paused:Bool
	
	
	
	
	Global angle:Float 	'Added for angle
	
	Method OnRender()
	
	'add angle var
	angle+=1
	If angle=359 Then angle=0

		canvas.PushMatrix()	'Added to modify matrix
	
		'in case device mode changed
		canvas.SetViewport 0,0,DeviceWidth,DeviceHeight
		canvas.SetScissor 0,0,DeviceWidth,DeviceHeight
		canvas.Translate(160,120)	
		canvas.Rotate(angle)
		canvas.SetProjection2d 0,WIDTH,0,HEIGHT

		rframes+=1
		Local e=Millisecs-rtime
		If e>=1000
			rfps=rframes
			rframes=0
			rtime+=e
		Endif
		
		canvas.Clear .5,0,1


		Local xoff:Int=160	'Offset to center images / text
		Local yoff:Int=120

		Local r:=rot
		Local frames:=frames1
		Local i,n=sprites.Length()/10	'ie: simulate 10 render state changes
		random.Seed=1234
		
		canvas.DrawImage(background_image,xoff,yoff) ' Added a background image
		
		For Local sprite:=Eachin sprites
			i+=1
			If i Mod n=0
				If (i/n)&1 frames=frames2 Else frames=frames1
			End
			r+=Rnd(360)
			canvas.DrawImage frames[sprite.f],sprite.x-xoff,sprite.y-yoff,r,Rnd(1,2),Rnd(1,2)
		Next
		
	'	canvas.DrawText "[<<]",0-xoff,8-yoff,0,.5
	'	canvas.DrawText "imgs="+sprites.Length()+", ufps="+ufps+", rfps="+rfps+", last update="+ums,(DeviceWidth/2-xoff),8-yoff,.5,.5
	'	canvas.DrawText "[>>]",DeviceWidth-xoff,8-yoff,1,.5
		
		If paused

			canvas.SetColor 0,0,0,.5
			canvas.DrawRect 0,0,DeviceWidth,DeviceHeight
			canvas.SetColor 1,1,1,1
			canvas.DrawText "Suspended",(DeviceWidth/2)-xoff,(DeviceHeight/2)-yoff,.5,.5
			canvas.SetColor 1,1,1,1
			
		Endif
		
		canvas.PopMatrix() 'Add to modify matrix

		canvas.Flush

		'If Image.ImagesLoading()  Then canvas.DrawText "LOADING IMAGE. . .",(DeviceWidth/2)-xoff,(DeviceHeight/2)-yoff,.5,.5
	
	End
	
	Method OnSuspend()
		Print "BouncyAliens: OnSuspend"
		paused=True
	End

	Method OnResume()
		Print "BouncyAliens: OnResume"
		paused=False
	End

End

Function Main()

	New MyApp
	
End

ImmutableOctet(SKNG)

(Posted 2015) [#2]

WebGL isn't supported on Internet Explorer versions earlier than 11 from what I recall. That's Microsoft for you. Your example, along with everything else runs fine here. I'm running the newest developer build of Opera, which is just a nice coat of paint on top of Chromium at this point.

Richard Betson

(Posted 2015) [#3]

^Actually the rendererdemo and directlight demos both run on IE so I am not sure.

Danilo

(Posted 2015) [#4]

Press F12 in IE11 to open developer tools (debugger).

I get an error at line 5531:

gl.uniform1i(t_u.m_location,t_texid);

t_u.m_location is -1