DrawPoly2 is not implemented for Flash target NEW

Monkey Forums/Monkey Bug Reports/DrawPoly2 is not implemented for Flash target NEW

programmer

(Posted 2014) [#1]

Mark,
1. Please add info about DrawPoly( verts#[],image:Image,frame:Int=0 ) to the docs
2. I implemented it (license: public domain)


	private var drawPoly2Vertices3:Vector.<Number>=new Vector.<Number>( 6 );
	private var drawPoly2UvtData3:Vector.<Number>=new Vector.<Number>( 6 );

	private var drawPoly2QuadIndices:Vector.<int>=new <int>[0, 1, 2, 0, 2, 3];
	private var drawPoly2Vertices4:Vector.<Number>=new Vector.<Number>( 8 );
	private var drawPoly2UvtData4:Vector.<Number>=new Vector.<Number>( 8 );

	public function DrawPoly2( verts:Array,surface:gxtkSurface,srcx:int,srcy:int ):int{
		var n:int=verts.length/4;
		if( n<1 ) return 0;
		
		UseGraphics();

		var vertices:Vector.<Number>=null;
		var indices:Vector.<int>=null;
		var uvtData:Vector.<Number>=null;

		if (n == 1) {
			return DrawPoint( verts[0],verts[1] );
		} else if (n == 2) {
			return DrawLine( verts[0],verts[1],verts[4],verts[5] );
		} else if (n == 3) {
			vertices=drawPoly2Vertices3;
			uvtData=drawPoly2UvtData3;
		} else if (n == 4) {
			vertices=drawPoly2Vertices4;
			indices=drawPoly2QuadIndices;
			uvtData=drawPoly2UvtData4;
		} else {
			vertices=new Vector.<Number>( verts.length/2 );
			uvtData=new Vector.<Number>( verts.length/2 );
			indices=new Vector.<int>( (n-2)*3 );

			for ( var k:int=0,l:int=1;k<indices.length;k+=3,l+=1 ) {
				indices[k] = 0;
				indices[k+1] = l;
				indices[k+2] = l + 1;
			}
		}

		for ( var i:int=0,j:int=0;i<verts.length;i+=4,j+=2 ) {
			vertices[j]=verts[i];
			vertices[j+1]=verts[i+1];
			uvtData[j]=(srcx+verts[i+2])/surface.bitmap.width;
			uvtData[j+1]=(srcy+verts[i+3])/surface.bitmap.height;
		}

		graphics.beginBitmapFill( surface.bitmap.bitmapData,null,false,bitmap.smoothing );
		graphics.drawTriangles( vertices,indices,uvtData );
		graphics.endFill();
		
		return 0;
	}

.
.
.

(UPDATE: 25.07.14 - I fixed it!)
Not supports:
- color blending
- textured lines and points

Skn3	(Posted 2014) [#2]

Is this difference in rendering due to different triangulation?

programmer

(Posted 2014) [#3]

@Skn3, yep. It was my failure.

Fixed!