Fonts 4 Monkey

Monkey Forums/Monkey Code/Fonts 4 Monkey

DrT	(Posted 2012) [#1]

I wrote a program in PureBasic (no blasphemy intended) that allows the user to select one of the fonts installed on his/her machine, size it, style it (e.g. bold, underline, strikeout), set the front color, set the front color alpha, set the back color and set the back color alpha. The program then outputs an image (similar to mojo_font) and a text file that keeps track of the character positions and character widths.

Here is a live (flash) example: http://www.muskingum.edu/~richardt/fonts4monkey/MonkeyGame.html

You can obtain a Windows (x86) Purebasic executable at http://www.muskingum.edu/~richardt/fonts4monkey/fonts4monkey.exe

To run the executable, you will also need a text file that lists the fonts that are available on your system. You can obtain the one I used at http://www.muskingum.edu/~richardt/fonts4monkey/fonts4monkey.txt
You'll need to edit it for your system. [UPDATE: You will need to copy the text from the browser, save it in a file fonts4monkey.txt and make sure that it is in the same directory as fonts4monkey.exe]

You can obtain the source at http://www.muskingum.edu/~richardt/fonts4monkey/fonts4monkey.pb
Feel free to tweak it, compile it for Mac or Linux or port it to another language.

Here is the monkey code that generated the live example.


Strict

Import mojo

Class Font

	Private
	
	Field png:Image
	Field height:Int
	Field positions:Int[]
	Field widths:Int[]
	
	Public
	
	Method New(fontName:String)
		Local txt:String
		Local numbers:String[]
		Local positionsAndWidths:String[]
		png = LoadImage(fontName + ".png")
		txt = LoadString(fontName + ".txt")
		numbers = txt.Split(",")
		height = Int(numbers[0])
		positionsAndWidths = numbers[1 ..]
		positions = positions.Resize(positionsAndWidths.Length())
		widths = widths.Resize(positionsAndWidths.Length())
		For Local i:Int = 0 to positionsAndWidths.Length() - 1
			positions[i] = Int(positionsAndWidths[i]) / 1000
			widths[i] = Int(positionsAndWidths[i]) Mod 1000
		End
	End
	
	Method DrawText:Void(text:String, x:Float, y:Float)
		Local indexImage:Int
		Local xImage:Int
		Local yImage:Int
		Local widthImage:Int
		Local heightImage:Int
		Local deltaX:int
		For Local i:Int = 0 To text.Length() - 1
			indexImage = text[i] - 32
			xImage = positions[indexImage]
			yImage = 0
			widthImage = widths[indexImage]
			heightImage = height
			DrawImage(png.GrabImage(xImage, yImage, widthImage, heightImage), x + deltaX, y)
			deltaX = deltaX + widthImage
		End
	End
	
	Method TextWidth:Int(text:String)
		Local indexImage:int
		Local widthImage:Int
		Local result:Int
		For Local i:Int = 0 to text.Length() - 1
			indexImage = text[i] - 32
			widthImage = widths[indexImage]
			result += widthImage
		End
		Return result
	End
	
	Method TextHeight:Int()
		Return height
	End
	
End

Class MyApp Extends App

	Field font1:Font
	Field font2:Font
	
	Method OnCreate:Int()
		font1 = New Font("comic_sans_ms_40_yellow_255_transparent")
		font2 = New Font("impact_20_purple_120_transparent")
		SetUpdateRate(30)
		Return 0
	End
	
	Method OnUpdate:Int()
		Return 0
	End

	Method OnRender:Int()
		Cls()
		font1.DrawText("Fonts 4 Monkey", 50, 100)
		font2.DrawText("by DrT", 350, 140)
		Return 0
	End

End

Function Main:Int()
	New MyApp()
	Return 0
End

Notes:
I've noticed that some of the font images end up with stray artifacts. These can be cleaned up in Paint.
I will continue to work on this and post updates, so please let me know if you have any suggestions.

Sub_Zero

(Posted 2012) [#2]

Nice, thanks