How do I create a transparent rectangle

Monkey Forums/Monkey Beginners/How do I create a transparent rectangle

En929

(Posted 2015) [#1]

How do I create a white rectangle box that's transparent in the middle?

ImmutableOctet(SKNG)

(Posted 2015) [#2]

Do you mean the entire thing, or just the outline (Wireframe quad). For a transparent rectangle, use 'DrawRect' and 'SetAlpha' (As well as 'SetBlend', depending on what you're doing). For a wire-frame look, you could either use custom OpenGL code, or render it using lines yourself. To manually draw the rectangle's lines, you can use the 'DrawLine' command.

Here's an example using standard Mojo:

Strict

Public

' Imports:
Import mojo

' Functions:
Function Main:Int()
	New Application()
	
	' Return the default response.
	Return 0
End

' Classes
Class Application Extends App Final
	' Constant variable(s):
	Const MODE_NORMAL:= 0
	Const MODE_TRANSPARENT:= 1
	Const MODE_LINES:= 2
	Const MODE_RESET:= (MODE_LINES+1)
	
	' Constructor(s):
	Method OnCreate:Int()
		SetUpdateRate(0) ' 60
		
		' Return the default response.
		Return 0
	End
	
	' Methods:
	Method OnRender:Int()
		' Constant variable(s):
		Const Width:= 64.0
		Const Height:= Width ' 64
		
		Const HalfWidth:= (Width / 2.0) ' * 0.5
		Const HalfHeight:= (Height / 2.0) ' * 0.5
		
		Cls()
		
		Translate(-HalfWidth, -HalfHeight)
		Translate(DeviceWidth()/2, DeviceHeight()/2)
		
		Select Mode
			Case MODE_NORMAL
				DrawRect(0.0, 0.0, Width, Height)
			Case MODE_TRANSPARENT
				SetAlpha(0.5)
				DrawRect(0.0, 0.0, Width, Height)
				SetAlpha(1.0)
			Case MODE_LINES
				DrawLine(0.0, 0.0, Width, 0.0)
				DrawLine(0.0, 0.0, 0.0, Height)
				DrawLine(Width, 0.0, Width, Height)
				DrawLine(0.0, Height, Width, Height)
		End Select
		
		' Return the default response.
		Return 0
	End
	
	Method OnUpdate:Int()
		If (KeyHit(KEY_SPACE)) Then
			Mode = ((Mode+1) Mod MODE_RESET)
		Endif
		
		' Return the default response.
		Return 0
	End
	
	' Fields:
	Field Mode:Int
End

Press space to cycle through the modes.

En929

(Posted 2015) [#3]

Thanks ImmutableOctet(SKNG). That worked!