Is Monkey-X a good choice for a beginner?

Monkey Forums/Monkey Beginners/Is Monkey-X a good choice for a beginner?

mejon

(Posted 2015) [#1]

Hello,

I'm new to app development, and I was wondering if Monkey- X is a good choice for someone with no experience in app development? Also, how long would it take someone to learn Monkey - X?

therevills

(Posted 2015) [#2]

The language is good for beginners, but the SDKs can be a pain to install from scratch.

What are you after creating?

mejon

(Posted 2015) [#3]

For now, just very simple game like Hangman for example.

therevills

(Posted 2015) [#4]

Double post...

therevills

(Posted 2015) [#5]

Okay, I've just knocked together a quick Hangman game to give you an example of what is needed (of course this could be coded in several different ways):

https://dl.dropboxusercontent.com/u/35103024/tutorials/hangman.buildv84b/html5/MonkeyGame.html

Strict

Import mojo

Function Main:Int()
	New HangManApp()
	Return 0
End

Class HangManApp Extends App
	Field hangMan:HangMan
	Field words:String[10]
	Field currentWord:Int
	Field correctLettersList:List<String> = New StringList
	Field gameStatus:Int
	
	Const PLAYING:Int = 0
	Const WIN:Int = 1
	Const LOSE:Int = 2
		
	Method OnCreate:Int()
		SetUpdateRate(60)
		
		Local date := GetDate()
		Seed = date[5] * 1000 + date[6]
		
		CreateWords()
		SetUp()
		
		Return 0
	End
	
	Method CreateWords:Void()
		words[0] = "MONKEY"
		words[1] = "PROGRAMMING"
		words[2] = "LANGUAGE"
		words[3] = "COOL"
		words[4] = "PAPER"
		words[5] = "JOYSTICK"
		words[6] = "KEYBOARD"
		words[7] = "MONITOR"
		words[8] = "COMPUTER"
		words[9] = "MOUSE"
	End
	
	Method SetUp:Void()
		hangMan = New HangMan(300, 100, 100, 200)
		currentWord = Rand(0, words.Length() - 1)
		correctLettersList.Clear()
		gameStatus = PLAYING
	End
	
	Method OnUpdate:Int()
		If gameStatus = PLAYING
			Repeat
				Local char := GetChar()
				If Not char Exit
				If char >= 32
					Local c:String = String.FromChar( char )
					c = c.ToUpper()
					If words[currentWord].Contains(c)
						correctLettersList.AddLast(c)
					Else
						hangMan.stage += 1
					End
				End
			Forever
		End
		If gameStatus = WIN Or gameStatus = LOSE
			If KeyHit(KEY_SPACE)
				SetUp()
			End
		End
		Return 0
	End
	
	Method OnRender:Int()
		Cls
		hangMan.Draw()
		DrawWord()
		Return 0
	End	
	
	Method DrawWord:Void()
		Local x:Int = 100
		Local y:Int = 400
		Local w:Int = 10
		Local gap:Int = 20
		Local correct:Int = 0
		
		For Local i:Int = 0 To words[currentWord].Length() - 1
			Local chars := words[currentWord].ToChars()
			Local currentLetter:String = String.FromChar( chars[i] )
			If correctLettersList.Contains( currentLetter ) Or gameStatus = LOSE
				DrawText (currentLetter, x + gap * i, y - 25)
				correct += 1
			End
			DrawLine (x + gap * i, y, w + (x + gap * i), y)
		Next
		
		If correct = words[currentWord].Length()
			DrawText ("You Win!", 100, y + 25)
			gameStatus = WIN
		End
		If hangMan.stage > hangMan.maxStage
			DrawText ("You Lose!", 100, y + 25)	
			gameStatus = LOSE
		End
		If gameStatus = WIN Or gameStatus = LOSE
			DrawText ("Press Space to Replay!", 100, y + 50)	
		End
	End
End

Class HangMan
	Field x:Float, y:Float
	Field w:Float, h:Float
	Field headDiameter:Float
	Field bodyHeight:Float
	Field armLength:Float
	Field legLength:Float
	Field stage:Int
	Field maxStage:Int = 5
	
	Method New(x:Float, y:Float, w:Float, h:Float)
		Self.x = x
		Self.y = y
		Self.w = w
		Self.h = h
		Self.stage = 0
		Self.headDiameter = w / 4
		Self.bodyHeight = h / 2.5
		Self.armLength = w / 3
		Self.legLength = h / 6
	End
	
	Method Draw:Void()
		DrawGallows()
		If stage > 0 Then DrawHead()
		If stage > 1 Then DrawTorso()
		If stage > 2 Then DrawLeftArm()
		If stage > 3 Then DrawRightArm()
		If stage > 4 Then DrawLeftLeg()
		If stage > 5 Then DrawRightLeg()
	End
	
	Method DrawGallows:Void()
		DrawLine(x  + (w / 4), y, x + w, y)
		DrawLine(x + w, y, x + w, y + h)
		DrawLine(x, y + h, x + w + (w / 4), y + h)
		DrawLine(x  + (w / 4), y, x  + (w / 4), y + (h / 6))
	End

	Method DrawHead:Void()
		DrawOval(x  + ( w / 4 ) - headDiameter / 2, y + ( h / 6 ), headDiameter, headDiameter)
	End 

	Method DrawTorso:Void()
		DrawLine(x  + ( w / 4 ), y + ( h / 6 ) + headDiameter, x  + ( w / 4 ), y + ( h / 6 ) + bodyHeight)
	End

	Method DrawLeftArm:Void()
		DrawLine(x  + ( w / 4 ), y + ( h / 6 ) + headDiameter, x  + ( w / 4 ) - armLength, y + ( h / 6 ) + (bodyHeight / 2))
	End

	Method DrawRightArm:Void()
		DrawLine(x  + ( w / 4 ), y + ( h / 6 ) + headDiameter, x  + ( w / 4 ) + armLength, y + ( h / 6 ) + (bodyHeight / 2))
	End

	Method DrawLeftLeg:Void()
		DrawLine(x  + ( w / 4 ),  y + ( h / 6 ) + bodyHeight, x  + ( w / 4 ) - legLength, y + ( h / 6 ) + bodyHeight * 1.5)
	End

	Method DrawRightLeg:Void()
		DrawLine(x  + ( w / 4 ),  y + ( h / 6 ) + bodyHeight, x  + ( w / 4 ) + legLength, y + ( h / 6 ) + bodyHeight * 1.5)
	End
End

Function Rand:Int(vmin:Int, vmax:Int)
	Return Rnd(vmin, vmax + 1)
End

Gerry Quinn

(Posted 2015) [#6]

Monkey is pretty easy to learn IMO, and it is like most Basics in that it comes with easy to use functions for getting graphics on the screen etc. So I would say it is quite good for beginners. And there is the advantage of multiple targets (though as therevills says, you have to install some extra stuff before they work).