Image MidHandle flag bug

Monkey Forums/Monkey Bug Reports/Image MidHandle flag bug

impixi

(Posted 2014) [#1]

(Monkey X Pro V81a)

When loading or creating an Image, the MidHandle flag is not correctly set. Example:

Strict

Import mojo
'Import "img2.png"

Function Main:Int()
	New MyApp
	Return 0
End

Class MyApp Extends App

	Field img:Image

	Method OnCreate:Int()
		
		Local flagTest:Int = Image.MidHandle | Image.XYPadding
		
		'Image.DefaultFlags = flagTest
		
		img = LoadImage("img2.png", 1, flagTest)
		If (Not img) Then img = CreateSampleImage(128, 128, flagTest)
		
		SetUpdateRate(60)
		Return 0
	End

	Method OnRender:Int()
	
		Cls 128, 128, 128
		
		DrawImage img, DeviceWidth()/2, DeviceHeight()/2
		
		DrawText "Handle X,Y: " + img.HandleX() + ", " + img.HandleY(), 10, 0
						
		Local flags:Int = img.Flags()
		
		If (flags & Image.MidHandle)
			DrawText "MidHandle: True", 10, 20
		Else
			DrawText "MidHandle: False", 10, 20
		Endif
		
		If (flags & Image.XPadding)
			DrawText "XPadding: True", 10, 40
		Else
			DrawText "XPadding: False", 10, 40
		Endif
		
		If (flags & Image.YPadding)
			DrawText "YPadding: True", 10, 60
		Else
			DrawText "YPadding: False", 10, 60
		Endif
		
		Return 0
	End
	
End


'-------


Function CreateSampleImage:Image(width:Int, height:Int, flags:int)
	
	Local img:Image = CreateImage(width, height, 1, flags)
	Local arr:Int[] = New Int[width * height]
	
	Local r:Int, g:Int, b:Int = 32, a:Int = 255
	
	For Local x:Int = 0 Until width
		For Local y:Int = 0 Until height
			r = Floor(Float(x) / Float(width) * 255.0)
			g = Floor(Float(y) / Float(height) * 255.0)
			arr[y * width + x] = (a Shl 24) | (r Shl 16) | (g Shl 8) | b
		Next
	Next

	img.WritePixels(arr, 0, 0, width, height) 
		
	Return img

End

This is happening because the MidHandle flag is turned off whenever the Image.SetHandle method is called. So it happens initially too, when the image is first loaded/created, even when the MidHandle flag is specified. (The actual handle xy coordinate is set correctly).

Possible fix in Image.ApplyFlags method in "graphics.monkey":

	Method ApplyFlags( iflags )
		
		flags=iflags
		
		[...]
		
		If flags & Image.MidHandle
			SetHandle width/2.0,height/2.0
			
			'********** Add the following line ******
			flags = flags | Image.MidHandle
			'****************************************
			
		Endif
		
		[...]
		
	End