Mojo 2 : only scale an image.

Monkey Forums/Monkey Beginners/Mojo 2 : only scale an image.

hub	(Posted 2015) [#1]

Hi !
1) How to only scale an image with modo2 ? not all the device screen or others images.
2) Is it possible to 'zoom' on it with the mouse as 'Lightroom' magnifying glass tool ?
Thanks.

ImmutableOctet(SKNG)

(Posted 2015) [#2]

You mean like zooming from the center/handle? Because, though there's plenty of ways to handle this yourself, Mojo and Mojo 2 both have overloads that can do this.

For Mojo, you have 'DrawImage' and 'DrawImageRect', which have useful overloads for this (As linked). If you want to do this manually, then you can do something similar to what those overloads do.

For Mojo 2, it's basically the same deal, it's just accessed through a 'DrawList' or 'Canvas' object. And, the 'DrawImageRect' command is just handled by 'DrawRect' overloads.

hub	(Posted 2015) [#3]

Many thanks. I use mojo2. i'm searching the commands

1) i use PushMatrix - Scale or Rotate - DrawImage - PopMatrix
2) set the push 'operation origin x,y to the mouse position MouseX(), MouseY() ... so my other question :

How to set the matrix 'operation origin'.

Actually i've it at 0,0. Note that my image PosX = DeviceWidth()/2 and PosY = DeviceWidth() and by default 'MidHandled'

Thanks !

ImmutableOctet(SKNG)

(Posted 2015) [#4]

Here, I'll just post an example:

Strict

Public

' Imports:
Import mojo2

' Classes:
Class Application Extends App Final
	' Constructor(s):
	Method OnCreate:Int()
		SetUpdateRate(0) ' 60
		
		Graphics = New Canvas()
		
		TestImage = New Image(64, 64)
		
		TestCanvas = New Canvas(TestImage)
		
		' Return the default response.
		Return 0
	End
	
	' Methods:
	Method OnRender:Int()
		Graphics.Clear((1.0-(Sin(Rotation)*0.5)), Cos(Rotation), 0.0)
		
		Draw(Graphics, TestImage, MouseX(), MouseY(), 4.0, 2.0, Rotation)
		
		Graphics.Flush()
		
		TestCanvas.Clear(0.0, 0.0, Sin(Rotation * 2.0))
		TestCanvas.Flush()
		
		' Return the default response.
		Return 0
	End
	
	Method OnUpdate:Int()
		Rotation = (Millisecs()/10)
		
		' Return the default response.
		Return 0
	End
	
	Method Draw:Void(Graphics:Canvas, I:Image, X:Float, Y:Float, ScaleX:Float, ScaleY:Float, Rotation:Float)
		Graphics.PushMatrix()
		
		Graphics.Translate(X, Y)
		Graphics.Scale(ScaleX, ScaleY)
		Graphics.Rotate(Rotation)
		
		Graphics.DrawImage(I)
		
		Graphics.PopMatrix()
		
		Return
	End
	
	' Fields:
	Field Graphics:Canvas
	
	Field TestImage:Image
	Field TestCanvas:Canvas
	
	Field Rotation:Float
End

' Functions:
Function Main:Int()
	New Application()
	
	' Return the default response.
	Return 0
End

hub	(Posted 2015) [#5]

Many thanks SKNG.