reference not updating... bug?

Monkey Forums/Monkey Bug Reports/reference not updating... bug?

Nobuyuki

(Posted 2015) [#1]

Hi,

I'm having a bit of a problem updating a reference to a variable that's set as Private Global (static) in my class. I'm not sure if I made a typo, or I'm not understanding how the reference stuff works here, so my apologies if I screwed this up.

The problem occurs in the Set() function, and basically any function that tries to update currentPool in this class. This is for an asset loader, which stores Images in "asset pools" (actually a StringMap<StringMap<Image>>). Retreiving an asset works, however it seems that I'm unable to manually set currentPool to the one I want, nor can the search function update it automatically, which makes using this class very inefficient.

I'm using v82a. I'm aware that some things related to Private/Public directives may have changed recently, but since I haven't tested this code on other versions, I don't know if it works on older/newer ones.

Class Resources
  Private
	Global assets:= New StringMap<StringMap<Image>>
	Global currentPool:StringMap<Image>
	Global defaultImg:Image
  Public
	Function Init:Int(async:Bool = False)
	'This uses brl.filesystem to scan the resources.  We should do this from an asset list on platforms
	'unsupported by brl.filesystem later on.   TODO
	
	'TODO:  Support asynchronous loading.
		
		'gameScreen
		Local p:= New StringMap<Image>  'Asset pool
		Local files:= New StringStack(LoadDir("monkey://data/graphics/gamescreen/"))
		For Local o:String = EachIn files
			p.Set(o[0 .. o.FindLast(".")], LoadImage("monkey://data/graphics/gamescreen/" + o))
		Next
		assets.Set("gamescreen", p)
		
		'Tiles
		p = New StringMap<Image>  'Asset pool
		files = New StringStack(LoadDir("monkey://data/graphics/tiles/"))
		For Local o:String = EachIn files
			p.Set(o[0 .. o.FindLast(".")], LoadImage("monkey://data/graphics/tiles/" + o))
		Next
		assets.Set("tiles", p)
		
		'Default image
		defaultImg = LoadImage("default.png")
	
		'currentPool = gameScreen  'Set the asset pool to something....
	Return 0
	End Function

	'Summary:  Gets an asset from the currently active resource pool. If it can't find it in the current pool, it will search the other pools.
	Function Get:Image(assetName:String)
		Local out:Image
		
		If currentPool <> Null
			currentPool.Get(assetName)
		End If
		
		If out <> Null
			Return out
		Else  'Crap, we couldn't find what we were looking for.  Search a different resource pool.
			For Local o:= EachIn assets
				out = o.Value.Get(assetName)
				
				If out <> Null Then
					currentPool = o.Value
					Print("Resource '" + assetName + "' found in " + o.Key)
					Return out
				End If
			Next
			
			'If we've reached this far, then that means the asset couldn't be found.  Return a default.
			Print("Warning: Asset '" + assetName + "' doesn't exist; Replacing with default")
			Return defaultImg
		End If
	End Function
	
	'Summary:  Sets the active resource pool.  Case-insensitive
	Function Set:Bool(poolName:String)
		Local newPool:= assets.Get(poolName.ToLower())
		If newPool <> Null
			currentPool = newPool
			Print "Set Pool OK"
			Return True
		End If
		
		Return False
	End Function
	
End Class

edit: to test this in an example, put some assets in the data folders I specified above, and try loading from the different pools multiple times. The "Resource x found in y" message should only appear once when attempting to load an asset from a different pool, and shouldn't appear at all if Set() is called and pointed to the proper pool first. However as I run this code now, it never seems to update currentPool, either from Get() or Set().....

marksibly

(Posted 2015) [#2]

Can you reduce it down a bit?

If not, can you send me a zip with some assets in it?

Nobuyuki

(Posted 2015) [#3]

I can send you a zip. Email?

Edit: Actually, here. I'll keep this file up for a few days https://dl.dropboxusercontent.com/u/1417196/testRes.zip

marksibly

(Posted 2015) [#4]

Perhaps this...

If currentPool <> Null
	currentPool.Get(assetName)
End If

...is supposed to be...

If currentPool <> Null
	out=currentPool.Get(assetName)
End If

Nobuyuki

(Posted 2015) [#5]

wow, how did I miss that? 4am coding oversights........

thanks a bunch, sorry for the time sink, lol :(