Sort arbitrary items with no fuss

Monkey Forums/Monkey Code/Sort arbitrary items with no fuss

Gerry Quinn

(Posted 2013) [#1]

[Edit: I rewrote this adding a more general sorting function]

Ever had an array of objects that you'd like to tackle in a particular order based on some property but you haven't sorted them that way and you don't want to? For example, suppose creatures in a dungeon are listed in order of which will move first, but occasionally you want to cast a spell that affects everyone in order of size.

Let us hypothesise further that you don't want to have to make generic classes to help with sorting.

Then this module may be for you!

sortitems.monkey

Strict


' Usage:

' (1) Sort any collection of items, each with a value
'		Local si:SortItems< Item > = New SortItems< Item >
'		si.Add( item, value )		'Add each item like this
'		Local sorted:List< Item > = si.Sort()


' (2) Sort an array of items given an array of values associated with each
' 		Local sorted:List< Item > = SortItems.SortArray< Item >( items[], values[] )


Class SortItems< T >

	Field tis:TaggedItemList< T >


	Method New()
		tis = New TaggedItemList< T >
	End


	Method Add:Void( item:T, value:Float )
		tis.AddLast( New TaggedItem< T >( item, value ) )
	End
	
	
	Method Sort:List< T >( ascending:Bool = True )
		tis.Sort( ascending )
		Local sorted:List< T > = New List< T >
		For Local ti:TaggedItem< T > = Eachin tis
			sorted.AddLast( ti.item )
		Next
		Return sorted
	End
	


	Function SortArray:List< T >( items:T[], tags:Float[], ascending:Bool = True )
			
		Local sorted:List< T > = New List< T >
		
		Local len:Int = items.Length()
		If len <> tags.Length()
			Return sorted
		End
		
		Local tis:TaggedItemList< T > = New TaggedItemList< T >()
		For Local i:Int = 0 Until len
			tis.AddLast( New TaggedItem< T >( items[ i ], tags[ i ] ) )
		Next
		tis.Sort( ascending )
		
		For Local ti:TaggedItem< T > = Eachin tis
			sorted.AddLast( ti.item )
		Next		
		Return sorted
	End
	
End


Class TaggedItem< T >
	
	Field item:T
	
	Field tag:Float
		
	Method New( taggedItem:T, tagVal:Float )
		item = taggedItem
		tag = tagVal
	End
	
End


Class TaggedItemList< T > Extends List< TaggedItem< T > >

	Method New( data:TaggedItem< T >[] )
		Super.New( data )
	End

	Method Equals:Bool( lhs:TaggedItem< T >, rhs:TaggedItem< T > )
		Return lhs.tag = rhs.tag
	End
	
	Method Compare:Int( lhs:TaggedItem< T >, rhs:TaggedItem< T > )
		Return lhs.tag - rhs.tag
	End

End

Example using it:

Strict


' Demonstrate use of SortItems()


Import sortitems


Function Main:Int()

	' Use the SortArray function to sort one array according to the values in another
	Print "SORT AN ARRAY ACCORDING TO AN ARRAY OF VALUES"
	Local persons:String[] = [ "Archibald", "Mary", "Tom", "Anne", "Roger", "Gertrude", "John" ]
	Local letters:Float[] = New Float[ persons.Length() ]
	For Local i:Int = 0 Until persons.Length()
		letters[ i ] = persons[ i ].Length()
	Next
	Local sortedByLength:List< String > = SortItems< String >.SortArray( persons, letters )
	For Local person:String = Eachin sortedByLength
		Print person
	Next
	
	' Create an instance of SortItems for more general sorting
	Print "SORT ARBITRARY DATA ACCORDING TO VALUE"
	Local si:SortItems< String > = New SortItems< String >()
	si.Add( "Dog", 4 )
	si.Add( "Duck", 2 )
	si.Add( "Spider", 8 )
	si.Add( "Centipede", 100 )
	si.Add( "Beetle", 6 )
	Local sortedByLegs:List< String > = si.Sort()
	For Local creature:String = Eachin sortedByLegs
		Print creature
	Next
	
	Return 0
End

Note that nothing happens to your original data, you just get a list that you can use to do each item in order.

If you are using the SortArray function and the number of values does not match the number of items, an empty list will be returned.

Gerry Quinn

(Posted 2013) [#2]

Just to note: I edited the above today to include a more general sorting functionality.