Collision detection OOP

Monkey Forums/Monkey Beginners/Collision detection OOP

vic	(Posted 2015) [#1]

Hi,

I have made 3 seperate classes Player (p), Enemy (e) and Bullet (b) and ran into below described problem with some simple collison detection function.

How could/should I use the following collision detection code,

If rectsoverlap(b.x,b.y,5,5,e.x,e.y,32,32) = True
...<do something with Enemy/Bullet>
End if

I either end up with a NullObjectAccess error when placed in OnUpdate() method) or
when placed inside the Bullet class it seems it cannot access the Enemy x, y position and vice versa.

The rectsoverlap function:
Function rectsoverlap:Int(x1:Int, y1:Int, w1:Int, h1:Int, x2:Int, y2:Int, w2:Int, h2:Int)
If x1 > (x2 + w2) Or (x1 + w1) < x2 Then Return False
If y1 > (y2 + h2) Or (y1 + h1) < y2 Then Return False
Return True
End

Salmakis

(Posted 2015) [#2]

if you get a "NullObjectAccess" then this might be refer to the object e, instead of its field x, otherwise x would just something like 0 or whatever you defined for its Default values
so maybe in this Moment the object e seems to be null.
Did you called something like
e = new Enemy(...)
or if you got an own constructor like enemy.Create(...) then maybe you not returned your new object?

Pakz	(Posted 2015) [#3]

The rectsoverlap function is not correct btw. I found the same function on this forum but found that it collides one pixel distance from the true collision point. I fixed it by putting = characters in the function.

See below.

Function rectsoverlap:Bool(x1:Int, y1:Int, w1:Int, h1:Int, x2:Int, y2:Int, w2:Int, h2:Int)
    If x1 >= (x2 + w2) Or (x1 + w1) <= x2 Then Return False
    If y1 >= (y2 + h2) Or (y1 + h1) <= y2 Then Return False
    Return True
End

This one makes sure that collision rectangles can touch eachother, Your function collides when it is next to a rectangle.

For you original post. Were you using global or local? I am stil new at monkey so I might be completely wrong with the error message.

I have lots of examples on my blog(monkey tutorial section) that might help you learn how to do the collision things. I use rectsoverlap a lot. I am going to make a beginners example with a player class and enemy class and bullet class after reading your post. I think it will be ready soon.

I already messed up some of my examples by using the older rectsoverlap I found a few days ago. This I still need to repair now.

Edit :

Here is the example I made. I hope it was close to what you ment to do.

Import mojo

Class player
	Field x:Float,y:Float
End Class

Class bullet
	Field x:Float,y:Float
	Field active:Bool
End Class

Class enemy
	Field x:Float,y:Float
End Class

Global p:player = New player
Global e:enemy = New enemy
Global b:bullet = New bullet

Class MyGame Extends App

    Method OnCreate()
        SetUpdateRate(60)
        p.x = 320
        p.y = 240
        e.x = 460
        e.y = 240
    End Method
    Method OnUpdate()
		' if the user presses space
    	If KeyHit(KEY_SPACE)
    		' if the bullet is not active
    		If b.active = False
    			' put the bullet at the player position
    			b.x = p.x+32
    			b.y = p.y+12
    			' activate the bullet
    			b.active = True
    		End If
    	End If
    	' if the bullet is active
    	If b.active = True 
    		' increase the position by 1 to the right
    		b.x += 1
    		' if the bullet hits the enemy then set the 
    		' bullet active to false
    		If rectsoverlap(b.x,b.y,6,6,e.x,e.y,32,32)
    			b.active = False
    		End If
    		' if the bullet gets out of the screen area
    		' then set it to not active
    		If rectsoverlap(b.x,b.y,0,0,0,0,640,480) = False Then b.active = False
    	End If
    End Method
    Method OnRender()
        Cls 0,0,0 
        SetColor 255,255,255
       	' draw player
       	DrawRect p.x,p.y,32,32
       	' draw enemy
       	DrawRect e.x,e.y,32,32
       	' draw bullet if it is active
       	If b.active = True Then DrawRect b.x,b.y,6,6
       	DrawText "Press space to fire bullet.",0,0
    End Method
End Class

Function rectsoverlap:Bool(x1:Int, y1:Int, w1:Int, h1:Int, x2:Int, y2:Int, w2:Int, h2:Int)
    If x1 >= (x2 + w2) Or (x1 + w1) <= x2 Then Return False
    If y1 >= (y2 + h2) Or (y1 + h1) <= y2 Then Return False
    Return True
End

Function Main()
    New MyGame()
End Function

vic	(Posted 2015) [#4]

Thanks for your reply Salmakis & Pakz.
@Pakz: I tried your code and it runs fine, I just want to understand what I am doing wrong (or what is missing) in my code.

In the Bullet class Update method I want to check if the bullet overlaps the enemy x,y but somehow I don't have 'access' to either the bullet x,y or enemy x,y from there.


Import mojo

Global players:List<Player> = New List<Player> 
Global enemies:List<Enemy> = New List<Enemy> 
Global bullets:List<Bullet> = New List<Bullet> 

Global p:Player
Global b:Bullet
Global e:Enemy

Class Player 

  Field x:Float
  Field y:Float

  'Field sprite:Image = LoadImage("sprites.png",32,32,64, Image.MidHandle)  
  'Field backgr:Image = LoadImage("nebula2.png", Image.MidHandle)  

  Field bgX:Float
  Field bgY:Float 
  

   Method New(x, y)
       Self.x = x
       Self.y = y
   End Method
 
  Method Update()
     
     'bgY += 0.02
     
      If KeyDown(KEY_LEFT) 
         x -= 3.0    
      End If
      If KeyDown(KEY_RIGHT) 
        x += 3.0   
      End If
      If KeyHit(KEY_SPACE)
        b = New Bullet(x,y)
      End If
   
   End Method   

   Method Draw()
      
       DrawRect(x,y,25,25)
       'DrawImage(backgr,bgX,bgY)
       'DrawImage(sprite,x,y,1)
       'DrawText("Players: "+players.Count,10,10)
       
  End Method
  
  Method Destroy()
        players.RemoveLast
  End Method
  
  '--- Player Functions  
  Function Create()
      Local p:Player 
        players.AddLast(New Player(300,400))
  End Function
  
  Function UpdateAll()
      For Local p:=Eachin players
          p.Update()
      Next
  End Function
  
   Function DrawAll()
      For Local p:=Eachin players
          p.Draw()
      Next
  End Function
  

End Class

Class Enemy 
  
  Field x:Float
  Field y:Float

  Field angle:Float
  'Field sprite:Image = LoadImage("sprites.png",32,32,64, Image.MidHandle) 
  Field vX:Float = 1
  'Field vY:Float
  Field rem:Bool = False   
  Field phase:Float

  Field counter:Float = 1.0
  
  Method New(x, y)
      Self.x = x
      Self.y = y
            
  End Method

  Method Update()
   
         phase += 3.2
         Local magnitude:Float = 1.65
         Local speed:Float = 0.2
         y += Sin((Millisecs() + phase)* speed) * magnitude
         x += vX 
          If x > 400 Or x < 0
               vX *= -1              
          Endif
      
  End Method
  
  Method Draw()
    
    DrawOval(x+100,y+100,20,20)
      DrawText "Enemies: "+enemies.Count, 300,10
      DrawText "Enemy X : "+x,300,30
      DrawText "Enemy Y : "+y,300,50
    
  End
  
  Method Destroy()
         enemies.RemoveLast(Self)
  End Method
  
  '--- Enemy Functions
  Function Create()
      For Local i = 0 Until 5
       Local e:Enemy = New Enemy
        e.x = i*20
        e.y = i*20
        'e.counter += 1
      enemies.AddLast(e)
      Next 
  End Function
  
  Function UpdateAll()
     For Local e:=Eachin enemies
          e.Update()
     Next
  End Function
  
  Function DrawAll()
      For Local e:=Eachin enemies
            e.Draw()
      Next
  End Function
    

End Class

Class Bullet
  
  Field x:Float
  Field y:Float
  Field rem:Bool = False   
  Field speedY:Float = 5
  
  Method New(x, y)
      Self.x = x
      Self.y = y - 15
      bullets.AddLast(Self)
  End Method 
    
  Method Update()
      y -= speedY
      If y < 0 
        Destroy()
       Endif  
    
   'This code gives a NullObjectAccess error when pressing Spacebar
    If rectsoverlap(b.x,b.y,5,5,e.x,e.y,20,20) = True
        Print("Hit")
    Endif  

  End Method
  
  Method Draw()
      DrawOval(x,y,5,5)
      DrawText("Bullets "+bullets.Count,10,30)
  End Method  
  
  Method Destroy()
        bullets.RemoveLast(Self)
  End Method
  
  '--- Bullet functions
  Function UpdateAll()
      For Local b:=Eachin bullets
              b.Update()
     Next
   End Function
  
  Function DrawAll()
      For Local b:=Eachin bullets
            b.Draw()
      Next
  End Function

  
End Class

Function rectsoverlap:Bool(x1:Int, y1:Int, w1:Int, h1:Int, x2:Int, y2:Int, w2:Int, h2:Int)
    If x1 >= (x2 + w2) Or (x1 + w1) <= x2 Then Return False
    If y1 >= (y2 + h2) Or (y1 + h1) <= y2 Then Return False
    Return True
End

Function getangle:Float(x1:Float,y1:Float,x2:Float,y2:Float)
         Local dx = x2 - x1
         Local dy = y2 - y1
         Return ATan2(dy,dx)+360 Mod 360
End Function

Gerry Quinn

(Posted 2015) [#5]

You have a separate single global e:Enemy which is never set so it is null when accessed. The enemies are in the global enemies:List< Enemy >.

There seems no reason for p, e or b to exist (you seem to have multiple players too).

Your Bullet.Update() should go through the list of enemies, testing against each.

vic	(Posted 2015) [#6]

Woohoo, I got it working... thanks guys :)