Socket / Stream - Android V4 & V5 - Possible Bug?

Monkey Forums/Monkey Bug Reports/Socket / Stream - Android V4 & V5 - Possible Bug?

Yeshu777

(Posted 2015) [#1]

Hi All,

Just thought I'd share the following problem I've come across:

All tested & working fine on Android V4 devices...

Import brl.socket
Import mojo

Class MyClient Extends App Implements IOnConnectComplete, IOnSendComplete, IOnReceiveComplete

	Public

	Field _connected:Bool
	Field _socket:Socket
	Field _rx_data:DataBuffer = New DataBuffer(1024)
	Field _tx_data:DataBuffer = New DataBuffer(1024)
	Field _status:String
	Field _server:String

	Field _strs:StringList = New StringList()

	Method OnCreate:Int()
	
		_socket = New Socket("stream")
		
		_socket.ConnectAsync("192.168.0.10", 21, Self)
		
		SetUpdateRate(60)
		Return 0

	End Method

	Method OnUpdate:Int()

		UpdateAsyncEvents()
		Return 0

	End Method

	Method OnRender:Int()

		Cls
		DrawText("Status: " + _status, 10, 10)
		DrawText("Server: " + _server, 10, 30)
		Return 0

	End Method

	Method SendMore:Void()
		
		If( _strs.IsEmpty() )
		
			Print "Command List Empty!"
			'_socket.Close()
			Return
		
		EndIf
		
		Print "Sending: " + _strs.First

		Local n:Int = _tx_data.PokeString(0, _strs.RemoveFirst())
		_socket.SendAsync(_tx_data, 0, n, Self)

	End Method

	Method OnConnectComplete:Void(connected:Bool, source:Socket)
	
		If( Not connected )
			_status = "Connection Error"
			Return
		End If
	
		_status = "Connected"
	
		Print "Connection to server established"
	
		_socket.ReceiveAsync(_rx_data, 0, _rx_data.Length, Self)

'		SendMore()
	
	End Method

	Method OnSendComplete:Void(data:DataBuffer, offset:Int, count:Int, source:Socket)
	
		_socket.ReceiveAsync(_rx_data, 0, _rx_data.Length, Self)
	
		Print "OnSendComplete > ReceiveAsync"
	
	End Method

	Method OnReceiveComplete:Void( data:DataBuffer, offset:Int, count:Int, source:Socket )
		
		Local command:Int = 0;
	
		_server = _rx_data.PeekString(offset, count)

		Print "OnReceiveComplete: " + _server

		command = Int(_server[ .. 3])
		
		Print "Command: " + command

		If (command = 220) _strs.AddLast "USER anonymous ~r~n"
		
		If (command = 331) _strs.AddLast "PASS anonymous ~r~n"		'
						
		If (command = 230) _strs.AddLast "PWD ~r~n"  ' Test Log In..
					
		SendMore()

	End Method

End Class

Function Main:Int()
		
	New MyClient()

	Return 0
End Function

The problem / crash still only appears on Android V5 as soon as the stream is accessed (and it's own 'low-level' buffer). So annoying.

Error Output:


E/AndroidRuntime(28377): java.lang.UnsupportedOperationException

E/AndroidRuntime(28377): 	at java.nio.DirectByteBuffer.protectedArray(DirectByteBuffer.java:289)

E/AndroidRuntime(28377): 	at java.nio.ByteBuffer.array(ByteBuffer.java:139)

E/AndroidRuntime(28377): 	at com.lucid.ftptest.BBSocket.Receive(MonkeyGame.java:1824)

E/AndroidRuntime(28377): 	at com.lucid.ftptest.c_AsyncReceiveOp.p_Execute__UNSAFE__(MonkeyGame.java:4914)

Does the _UNSAFE_ suffix have a meaningful relevance?

Is anyone aware of underlying differences in both the 'stream' & 'socket' operations / implementation on Android V5 ?

Yeshu777

marksibly

(Posted 2015) [#2]

Just uploaded v85c which should fix this.

Yeshu777

(Posted 2015) [#3]

Thank you Mark!

Johann