Socket server acceots only one client

Monkey Forums/Monkey Bug Reports/Socket server acceots only one client

Xaron

(Posted 2014) [#1]

Hey all,

I'm not the first having this problem but at least using the desktop target I don't get a simple tcp server to work with more than one client.

Here's the server:

Strict

Import mojo

Import brl.socket

' ****** TCP CLIENT ******
Class TcpClient Implements IOnSendComplete, IOnReceiveComplete
Public
  Method New( socket:Socket )
    _socket = socket
    _socket.ReceiveAsync( _data, 0, _data.Length, Self )
  End Method

Private
  Field _socket:Socket
  Field _data:DataBuffer = New DataBuffer( 1024 )

  Method OnReceiveComplete:Void( data:DataBuffer, offset:Int, count:Int, source:Socket )
    If( Not count )
      Print "TcpEchoServer: Closing client connection"
      _socket.Close()
      Return
    End If
    'Print "OnReceiveComplete"
    _socket.SendAsync( data, offset, count, Self )
  End Method

  Method OnSendComplete:Void( data:DataBuffer, offset:Int, count:Int, source:Socket )
    'Print "OnSendComplete"
    _socket.ReceiveAsync( _data, 0, _data.Length, Self )
  End Method
End Class

Class MyServer Extends App Implements IOnAcceptComplete
Private
  Field _socket:Socket
  Field _clients:List< TcpClient >
  Field _data:DataBuffer = New DataBuffer( 1024 )
  Field _strs:StringList = New StringList()

Public
  Method OnCreate:Int()
    _clients = New List< TcpClient >
    _socket = New Socket( "server" )
    Local port:Int = 12345
    If( Not _socket.Bind( "", port ) ) Error "Bind failed"
    _socket.AcceptAsync( Self )
    Print "Server created, listening on port " + port
    SetUpdateRate(60)
    Return 0
  End Method

  Method OnUpdate:Int()
    UpdateAsyncEvents()
    Return 0
  End Method

  Method OnRender:Int()
    Cls
    DrawText( "Connected clients: " + _clients.Count(), 10, 10 )
    Return 0
  End Method

Private
  Method OnAcceptComplete:Void( socket:Socket, source:Socket )
    If( Not socket ) Error "Accept error"
    Local client:TcpClient = New TcpClient( socket )
    _clients.AddLast( client )
    Print "Accepted client connection"
    Print "Connected clients: " + _clients.Count()
  End Method
End Class

Function Main:Int()
  New MyServer()
  Return 0
End Function

Here's the client:

Strict

Import mojo

Import brl.socket

Class MyClient Extends App Implements IOnConnectComplete, IOnSendComplete, IOnReceiveComplete
Public
  Field _socket:Socket
  Field _data:DataBuffer = New DataBuffer( 1024 )
  Field _status:String

  Field _strs:StringList = New StringList()

  Method OnCreate:Int()
    _strs.AddLast "Hello"
    _strs.AddLast "World!"
    _strs.AddLast "This is a test"
    _strs.AddLast "Of a"
    _strs.AddLast "TCP EchoServer"

    _socket = New Socket( "stream" )
    _socket.ConnectAsync( "localhost", 12345, Self )

    Local n:Int = _data.PokeString( 0, _strs.RemoveFirst() )
    _socket.SendAsync( _data, 0, n, Self )

    SetUpdateRate(60)
    Return 0
  End Method

  Method OnUpdate:Int()
    UpdateAsyncEvents()
    Return 0
  End Method

  Method OnRender:Int()
    Cls
    DrawText( "Status: " + _status, 10, 10 )
    Return 0
  End Method

  Method SendMore:Void()
    If( _strs.IsEmpty() )
      Print "All done!"
      _socket.Close()
      Return
    End If
    Local n:Int = _data.PokeString( 0, _strs.RemoveFirst() )
    _socket.SendAsync( _data, 0, n, Self )
  End Method

  Method OnConnectComplete:Void( connected:Bool, source:Socket )
    If( Not connected )
      _status = "Connection Error"
      Return
    End If
    _status = "Connected"
    Print "Connection to server established"
    SendMore()
  End Method

  Method OnSendComplete:Void( data:DataBuffer, offset:Int, count:Int, source:Socket )
    _socket.ReceiveAsync( _data, 0, _data.Length, Self )
    Print "OnSendComplete"
  End Method

  Method OnReceiveComplete:Void( data:DataBuffer, offset:Int, count:Int, source:Socket )
    Print "Received response: " + data.PeekString( offset, count )
    SendMore()
  End Method
End Class

Function Main:Int()
  New MyClient()
  Return 0
End Function

nikoniko

(Posted 2014) [#2]

I discovered the same issue already.
I add _socket.AcceptAsync( Self ) to the end of OnAcceptComplete method

  Method OnAcceptComplete:Void( socket:Socket, source:Socket )
    If( Not socket ) Error "Accept error"
    Local client:TcpClient = New TcpClient( socket )
    _clients.AddLast( client )
    Print1("New client " + socket.RemoteAddress.ToString())
    Print1 "Accepted client connection"
    Print1 "Connected clients: " + _clients.Count()
    _socket.AcceptAsync( Self )
  End Method

~~It's a bug.~~ or it's not bug...

nikoniko

(Posted 2014) [#3]

Anyway count of opened sockets is limited 256 by default setting in "socket.monkey"

marksibly

(Posted 2014) [#4]

Yes, you must call AcceptAsync again inside OnAcceptComplete in order to accept multiple connections.

> Anyway count of opened sockets is limited 256 by default setting in "socket.monkey"

I don't think so - what code are you referring to?

There is a 'command queue' in there that's 256 bytes long, but it's utter overkill and should probably be removed altogether as it'll just confuse things even more if I attempt to describe what it does!

nikoniko

(Posted 2014) [#5]

marksibly wrote:

I don't think so - what code are you referring to?
There is a 'command queue' in there that's 256 bytes long, but it's utter overkill and should probably be removed altogether as it'll just confuse things even more if I attempt to describe what it does!

Ops.
I misunderstand how to asyncop queue works.

AcceptAsync() and other methods add new asynevent into queue until size of queue does not overflow limit (QUEUE_SIZE).
but I don't see the code to remove items from queue in the socket.monkey...

Xaron

(Posted 2014) [#6]

Yes, you must call AcceptAsync again inside OnAcceptComplete in order to accept multiple connections.

Oh well thanks Mark, that was the problem! :)