Oval Reaction Thingy

Monkey Forums/Monkey Code/Oval Reaction Thingy
Dabz	(Posted 2014) [#1]
Based on a flash game I saw a few years ago, I decided to have a little play to get back into Monkey, click on the screen and a new oval will expand, if it hits an existing one, that will expand, rinse, repeat till all the ovals are gone:-

*Note, uses Diddy
'Reactions Using Ovals
'Written by Michael Denathorn 2014

Strict

Import diddy

Global gameScreen:MainGame

Function Main:Int()
	diddyGame = New GameApp()
	diddyGame.FPS = 30
	diddyGame.frameRate = 75
	diddyGame.UseFixedRateLogic(True)
	Return 0
End

Class GameApp Extends DiddyApp
	Method Create:Void()
		drawFPSOn = False
		gameScreen = New MainGame
		Start(gameScreen)
	End
End

Class MainGame Extends Screen
	
	Field listBalls:List<CBall> = New List<CBall>
	Field tempListBall:List<CBall> = New List<CBall>, collisionListBall:CBall, bStartCollisions:Int,iAliveAmount:Int 
	Field iMX:Int, iMY:Int
	
	Method New()
	End
	
	Method Start:Void()
		Seed = RealMillisecs()
		CreateBalls(11)
		bStartCollisions = False
	End
	
	Method Render:Void()
		Cls
		DrawText "Chain Reaction Using Ovals - Michael Denathorn 2014",0,0
		DrawText "Total Balls: "+listBalls.Count(),0,20
		DrawText "Alive Balls: "+iAliveAmount,0,40
		RenderBalls()
	End
	
	Method DebugRender:Void()
	End
	
	Method Update:Void()
		iMX = MouseX()
		iMY = MouseY()
		If MouseHit(MOUSE_LEFT) And bStartCollisions = False
			bStartCollisions = True
			CreateBalls(1,iMX, iMY, 1)
		Endif
		
		UpdateBalls()
	End
	
	Method UpdateBalls:Void()
		Local deleteBall:int 
		Local ballCount:Int , ballCounter:Int, distance:Int
			For Local tempListBall:CBall = Eachin listBalls
				deleteBall = tempListBall.UpdateBall()
				If deleteBall = True
					tempListBall.KillBall() 
					iAliveAmount = iAliveAmount - 1
					'listBalls.Remove(tempListBall) 
				End If
			Next
			
			'The action has started
			If bStartCollisions = True
				For collisionListBall = EachIn listBalls
				If collisionListBall.ballAlive = true	
					If collisionListBall.bBallStatus <> collisionListBall.BALL_NORMAL
						For Local tempListBall:CBall = Eachin listBalls
							If tempListBall.bBallStatus = tempListBall.BALL_NORMAL
								distance = GetDistance(collisionListBall.fX , collisionListBall.fY , tempListBall.fX , tempListBall.fY)-(collisionListBall.iRadius+tempListBall.iRadius)
								If distance < 0
									tempListBall.bBallStatus = tempListBall.BALL_EXPANDING
									collisionListBall.bBallStatus = collisionListBall.BALL_DEFLATING
								End If
							End If 
						Next
					End If
				Endif  
				Next
			
				For Local tempListBall:CBall = Eachin listBalls
					If tempListBall.bBallStatus = tempListBall.BALL_NORMAL
						ballCounter = ballCounter + 1
					End If 
				Next
				If iAliveAmount = ballCounter
					bStartCollisions = False 
					listBalls.RemoveLast()
					If iAliveAmount = 0 Then ReviveAllBalls()
				End If		
			End If 
	End Method 
	
	Method RenderBalls:Void()
		For Local tempListBall:CBall=Eachin listBalls
			tempListBall.DrawBall()
		Next
	End Method 


	Method CleanUp:Void()
		For Local tempListBall:CBall=Eachin listBalls
			tempListBall.RemoveBall() 
		Next
		listBalls.Clear()
	End Method
	
	Method CreateBalls:Void(amount:Int,posX:Int = 0, posY:Int = 0,status:Int = 0)
		Local loopx:Int 
		Local tempBall:CBall
	
		For loopx = 1 To amount
			tempBall = New CBall
			listBalls.AddLast(tempBall.CreateBall(posX,posY,status))
			iAliveAmount = iAliveAmount + 1
		Next
	End Method
	
	Method ReviveAllBalls:void()
		For Local tempListBall:CBall=Eachin listBalls
			tempListBall.ReviveBall() 
			iAliveAmount = iAliveAmount + 1
		Next
	End Method 
	
	Method GetDistance:Int(fSourceX:Float, fSourceY:Float, fDestinationX:Float, fDestinationY:Float)
		Local iXdist:Int = Abs(fSourceX - fDestinationX) , iYdist:Int = Abs(fSourceY - fDestinationY)
		Return Sqrt(iXdist * iXdist + iYdist * iYdist)
	End Method 
	
End

Class CBall
	Field ball:CBall
	Field ballAlive:Int 
	Field fX:Float , fY:Float  
	Field iRadius:Int
	Field fXDir:Float , fYDir:Float  
	Field bBallStatus:Int 
	Field bCheckCollision:int
	Field iRedElement:Int , iGreenElement:Int , iBlueElement:Int 
	
	Const BALL_NORMAL:int 		= 0
	Const BALL_EXPANDING:int 	= 1
	Const BALL_DEFLATING:int	= 2

	Const MAX_RADIUS:Int = 150
	Const NORMAL_RADIUS:Int = 10 
	Const MIN_RADIUS:Int = 1
	
	Method New()
		ball = Self 
	End Method
	
	Method CreateBall:CBall(iX:Int = 0,iY:Int = 0,bStatus:int = BALL_NORMAL)
		Local bResult:int

		If iX < NORMAL_RADIUS
			Self.fX = Rand(NORMAL_RADIUS , DeviceWidth() - NORMAL_RADIUS) 
		Else
			self.fX = Float(iX)
		End If
		
		If iY < NORMAL_RADIUS
			Self.fY = Rand(NORMAL_RADIUS , DeviceHeight() - NORMAL_RADIUS)
		Else
			self.fY = Float(iY)
		End If

		self.iRadius = NORMAL_RADIUS
		self.bBallStatus = bStatus
		self.bCheckCollision = False
		self.iRedElement = 0
		self.iGreenElement = Rand(0 , 150)
		self.iBlueElement = Rand(150 , 200)
		Self.ballAlive = True
		
		bResult = Rand(False , True) 
		
		If bResult = True
			self.fXDir = Rnd(0.5,1)
			self.fYDir = - (Rnd(0.5,1))
		Else
			self.fXDir = - (Rnd(0.5,1))
			self.fYDir = Rnd(0.5,1)
		End If 
		Return Self 
	End Method 
	
	Method UpdateBall:int()
	If Self.ballAlive = True 
		If self.bBallStatus = BALL_NORMAL
			'Move ball
			Self.fX = Self.fX + fXDir
			Self.fY = Self.fY + fYDir
		
			If self.fX < NORMAL_RADIUS Or self.fX > (DeviceWidth()-(NORMAL_RADIUS)) Then self.fXDir = - self.fXDir
			If self.fY < NORMAL_RADIUS Or self.fY > (DeviceHeight()-(NORMAL_RADIUS)) Then self.fYDir = - self.fYDir
		End If
		
		If self.bBallStatus = BALL_EXPANDING
			self.iRadius = self.iRadius + 1
			If self.iRadius = MAX_RADIUS
				self.bBallStatus = BALL_DEFLATING
			End If
		End If
		
		If self.bBallStatus = BALL_DEFLATING
			self.iRadius = self.iRadius - 1
			If self.iRadius = MIN_RADIUS
				Return True 
			End If
		End If 		
	Endif		
	
	Return False 
	 
	End Method
	
	Method DrawBall:Void()
		If Self.ballAlive = True
			SetColor Self.iRedElement,Self.iGreenElement,Self.iBlueElement
			DrawOval (Self.fX-Self.iRadius),(Self.fY-Self.iRadius),(Self.iRadius*2),(Self.iRadius*2)
		Endif 
	End Method 
	
	Method KillBall:Void()
		If Self.ballAlive = True
			Self.ballAlive = False
		Endif  
	End Method 
	
	Method ReviveBall:Void()
		If Self.ballAlive = False	
			Self.ballAlive = True
			Self.iRadius = NORMAL_RADIUS
			self.bBallStatus = BALL_NORMAL
		Endif 
	End Method 
	
	Method RemoveBall:Void()
		ball = Null 
	End Method
End
Edit: If you cannot be chewed to copy/paste/run it, then, go here for a peek: http://www.denathorn.com/2014/02/02/chain-reaction-using-ovals/

Dabz