Entity Component System

Monkey Forums/Monkey Code/Entity Component System

Belimoth

(Posted 2013) [#1]

Fun little experiment I did in another thread.
In order to write a new Component you have to define an accompanying ComponentGetter<>, which in this example I've prefixed with an underscore.

Strict
#REFLECTION_FILTER="*"
Import reflection

Class Entity
	Field components := New StringMap<Component>
	
	Method AddComponent:Void(component:Component)
		Local key:String = GetClass(component).Name
		components.Set(key, component)
		component.owner = Self
	End
End

Class Component
	Field owner:Entity
End

Class ComponentGetter<T>
	Global name:String
	
	Function GetFrom:T(entity:Entity)
		If name = "" Then name = GetClass( New T() ).Name	'be aware of this New
		Return T( entity.components.Get(name) )
	End
End



Class _PositionComponent Extends ComponentGetter<PositionComponent> End

Class PositionComponent Extends Component

Public
	Method X:Int() Property Return _x End
	Method X:Void(x:Int) Property _x = x End
	Method Y:Int() Property Return _y End
	Method Y:Void(y:Int) Property _y = y End
	
	Method New(x:Int, y:Int)
		Self._x = x
		Self._y = y
	End
Private
	Field _x:Int, _y:Int
End

Function Main:Int()
	Local myEntity := New Entity()
	myEntity.AddComponent( New PositionComponent(16, 24) )
	Local position := _PositionComponent.GetFrom(myEntity)
	Print "X: " + position.X + " Y: " + position.Y
	Return 0
End

Belimoth

(Posted 2013) [#2]

Here's a version that doesn't involve reflection.

Strict

Class Entity
	Field components := New StringMap<Component>
	
	Method AddComponent:Void(component:Component)
		Local key:String = component.ComponentName()
		components.Set(key, component)
		component.owner = Self
	End
End

Class Component
	Field owner:Entity
	Method ComponentName:String() Abstract
End

Class ComponentGetter<T>		'T must extend Component
	Global name:String
	
	Function GetFrom:T(entity:Entity)
		If name = ""
			Local t := New T()
			name = t.ComponentName()
			'do whatever you need to do to finalize t here.
		EndIf
		Return T( entity.components.Get(name) )
	End
End



Class _PositionComponent Extends ComponentGetter<PositionComponent> End

Class PositionComponent Extends Component

Public
	Method ComponentName:String() Return "PositionComponent" End
	
	Method X:Int() Property Return _x End
	Method X:Void(x:Int) Property _x = x End
	Method Y:Int() Property Return _y End
	Method Y:Void(y:Int) Property _y = y End
	
	Method New(x:Int, y:Int)
		Self._x = x
		Self._y = y
	End
Private
	Field _x:Int, _y:Int
End

Function Main:Int()
	Local myEntity := New Entity()
	myEntity.AddComponent( New PositionComponent(16, 24) )
	Local position := _PositionComponent.GetFrom(myEntity)
	Print "X: " + position.X + " Y: " + position.Y
	Return 0
End

Belimoth

(Posted 2013) [#3]

All this to avoid one cast

Belimoth

(Posted 2013) [#4]

Version 3, I never miss an opportunity to over-engineer something.

Strict
#REFLECTION_FILTER="*"
Import reflection



Interface IProperties
	Method SetProperty:Void(key:String, value:Float = 0)
	Method RemoveProperty:Void(key:String)
	Method HasProperty:Bool(key:String)
	Method GetProperty:Float(key:String)
End



Class Entity
	Field components := New StringMap<IComponent>
	Field propertyLocations := New StringMap< StringMap<FloatObject> >
	
	Method SetComponent:Void(component:Component, key:String = "")
		Local type:String = GetClass(component).Name
		
		Local destination:StringMap<IComponent>
		Local destinationKey:String
		
		If key = ""
			destination = components
			destinationKey = type
		Else
			Local multiplicity := ComponentMultiplicity( components.Get(type) )
			If multiplicity = Null
				multiplicity = New ComponentMultiplicity
				components.Add(type, multiplicity)
			EndIf
			destination = multiplicity
			destinationKey = key
		EndIf
		
		Local componentOld:IComponent = destination.Get(destinationKey)
		If componentOld <> Null Then componentOld.Finalize()
		destination.Set(destinationKey, component)
		component.SetOwner(Self)
		component.ownerLocation = destination
		component.ownerKey = destinationKey
	End
	
	Method GetProperty:Float(name:String)
		Local propertyLocation := propertyLocations.Get(name)
		If propertyLocation = Null Return 0
		Local floatObject := propertyLocation.Get(name)
		If floatObject = Null Return 0
		Return floatObject.value
	End
End



Interface IComponent
	Method Finalize:Void()
End



Class ComponentMultiplicity Extends StringMap<IComponent> Implements IComponent
	Method Finalize:Void()
		For Local component := Eachin Values()
			component.Finalize()
		Next
	End
End



Class Component Implements IComponent, IProperties
	Field owner:Entity, ownerLocation:StringMap<IComponent>, ownerKey:String
	Field properties := New StringMap<FloatObject>
	
	Method Finalize:Void() Abstract
	
	Method SetOwner:Void(owner:Entity)
		If Self.owner <> Null
			ownerLocation.Remove(ownerKey)
			For Local key := Eachin Self.owner.propertyLocations.Keys()
				Local location := Self.owner.propertyLocations.Get(key)
				If location = properties
					Self.owner.propertyLocations.Remove(key)
				EndIf
			Next
		EndIf
		
		Self.owner = owner
		If owner = Null Then Return
		For Local name := eachin properties.Keys()
			owner.propertyLocations.Set(name, properties)
		Next
	End
	
	Method Remove:Void()
		SetOwner(Null)
		Finalize()
	End
	
	Method SetProperty:Void(name:String, value:Float = 0)
		properties.Set(name, New FloatObject(value) )
		If owner <> Null
			owner.propertyLocations.Set(name, properties)
		EndIf
	End
	
	Method RemoveProperty:Void(name:String)
		properties.Remove(name)
		If owner <> Null
			owner.propertyLocations.Remove(name)
		EndIf
	End
	
	Method HasProperty:Bool(name:String)
		Return ( properties.Get(name) <> Null )
	End
	
	Method GetProperty:Float(name:String)
		Local floatObject := properties.Get(name)
		If floatObject <> Null Then Return floatObject.value
		Return 0			'sketchy
	End
End



Class ComponentGetter<T>		'T must extend Component
	Global name:String
	
	Function CheckName:Void()
		If name = ""
			Local t := New T()
			name = GetClass(t).Name
			t.Finalize()
		EndIf
	End
	
	Function GetFrom:T(entity:Entity, key:String = "")
		CheckName()
		Local iComponent:IComponent = entity.components.Get(name)
		Local multiplicity := ComponentMultiplicity(iComponent)
		If multiplicity = Null
			Return T(iComponent)
		Else
			If key = ""
				For Local component := Eachin multiplicity.Values()
					Return T(component)
				Next
			Else
				Return T( multiplicity.Get(key) )
			EndIf
		EndIf
		Return Null
	End
	
	Function GetAllFrom:List<T>(entity:Entity)
		CheckName()
		Local list := New List<T>
		Local iComponent:IComponent = entity.components.Get(name)
		If Component(iComponent)
			list.AddLast( T(iComponent) )
		Else
			For Local component := EachIn ComponentMultiplicity(iComponent).Values()
				list.AddLast( T(component) )
			Next
		EndIf
		Return list
	End
End










Class _PositionComponent Extends ComponentGetter<PositionComponent> End



Class PositionComponent Extends Component

Public	
	Method New(x:Float, y:Float)
		SetProperty("x", x)
		SetProperty("y", y)
	End
	
	Method Finalize:Void()
		
	End
End



Class _FooComponent Extends ComponentGetter<FooComponent> End



Class FooComponent Extends Component
	Field value:Int
	
	Method New(value:Int)
		Self.value = value
	End
	
	Method Finalize:Void()
		Print "daisy daisy"
	End
	
	Method Bar:Void()
		Print "bar: " + value
	End
End



Function Main:Int()
	Local myEntity := New Entity()
	
	myEntity.SetComponent( New PositionComponent(16, 24) )
	
	For Local n := 0 To 5
		myEntity.SetComponent( New FooComponent(n), n )
	Next
	
	myEntity.SetComponent( New FooComponent(6), 3 )
	
	_FooComponent.GetFrom(myEntity, "5").Remove()
	
	
	
	
	Print "X: " + myEntity.GetProperty("x") + " Y: " + myEntity.GetProperty("y")
	
	Local foo:FooComponent
	foo = _FooComponent.GetFrom(myEntity)
	If foo <> Null Then foo.Bar
	
	For foo = EachIn _FooComponent.GetAllFrom(myEntity)
		foo.Bar()
	Next
	
	_PositionComponent.GetFrom(myEntity).Remove()
	
	Print "X: " + myEntity.GetProperty("x") + " Y: " + myEntity.GetProperty("y")
	
	Return 0
End

Supports having more than one component of the same type, and adds a "property" thing. I am probably done with this.

c.k.	(Posted 2013) [#5]

I wish I understood all this. :-/

Maybe someday.

Halfdan

(Posted 2013) [#6]

cool I started looking into this Entity Component thing, here is an article about it (article link)

your system looks a bit different but I'll use it as starting point

Belimoth

(Posted 2013) [#7]

Yeah it's all a bit fuzzy to me, it might be closer to aspect-oriented than component-oriented.
In hindsight...

Class Get<T>
	Function From:T(entity:Entity)
		...
	End
End
...
Get<PositionComponent>.From(myEntity)

...is much cleaner than my first attempt up there. Oh well.

Sammy

(Posted 2014) [#8]

Having just read up on component systems I was wondering if this was possible in Monkey. You example has show me it most definitely is, many thanks! :)

Goodlookinguy

(Posted 2014) [#9]

Entity component systems are overrated. It was a fad that's already expired. They're more work than they're worth. Just go the classic route unless you have a team of 10+ people and millions of lines of code. Because building games with ECS is like building a city out of Legos.