TouchDown stuck after GameCenter.ShowLeaderBoard()

Monkey Forums/Monkey Bug Reports/TouchDown stuck after GameCenter.ShowLeaderBoard()

Fred	(Posted 2013) [#1]

Bug found in v73b IOS (device and simulator, ioS 5 and 6)

TouchDown() still returns 1 after leaving the Game Center leaderboard.
And crashes when the next touch occurs;

if you do in OnUpdate()

if TouchHit()
GameCenter.ShowLeaderBoard()
endif

The Game Center popup is called and works. But when you leave it, the game loop is back fine but TouchDown is always set to 1. And then the next finger touch crashes in this part of monkey:

void BBIosGame::TouchesEvent( UIEvent *event ){
if( [event type]==UIEventTypeTouches ){
UIView *view=_appDelegate->view;
float scaleFactor=1.0f;
if( [view respondsToSelector:@selector(contentScaleFactor)] ){
scaleFactor=[view contentScaleFactor];
}
for( int pid=0;pid<32;++pid ){
if( _touches[pid] && _touches[pid].view!=view ) _touches[pid]=0;
}

EXC_BAD_ACCESS on the last line above

I know it's not a good iOS implementation. Buttons should be triggered when they are released according to iOS rules.

(I implemented it in the right way and the bug doesn't appear then, as the touch is released before calling the leaderboard.)

maverick69

(Posted 2013) [#2]

Same bug here with Monkey v74a. Is this already fixed in the latest monkey build?

marksibly

(Posted 2013) [#3]

Can you please post some runnable code?

Just tried this (adapted from GameCenter docs) and it seems to work OK on iPod/iOS6 and simulator/iOS7...


#If TARGET<>"ios"
#Error "GameCenter is only available on iOS"
#End

Import mojo
Import brl.gamecenter

Class MyApp Extends App

	Field gamectr:GameCenter

	Field coins_collected:=0
	
	Const coins_total=25
	
	Field tdown:Bool

	Method OnCreate()
		gamectr=GameCenter.GetGameCenter()
		gamectr.StartGameCenter
		SetUpdateRate 60
	End
	
	Method OnUpdate()
		tdown=TouchDown(0)<>0
		Select gamectr.GameCenterState()
		Case 2
			If TouchHit(0)
				If Abs( MouseY-DeviceHeight/4 )<16
					gamectr.ShowLeaderboard "HIGH_SCORES"			'use the Leaderboard ID you specified in iTunes connect here...
				Else If Abs( MouseY-DeviceHeight/2 )<16
					gamectr.ShowAchievements
				Else If Abs( MouseY-DeviceHeight*3/4 )<16
				
					random.Seed=Millisecs
					gamectr.ReportScore Rnd(1000,2000),"HIGH_SCORES"
					
					coins_collected+=1
					gamectr.ReportAchievement coins_collected*100/coins_total,"COLLECT_ALL_COINS"	'use the Achievement ID you specified in iTunes connect here...
					
				Endif
			Endif
		End
	End
	
	Method OnRender()
		If tdown
			Cls 0,0,255
		Else
			Cls 0,0,0
		Endif
		DrawText "Game Center state="+gamectr.GameCenterState(),DeviceWidth/2,0,.5,0
		If gamectr.GameCenterState()<>2 SetColor 128,0,0
		DrawText "Click here to show Leaderboard",DeviceWidth/2,DeviceHeight/4,.5,.5
		DrawText "Click here to show Achievements",DeviceWidth/2,DeviceHeight/2,.5,.5
		DrawText "Click here to report Score+Achievement",DeviceWidth/2,DeviceHeight*3/4,.5,.5
	End
	
End


Function Main()
	New MyApp
End