WriteAll to filestream async

Monkey Forums/Monkey Beginners/WriteAll to filestream async

Trion

(Posted 2016) [#1]

Hello! Is here any possibility to write data to file asynchronously?
I am writing a little server using tcpasync. It works fine, but I dont want to break main loop on saving some data to server's hdd. What can you suggest?

Pharmhaus

(Posted 2016) [#2]

Here is a working example I just wrote for you:

Strict
Import mojo
Import brl.databuffer
Import brl.thread
Import brl.filestream

Function Main:Int()
	New Game()
	Return 0
End

Class Game Extends App Implements IOnWriteDataComplete

	Field _isWriting:Bool = False
	Field _writer:AsyncDataWriter
	
	'summary:The OnCreate Method is called when mojo has been initialized and the application has been successfully created.
	Method OnCreate:Int()	
		'Set how many times per second the game should update and render itself
		SetUpdateRate(60)
		
		Return 0
	End
	
	'summary: This method is automatically called when the application's update timer ticks. 
	Method OnUpdate:Int()
	
		UpdateAsyncEvents()
	
		If KeyDown(KEY_A) And _isWriting = False Then
			Print "Writing"
			_isWriting = True
			Local testData:DataBuffer = New DataBuffer(12)
			testData.PokeString(0, "Hello World!")
			_writer = New AsyncDataWriter(testData, "C:\MonkeyXPro86e\test.txt", Self)
			_writer.Start()
		EndIf
		
		Return 0
	End
	
	'summary: This method is automatically called when the application should render itself, such as when the application first starts, or following an OnUpdate call. 
	Method OnRender:Int()
		Cls()
		
		Return 0
	End
	
	'summary: is Called when a file was written successfully
	Method OnWriteDataComplete:Void(data:DataBuffer, path:String)
		_isWriting = False
	End
End


Interface IOnWriteDataComplete
	Method OnWriteDataComplete:Void(data:DataBuffer, path:String)
End

Class AsyncDataWriter Extends Thread Implements IAsyncEventSource

	Method New(data:DataBuffer, path:String, onComplete:IOnWriteDataComplete)
		_data=data
		_path=path
		_onComplete=onComplete
	End
	
	Method Start:Void()
		AddAsyncEventSource Self
		_stream = UnsafeFileStream.Open(_path, "w")
		Super.Start
	End
	
	Private
	
	Field _stream:UnsafeFileStream
	Field _data:DataBuffer
	Field _path:String
	Field _onComplete:IOnWriteDataComplete

	Method Run__UNSAFE__:Void()
		_stream.Write__UNSAFE__(_data, 0, _data.Length)
	End
		
	Method UpdateAsyncEvents:Void()
		If IsRunning() Return
		RemoveAsyncEventSource Self
		_stream.Close()
		_onComplete.OnWriteDataComplete(_data, _path)
	End
	
End

Class UnsafeFileStream Extends Stream

	Method New( path:String,mode:String )
		_stream=OpenStream( path,mode )
		If Not _stream Error "Failed to open stream"
	End
	
	Method Close:Void()
		If Not _stream Return
		_stream.Close
		_stream=Null
	End
	
	Method Eof:Int() Property
		Return _stream.Eof()
	End
	
	Method Length:Int() Property
		Return _stream.Length()
	End
	
	Method Position:Int() Property
		Return _stream.Position()
	End
	
	Method Seek:Int( position:Int )
		Return _stream.Seek( position )
	End
	
	Method Read:Int( buffer:DataBuffer,offset:Int,count:Int )
		Return _stream.Read( buffer,offset,count )
	End
	
	Method Write__UNSAFE__:Int(buffer:DataBuffer, offset:Int, count:Int)
		Return _stream.Write( buffer,offset,count )
	End
	
	Function Open:UnsafeFileStream(path:String, mode:String)
		Local stream:=OpenStream( path,mode )
		If stream Return New UnsafeFileStream(stream)
		Return Null
	End
	
	Private
	
	Method New( stream:BBFileStream )
		_stream=stream
	End
	
	Function OpenStream:BBFileStream( path:String,mode:String )
		Local stream:=New BBFileStream
		Local fmode:=mode
		If fmode="a" fmode="u"
		If Not stream.Open( path,fmode ) Return Null
		If mode="a" stream.Seek stream.Length()
		Return stream
	End

	Field _stream:BBFileStream
	
End

Pharmhaus

(Posted 2016) [#3]

There are a few things to note:
Monkeys Garbage Collector does not like creating object (no new XYZ, strings work when using StrDup) on a different thread than the mainthread.
Also, all methods that the are called by the thread need to end with __UNSAFE__ or need to be defined as extern.
The class you see at the bottom is just in copy of the regular filestream with the name of write changed to unsafe.

Trion

(Posted 2016) [#4]

Wow! Thank you! Very nice stuff!