point-in-polygon hit detection

Import mojo 

Class Point
	Field x:Float
	Field y:Float

Method New(x:Float, y:Float)
	Self.x = x
	Self.y = y		
End Method

Method Clone:Point()
	Return New Point(Self.x,Self.y)
End Method

Method PosEqualTo:Bool(p:Point)
	If p.x = Self.x And p.y = Self.y Then Return True Else Return False		
End Method

Method PosEqualTo:Bool(x:Float, y:Float)
	If x = Self.x And y = Self.y Then Return True Else Return False		
End Method

Method SetPos:Void(x:Float,y:Float) 
	Self.x = x
	Self.y = y	
End Method

Method ToString:String()
	Return "(" + String(Self.x) + "," + String(Self.y) + ")"
End Method
End Class
Class Line
	Field x:Float,y:Float,x2:Float,y2:Float
	
	Method New(x:Float,y:Float,x2:Float,y2:Float)
		Self.x = x; Self.y = y; Self.x2 = x2;  Self.y2 = y2
	End Method
	
	Method Draw:Void()
		DrawLine (Self.x,Self.y,Self.x2,Self.y2)
	End Method
	
	Method Direction:Vec2()
		Return New Vec2(Self.x2-Self.x, Self.y2-Self.y)
	End Method
End Class
Class Polygon
	Field Sides:List <Line>
	
	Method New()
		Sides = New List <Line>
	End Method
End Class

Function Main:Int()
	New Game()
End Function

Class Game extends App
	Field poly:Polygon = New Polygon 
	Field polyRay:Line 
	
	Field LastHitCount:Int 
	Field LastCornerCount:Int 
	Field InsidePolyTest:Int
	
	Method OnCreate:Int()
		SetUpdateRate 60
		poly.Sides.AddLast( New Line(64,64,200,96))
		poly.Sides.AddLast( New Line(200,96,360,240))
		poly.Sides.AddLast( New Line(360,240,340,400))
		poly.Sides.AddLast( New Line(340,400,128,300))		
		poly.Sides.AddLast( New Line(128,300,200,200))
		poly.Sides.AddLast( New Line(200,200,64,64))

		
	End Method

	Method OnUpdate:Int()
		polyRay = New Line(0,MouseY,MouseX,MouseY) 'Cast a ray for our In poly detection algo
		Local HitCount:Int
		Local CornerCount:Int
		
		For Local Side:Line = EachIn poly.Sides			
			Local p:Point = Intersection(Side,polyRay)
			If p <> Null Then 'Hit something
				If p.PosEqualTo(Side.x,Side.y) Then 'Hit a vertex
				'The intersection counts only if the other vertex of the side lies below the ray.
					If SideOf(Side.x2,Side.y2, polyRay) < 0 then CornerCount +=1
				ElseIf p.PosEqualTo(Side.x2,Side.y2) Then 'Hit the other vertex
				'The intersection counts only if the first vertex of the side lies below the ray.
					If SideOf(Side.x,Side.y, polyRay) < 0 then CornerCount +=1
				Else;  HitCount +=1	'Hit a side
				End If 
			End If 
		Next

		LastHitCount = HitCount 
		LastCornerCount = CornerCount 
		InsidePolyTest = (HitCount + CornerCount) Mod 2 
	End Method
	
	Method OnRender:Int()
		Cls 
		
		SetColor (0,255,255)
		SetAlpha(0.5)
		DrawLine (polyRay.x,polyRay.y,polyRay.x2,polyRay.y2)
		SetAlpha(1)

		If InsidePolyTest  = 1 Then SetColor(255,0,0)
		DrawCircle (MouseX,MouseY,4)

		For Local Side:Line = EachIn poly.Sides
			SetColor (255,255,255)
			DrawLine(Side.x,Side.y,Side.x2,Side.y2)
			Local p:Point = Intersection(Side,polyRay) 'Draw intersections
			SetColor(255,255,0); If p <> Null then DrawCircle(p.x,p.y,2)
		Next 
	
		DrawText("HitCount: " + LastHitCount + "    CornerDetect: " + LastCornerCount,8,8)
		DrawText("Inside Polygon?  " + InsidePolyTest, 8,32)
	End Method
End Class

Function Intersection:Point (AB:Line, CD:Line) 'Function returns intersection point if intersects, otherwise Null
  Local deltaACy:Float = AB.y - CD.y
  Local deltaDCx:Float = CD.x2 - CD.x
  Local deltaACx:Float = AB.x - CD.x
  Local deltaDCy:Float = CD.y2 - CD.y
  Local deltaBAx:Float = AB.x2 - AB.x
  Local deltaBAy:Float = AB.y2 - AB.y

  Local denominator:Float = deltaBAx * deltaDCy - deltaBAy * deltaDCx
  Local numerator:Float = deltaACy * deltaDCx - deltaACx * deltaDCy

  If denominator = 0 Then
    If numerator = 0 Then
      ' collinear. Potentially infinite intersection points.
      ' Check and return one of them.
      If  AB.x >= CD.x And AB.x <= CD.x2 Then
        Return New Point(AB.x, AB.y)
      ElseIf CD.x >= AB.x And CD.x <= AB.x2 Then
        Return New Point(CD.x, CD.y)
      Else
        Return Null
      End If
    Else ' parallel
      Return Null
    End If
  End If

  Local r:Float = numerator / denominator
  If r < 0 Or r > 1 Then Return Null

  Local s:Float = (deltaACy * deltaBAx - deltaACx * deltaBAy) / denominator
  If s < 0 Or s > 1 Then Return Null

  Return New Point (float(AB.x + r * deltaBAx), float(AB.y + r * deltaBAy))
End Function

Function SideOf:Float(x:Float,y:Float,l:Line)  'Determines which side of a line a point is on.
	Return Sgn(  (l.x2 - l.x)*(y - l.y) - (l.y2 - l.y)*(x - l.x)  )
End Function