TypeOf(T) -- Fix you generic Map<K,V> issues

Monkey Forums/Monkey Code/TypeOf(T) -- Fix you generic Map<K,V> issues

Pharmhaus

(Posted 2015) [#1]

Hi,
The following codes fixes all your problems when you try to use maps/lists/sets + Generics.
I hope it gets implemented into MX one day.

Strict

Function Main:Int()
	
	'/// Get the Type T as a string
	
	Print TypeOf<string>.TypeToString()
	Print TypeOf<int>.TypeToString()
	Print TypeOf<float>.TypeToString()
	Print TypeOf<bool>.TypeToString()
	Print TypeOf<object>.TypeToString()
	
	'// Get the Type of T as an int
	
	Print TypeOf<string>.Type()
	Print TypeOf<int>.Type()
	Print TypeOf<float>.Type()
	Print TypeOf<bool>.Type()
	Print TypeOf<object>.Type()
	
	Print "----"
	
	Local myMap:Map<string, int> = MapOfT<string, int>.CreateMap()
	myMap.Add("hello", 12345)
	myMap.Add("world", 5678)
	Print myMap.Get("world")
	
	Print "----"
	
	Local myMap2:Map<int, int> = MapOfT<int, int>.CreateMap()
	myMap2.Add(1, 12345)
	myMap2.Add(2, 5678)
	Print myMap2.Get(2)
	
	Print "----"
	
	Local myMap3:Map<float, int> = MapOfT<float, int>.CreateMap()
	myMap3.Add(1.345, 12345)
	myMap3.Add(2.345, 5678)
	Print myMap3.Get(2.345)
		
	Return 0
End

Class MapOfT<K, V>

	Function CreateMap:Map<K, V>()
		Select TypeOf<K>.Type()
			Case TTypes.TYPE_INT
				Return Map<K, V>(object(New IntMap<V>))
			Case TTypes.TYPE_FLOAT
				Return Map<K, V>(object(New FloatMap<V>))
			Case TTypes.TYPE_STRING
				Return Map<K, V>(object(New StringMap<V>))
			Default
				Return Null ' Not supported
		End
	End
End

Class TTypes
	Const TYPE_INT:Int = 0
	Const TYPE_FLOAT:Int = 1
	Const TYPE_BOOL:Int = 2
	Const TYPE_STRING:Int = 3
	Const TYPE_OBJECT:Int = 4
End

Class TypeOf<T>
	
	Function TypeToString:String()
		Select TypeOf<T>.Type()
			Case TTypes.TYPE_INT
				Return "int"
			Case TTypes.TYPE_FLOAT
				Return "float"
			Case TTypes.TYPE_BOOL
				Return "bool"
			Case TTypes.TYPE_STRING
				Return "string"
			Case TTypes.TYPE_OBJECT
				Return "object"
			Default
				Return "object"
		End
	End
	
	Function Type:Int()
		If ar.Length = 0 Then
			ar = New ITType[5]
			ar[0] = New TType<int>()
			ar[0].Type = TTypes.TYPE_INT
			ar[1] = New TType<float>()
			ar[1].Type = TTypes.TYPE_FLOAT
			ar[2] = New TType<bool>()
			ar[2].Type = TTypes.TYPE_BOOL
			ar[3] = New TType<string>()
			ar[3].Type = TTypes.TYPE_STRING
			ar[4] = New TType<object>()
			ar[4].Type = TTypes.TYPE_OBJECT
		EndIf
		
		For Local i:Int = 0 Until ar.Length
			If TType<T>(ar[i]) Then Return ar[i].Type
		Next
		
		Return ar[TTypes.TYPE_OBJECT].Type
	End

	'//// PRIVATE
	Private
	
	Global ar:ITType[]
End

Class TType<T> Implements ITType
	Field m_type:Int
	
	Method Type:Void(value:Int) Property
		m_type = value
	End
	
	Method Type:Int() Property
		Return m_type
	End
	
End

Interface ITType
	Method Type:Void(value:Int) Property
	Method Type:Int() Property
End

ziggy

(Posted 2015) [#2]

What's the usage of this? Can't see where I would be using this?

Pharmhaus

(Posted 2015) [#3]

The default Map<K,V> cannot be used to stored values because CompareTo(..) is abstract.
So you need a concrete implementation like IntMap, StringMap, etc.
When you write a generic class / method / function and you like to use a map you don't now which of kind of map you need (because of T).
Same for Set<T> and if you like to sort also for List<T> and Stack<T>.

Samah

(Posted 2015) [#4]

@Pharmhaus: Same for Set<T> and if you like to sort also for List<T> and Stack<T>.

This is why I made DiddyStack, DiddyList, and DiddySet. They extend the base library classes and handle all the sorting/comparison stuff for you. They can also be interchangeable in some situations.
https://code.google.com/p/diddy/source/browse/src/diddy/diddystack.monkey