How do I make a character do rapid fire

Global GunTimer:Int = Millisecs()
Global GunCoolDown:Int = 500 ' 1 bullet every half a second. decreasing will increase the rate of fire.

Method UpdateTimers:void()
  if Millisecs() > GunTimer+GunCoolDown
    GunTimer=Millisecs()
    'OK TO FIRE A BULLET
  endif
End Method

Strict

Import mojo

Function Main:Int()
	Local ExampleApp:= New ExampleApp
	Return 0
End Function

	Const LEFT:Int = 1
	Const RIGHT:Int = 2

Class ExampleApp Extends App
	
	
	Field gunTimer:Int
	Field gunDelay:Int
	
	Field playerX:Int
	Field playerY:Int
	Field playerDirection:Int
		
	Field shooting:Bool 
	Method New()
		Self.gunDelay=100 'change this to change the rate of fire.
		Self.playerX=640/2
		Self.playerY=480/2
		Self.playerDirection = LEFT
		Self.shooting=False
	End Method
	
	Method OnUpdate:Int()
		
		
		If KeyDown(KEY_LEFT) Then
			Self.playerX-=2
			Self.playerDirection=LEFT
		Endif
		If KeyDown(KEY_RIGHT) Then
			Self.playerX+=2
			Self.playerDirection=RIGHT
		Endif			
		
		If KeyDown(KEY_SPACE) Then
			Self.shooting=True
		Else
			Self.shooting=False
		Endif
		
		If Millisecs() > Self.gunTimer+Self.gunDelay And Self.shooting
			Self.gunTimer=Millisecs()
			Local NewBullet:cBullet = New cBullet(Self.playerX,Self.playerY,Self.playerDirection)
		Endif
		
		
		For Local B:cBullet = Eachin BulletList
			B.Update()
		Next
	
		Return 0
	End Method
	
	Method OnRender:Int()
		Cls	
		
		DrawRect(Self.playerX,Self.playerY,30,30)
		Select Self.playerDirection
			Case LEFT
				DrawRect(Self.playerX-10,Self.playerY+10,10,10)			
			Case RIGHT
				DrawRect(Self.playerX+30,Self.playerY+10,10,10)			
		End Select

		For Local B:cBullet = Eachin BulletList
			B.Render()
		Next
				
		Return 0
	End Method
	
End Class

Global BulletList:List<cBullet> = New List<cBullet>

Class cBullet
	Field x:Int
	Field y:Int
	Field speed:Float
	
	Method New(_x:Int , _y:Int , _direction:Int)
		Self.x=_x
		Self.y=_y
		Select _direction
			Case LEFT
				Self.speed=-5
			Case RIGHT
				Self.speed=5
		End Select
		BulletList.AddLast(Self)
	End Method
	
	Method Update:Void()
		If Self.x<0 Then BulletList.Remove(Self)
		Self.x+=Self.speed
	End Method 
	
	Method Render:Void()
		DrawRect(Self.x,Self.y,10,10)	
	End Method
	
End Class