ScaleEX: New scaling filter for 2D art!

Community Forums/Showcase/ScaleEX: New scaling filter for 2D art!

ErikT

(Posted 2010) [#1]

Hello everybody!

This here is my own addition to the scaling filters designed to make old-school pixel art more appealing to modern eyes. In contrast to filters like Bilinear and Bicubic Filtering which turns everything into a blurry mess, these smooth images by checking pixels around the source pixel to be scaled, then pick the most appropriate one out of those. So they're great for scaling lo-res art with few colors! There's only one problem: most of them are released under the GPL license, which kinda sucks for anyone wanting to use them in commercial projects. So I tried to rewrite the Scale2X algorithm without using any of the GPL'ed source code while borrowing a couple of tricks from Xenowhirl's RotSprite tool and Screaming Duck's Scale2X version. This is what I got so far. It produces smoother results than regular Scale2X but also runs a little slower:

Nearest neighbour:

ScaleEX:

Nearest neighbour:

ScaleEX:

Nearest neighbour:

ScaleEX:


' standard Scale2X.

Function Scale2X(Pixmap:TPixmap)

	Local Pix_W:Int = PixmapWidth(Pixmap)
	Local Pix_H:Int = PixmapHeight(Pixmap)
	Local x:Int
	Local y:Int

	Local ScaledPixmap:TPixmap = CreatePixmap(Pix_W*2,Pix_H*2,PF_RGB888)

	Local P:Int
	Local A:Int
	Local B:Int
	Local C:Int
	Local D:Int

	Local P_1:Int
	Local P_2:Int
	Local P_3:Int
	Local P_4:Int

	' go through all pixels in the image
	For x = 0 To Pix_W - 1
		For y = 0 To Pix_H - 1

			' read the source pixel and its surrounding pixels
			P = ReadPixel(Pixmap,x,y)
			If x > 0 And x < Pix_W - 1 And y > 0 And y < Pix_H - 1
				A = ReadPixel(Pixmap,x,y-1)
				B = ReadPixel(Pixmap,x+1,y)
				C = ReadPixel(Pixmap,x-1,y)
				D = ReadPixel(Pixmap,x,y+1)
			Else
				A = P
				B = P
				C = P
				D = P
			EndIf

			P_1 = P
			P_2 = P
			P_3 = P
			P_4 = P

			' check for equal pixels around P and modify output pixels accordingly
			If A = C And B <> C And A <> D Then P_1 = A
			If A = B And B <> C And A <> D Then P_2 = B
			If D = C And A <> D And B <> C Then P_3 = C
			If B = D And B <> C And A <> D Then P_4 = D


			WritePixel(ScaledPixmap,x*2,y*2,P_1)
			WritePixel(ScaledPixmap,(x*2)+1,y*2,P_2)
			WritePixel(ScaledPixmap,x*2,(y*2)+1,P_3)
			WritePixel(ScaledPixmap,(x*2)+1,(y*2)+1,P_4)
		Next
	Next

	OutputPixmap = CopyPixmap(ScaledPixmap)

End Function



Global InputPixmap:TPixmap = LoadPixmap("C:\input_ff.bmp")
Global OutputPixmap:TPixmap

Global TestImg:TImage



Graphics 800,600,32


ScaleEX(InputPixmap)
TestImg = LoadImage(OutputPixmap)


While Not KeyDown(KEY_ESCAPE)

	Cls
		DrawImage(TestImg,0,0)
	Flip

Wend

End


' My super-duper ScaleEX :] Inspired by Xenowhirl's RotSprite tool and Screaming Duck's
' expanded Scale2X algorithm. 

Function ScaleEX(Pixmap:TPixmap)

	Local Pix_W:Int = PixmapWidth(Pixmap)
	Local Pix_H:Int = PixmapHeight(Pixmap)
	Local x:Int
	Local y:Int

	Local ScaledPixmap:TPixmap = CreatePixmap(Pix_W*2,Pix_H*2,PF_RGB888)

	Local P:Int
	Local A:Int
	Local B:Int
	Local C:Int
	Local D:Int
	Local FL:Int	' far left pixel (beside C)
	Local TR:Int	' top right pixel
	Local FR:Int	' far right pixel (beside B)
	Local TL:Int	' top left pixel
	Local FT:Int	' far top pixel
	Local FB:Int	' far bottom pixel
	Local BL:Int	' bottom left pixel
	Local BR:Int	' bottom right pixel

	Local P_1:Int	' output pixel top-left
	Local P_2:Int	' output pixel top-right
	Local P_3:Int	' output pixel bottom-left
	Local P_4:Int	' output pixel bottom-right

	' RotSprite vars
	Local P_Clr:Int[4]	' 1 = R, 2 = G, 3 = B
	Local A_Clr:Int[4]	' 1 = R, 2 = G, 3 = B
	Local B_Clr:Int[4]	' 1 = R, 2 = G, 3 = B
	Local C_Clr:Int[4]	' 1 = R, 2 = G, 3 = B
	Local D_Clr:Int[4]	' 1 = R, 2 = G, 3 = B
	Local P_Value:Int		' holds average of RGB values
	Local A_Value:Int
	Local B_Value:Int
	Local C_Value:Int
	Local D_Value:Int

	' go through all pixels in the image
	For x = 0 To Pix_W - 1
		For y = 0 To Pix_H - 1

			' read the source pixel and its surrounding pixels
			P = ReadPixel(Pixmap,x,y)
			If x > 0 And x < Pix_W - 1 And y > 0 And y < Pix_H - 1
				A = ReadPixel(Pixmap,x,y-1)
				B = ReadPixel(Pixmap,x+1,y)
				C = ReadPixel(Pixmap,x-1,y)
				D = ReadPixel(Pixmap,x,y+1)
			Else
				A = P
				B = P
				C = P
				D = P
			EndIf

			P_1 = P
			P_2 = P
			P_3 = P
			P_4 = P

			' get colors
			P_Clr[1] = (P & $FF0000) Shr 16	' red
			P_Clr[2] = (P & $FF00) Shr 8		' green
			P_Clr[3] = (P & $FF)			' blue
			A_Clr[1] = (A & $FF0000) Shr 16	' red
			A_Clr[2] = (A & $FF00) Shr 8		' green
			A_Clr[3] = (A & $FF)			' blue
			B_Clr[1] = (B & $FF0000) Shr 16	' red
			B_Clr[2] = (B & $FF00) Shr 8		' green
			B_Clr[3] = (B & $FF)			' blue
			C_Clr[1] = (C & $FF0000) Shr 16	' red
			C_Clr[2] = (C & $FF00) Shr 8		' green
			C_Clr[3] = (C & $FF)			' blue
			D_Clr[1] = (D & $FF0000) Shr 16	' red
			D_Clr[2] = (D & $FF00) Shr 8		' green
			D_Clr[3] = (D & $FF)			' blue

			' set average value from RGB
			P_Value = (P_Clr[1] + P_Clr[2] + P_Clr[3]) / 3
			A_Value = (A_Clr[1] + A_Clr[2] + A_Clr[3]) / 3
			B_Value = (B_Clr[1] + B_Clr[2] + B_Clr[3]) / 3
			C_Value = (C_Clr[1] + C_Clr[2] + C_Clr[3]) / 3
			D_Value = (D_Clr[1] + D_Clr[2] + D_Clr[3]) / 3

			' check for equal pixels around P and modify output pixels accordingly
			If B <> C And A <> D And (A = C Or A = B Or C = D Or B = D)
				' if A = C then check far left and top right pixel to see if it's necessary 
				' to modify P_2 as well
				If A = C
					P_1 = A
					' check pixel at far left and top right to see if stepping needs easing
					If x > 1 Then FL = ReadPixel(Pixmap,x-2,y)
					' if FL = C then read another pixel: TR
					If FL = C
						If x < Pix_W - 1 And y > 0 Then TR = ReadPixel(Pixmap,x+1,y-1)
						' If both = A && C then set P_2 to be A as well.
						If FL = C And TR = A Then P_2 = A
					EndIf

					' If FL is C and TR is A then we already know what to smooth here so
					' we can skip checking for vertical stepping and save CPU load. But if not
					' then do another check for P_3 to see if the bottom left and far top 
					' pixels are the same.
					If FL <> C Or TR <> A
						' check pixel at far top and bottom left to see if stepping needs easing
						If x > 0 And y < Pix_H - 1 Then BL = ReadPixel(Pixmap,x-1,y+1)
						If BL = C
							If y > 1 Then FT = ReadPixel(Pixmap,x,y-2)
							' If both = A && C then set P_3 to be C as well
							If BL = C And FT = A Then P_3 = C
						EndIf
					EndIf

				' if A = B then check far right and top left pixel to see if it's necessary 
				' to modify P_1 as well
				ElseIf A = B
					P_2 = B
					If x < Pix_W - 2 Then FR = ReadPixel(Pixmap,x+2,y)
					If FR = B
						If x > 0 And y > 0 Then TL = ReadPixel(Pixmap,x-1,y-1)
						If FR = B And TL = A Then P_1 = B
					EndIf

					If FR <> B Or TL <> A
						If x < Pix_W - 1 And y < Pix_H - 1 Then BR = ReadPixel(Pixmap,x+1,y+1)
						If BR = B
							If y > 1 Then FT = ReadPixel(Pixmap,x,y-2)
							If BR = B And FT = A Then P_4 = B
						EndIf
					EndIf

				' if C = D then check far left and bottom right pixel to see if it's necessary 
				' to modify P_4 as well
				ElseIf C = D
					P_3 = C
					If x > 1 Then FL = ReadPixel(Pixmap,x-2,y)
					If FL = C
						If x > 0 And y < Pix_H - 1 Then BR = ReadPixel(Pixmap,x+1,y+1)
						If FL = C And BR = D Then P_4 = C
					EndIf

					If FL <> C Or BR <> D
						If x > 0 And y > 0 Then TL = ReadPixel(Pixmap,x-1,y-1)
						If TL = C
							If y < Pix_H - 2 Then FB = ReadPixel(Pixmap,x,y+2)
							If TL = C And FB = D Then P_1 = C
						EndIf
					EndIf

				' if B = D then check far right and bottom left pixel to see if it's necessary 
				' to modify P_3 as well
				ElseIf B = D
					P_4 = D
					If x < Pix_W - 2 Then FR = ReadPixel(Pixmap,x+2,y)
					If FR = B
						If x > 0 And y < Pix_H - 1 Then BL = ReadPixel(Pixmap,x-1,y+1)
						If FR = B And BL = D Then P_3 = D
					EndIf

					If FR <> B Or BL <> D
						If x < Pix_W - 1 And y > 0 Then TR = ReadPixel(Pixmap,x+1,y-1)
						If TR = B
							If y < Pix_H - 2 Then FB = ReadPixel(Pixmap,x,y+2)
							If TR = B And FB = D Then P_2 = B
						EndIf
					EndIf
				EndIf
			EndIf


			' if equal pixel conditions aren't met then check for similar pixels instead:
			' TODO: match pixels by color similarity instead of just RGB average.
			If P_1 = P
				' if A is similar to C and very different from P then turn P_1 into C
				If A_Value < C_Value + 40 And A_Value > C_Value - 40 And (P_Value >= A_Value + 40 Or P_Value <= A_Value - 40) And B <> D And A <> B
					If A <> D And B <> C Then P_1 = C
				EndIf
			EndIf
			If P_2 = P
				' if B is similar to A and very different from P then turn P_2 into A
				If A_Value < B_Value + 40 And A_Value > B_Value - 40 And (P_Value >= B_Value + 40 Or P_Value <= B_Value - 40) And A <> C And B <> D
					If B <> C And A <> D Then P_2 = A
				EndIf
			EndIf
			If P_3 = P
				' if C is similar to D and very different from P then turn P_3 into D
				If D_Value < C_Value + 40 And D_Value > C_Value - 40 And (P_Value >= C_Value + 40 Or P_Value <= C_Value - 40) And B <> D And C <> A
					If A <> D And B <> C Then P_3 = D
				EndIf
			EndIf
			If P_4 = P
				' if D is similar to B and very different from P then turn P_4 into B
				If B_Value < D_Value + 40 And B_Value > D_Value - 40 And (P_Value >= D_Value + 40 Or P_Value <= D_Value - 40) And B <> A And D <> C
					If B <> C And A <> D Then P_4 = B
				EndIf
			EndIf

			WritePixel(ScaledPixmap,x*2,y*2,P_1)
			WritePixel(ScaledPixmap,(x*2)+1,y*2,P_2)
			WritePixel(ScaledPixmap,x*2,(y*2)+1,P_3)
			WritePixel(ScaledPixmap,(x*2)+1,(y*2)+1,P_4)
		Next
	Next

	OutputPixmap = CopyPixmap(ScaledPixmap)

End Function



Global InputPixmap:TPixmap = LoadPixmap("C:\input_ff.bmp")
Global OutputPixmap:TPixmap

Global TestImg:TImage



Graphics 800,600,32


ScaleEX(InputPixmap)
TestImg = LoadImage(OutputPixmap)


While Not KeyDown(KEY_ESCAPE)

	Cls
		DrawImage(TestImg,0,0)
	Flip

Wend

End

The code is free to use for whatever you please. It's too slow to scale the entire screen in real-time, but definitely fast enough to pre-process images on loading a level for instance. I've also included a port of the standard Scale2X filter so you can compare them for speed and quality.

Last edited 2010

Last edited 2010

Robert Cummings

(Posted 2010) [#2]

Looks really nice

RifRaf

(Posted 2010) [#3]

Indeed.. now make it work realtime!

Robert Cummings

(Posted 2010) [#4]

Don't think realtime is possible without the engine being 2D with serious SSE style optimisations for mid range machines. However, if one was to use shaders to achieve this it would be :)

Last edited 2010

Panno

(Posted 2010) [#5]

cool looks much better imho

ErikT

(Posted 2010) [#6]

Glad you all like :)

@RifRaf: Well the Scale2X filter is pretty much as fast as they get and even that one's too slow for realtime scaling in Blitzmax. So that leaves doing it with a pixel shader I guess.

Thing is I don't have a very good understanding of how shaders actually work. I know that a shader is a small program you apply to 3D surfaces and then it does nice things to them and stuff, but that's pretty much where my understanding ends. Can I read and write to pixels easily within a pixel shader? How do I get it to output a processed image for access inside bmax code? How does Blitzmax interact with shaders in the first place? Etc, etc.. I tried to read up on this but now my head hurts :P

EDIT:
Ok, been reading a lot and it's starting to seep in finally. I'm gonna give it a try and see what turns out.

Last edited 2010

Jesse

(Posted 2010) [#7]

a bit faster. Input any valid format but it processes rgba images only:

SuperStrict
' My super-duper ScaleEX :] Inspired by Xenowhirl's RotSprite tool and Screaming Duck's
' expanded Scale2X algorithm. 

Function ScaleEX(PM:TPixmap)
	Local PMPixels: Int Ptr = Int Ptr(pm.pixels)
	Local Pix_W:Int = PixmapWidth(PM)
	Local Pix_H:Int = PixmapHeight(PM)
	Local x:Int
	Local y:Int
	Local yt:Int
	Local yb:Int
	Local xl:Int
	Local xr:Int
	Local yt2:Int
	Local yb2:Int
	Local xl2:Int
	Local xr2:Int
	
	Local ScaledPM:TPixmap = CreatePixmap(Pix_W*2,Pix_H*2,PF_RGBA8888)
	Local x2PMPixels:Int Ptr = Int Ptr (ScaledPM.pixels)
	
	Local x2Pix_W:Int = PixmapWidth(ScaledPM)
	Local x2Pix_H:Int = PixmapHeight(ScaledPM)
	
	Local P:Int
	Local A:Int
	Local B:Int
	Local C:Int
	Local D:Int
	Local FL:Int	' far left pixel (beside C)
	Local TR:Int	' top right pixel
	Local FR:Int	' far right pixel (beside B)
	Local TL:Int	' top left pixel
	Local FT:Int	' far top pixel
	Local FB:Int	' far bottom pixel
	Local BL:Int	' bottom left pixel
	Local BR:Int	' bottom right pixel
	
	Local P_1:Int	' output pixel top-left
	Local P_2:Int	' output pixel top-right
	Local P_3:Int	' output pixel bottom-left
	Local P_4:Int	' output pixel bottom-right

	' RotSprite vars
	Local P_Clr:Int[4]	' 1 = R, 2 = G, 3 = B
	Local A_Clr:Int[4]	' 1 = R, 2 = G, 3 = B
	Local B_Clr:Int[4]	' 1 = R, 2 = G, 3 = B
	Local C_Clr:Int[4]	' 1 = R, 2 = G, 3 = B
	Local D_Clr:Int[4]	' 1 = R, 2 = G, 3 = B
	Local P_Value:Int		' holds average of RGB values
	Local A_Value:Int
	Local B_Value:Int
	Local C_Value:Int
	Local D_Value:Int
	
	' go through all pixels in the image
	For x = 0 To Pix_W - 1
		For y = 0 To Pix_H - 1
			yt = (y-1)*Pix_W
			yb = (y+1)*Pix_W
			yt2 = (y-2)*Pix_W
			yb2 = (y+2)*Pix_W
			xl2 = (x-2)
			xr2 = (x+2)
			xl = x-1
			xr = x+1
			Local yc:Int = y*pix_W
			' read the source pixel and its surrounding pixels
			P = PMPixels[yc+x]
			If x > 0 And x < Pix_W - 1 And y > 0 And y < Pix_H - 1
				A = PMPixels[yt+x]
				B = PMPixels[yc+xr]
				C = PMPixels[yc+xl]
				D = PMPixels[yb+x]
			Else
				A = P
				B = P
				C = P
				D = P
			EndIf

			P_1 = P
			P_2 = P
			P_3 = P
			P_4 = P

			' get colors
			P_Clr[1] = (P & $FF0000) Shr 16	' red
			P_Clr[2] = (P & $FF00) Shr 8		' green
			P_Clr[3] = (P & $FF)			' blue
			A_Clr[1] = (A & $FF0000) Shr 16	' red
			A_Clr[2] = (A & $FF00) Shr 8		' green
			A_Clr[3] = (A & $FF)			' blue
			B_Clr[1] = (B & $FF0000) Shr 16	' red
			B_Clr[2] = (B & $FF00) Shr 8		' green
			B_Clr[3] = (B & $FF)			' blue
			C_Clr[1] = (C & $FF0000) Shr 16	' red
			C_Clr[2] = (C & $FF00) Shr 8		' green
			C_Clr[3] = (C & $FF)			' blue
			D_Clr[1] = (D & $FF0000) Shr 16	' red
			D_Clr[2] = (D & $FF00) Shr 8		' green
			D_Clr[3] = (D & $FF)			' blue

			' set average value from RGB
			P_Value = (P_Clr[1] + P_Clr[2] + P_Clr[3]) / 3
			A_Value = (A_Clr[1] + A_Clr[2] + A_Clr[3]) / 3
			B_Value = (B_Clr[1] + B_Clr[2] + B_Clr[3]) / 3
			C_Value = (C_Clr[1] + C_Clr[2] + C_Clr[3]) / 3
			D_Value = (D_Clr[1] + D_Clr[2] + D_Clr[3]) / 3

			' check for equal pixels around P and modify output pixels accordingly
			If B <> C And A <> D And (A = C Or A = B Or C = D Or B = D)
				' if A = C then check far left and top right pixel to see if it's necessary 
				' to modify P_2 as well
				If A = C
					P_1 = A
					' check pixel at far left and top right to see if stepping needs easing
					If x > 1 Then FL = PMPixels[yc+xl2]
					' if FL = C then read another pixel: TR
					If FL = C
						If x < Pix_W - 1 And y > 0 Then TR = PMPixels[yt+xr]
						' If both = A && C then set P_2 to be A as well.
						If FL = C And TR = A Then P_2 = A
					EndIf

					' If FL is C and TR is A then we already know what to smooth here so
					' we can skip checking for vertical stepping and save CPU load. But if not
					' then do another check for P_3 to see if the bottom left and far top 
					' pixels are the same.
					If FL <> C Or TR <> A
						' check pixel at far top and bottom left to see if stepping needs easing
						If x > 0 And y < Pix_H - 1 Then BL = PMPixels[yb+xl]
						If BL = C
							If y > 1 Then FT = PMPixels[yt2+x]
							' If both = A && C then set P_3 to be C as well
							If BL = C And FT = A Then P_3 = C
						EndIf
					EndIf

				' if A = B then check far right and top left pixel to see if it's necessary 
				' to modify P_1 as well
				ElseIf A = B
					P_2 = B
					If x < Pix_W - 2 Then FR = PMPixels[yc+xr2]
					If FR = B
						If x > 0 And y > 0 Then TL = PMPixels[yt+xl]
						If FR = B And TL = A Then P_1 = B
					EndIf

					If FR <> B Or TL <> A
						If x < Pix_W - 1 And y < Pix_H - 1 Then BR = PMPixels[yb+xr]
						If BR = B
							If y > 1 Then FT = PMPixels[yt2+x]
							If BR = B And FT = A Then P_4 = B
						EndIf
					EndIf

				' if C = D then check far left and bottom right pixel to see if it's necessary 
				' to modify P_4 as well
				ElseIf C = D
					P_3 = C
					If x > 1 Then FL = PMPixels[yc+xl2]
					If FL = C
						If x > 0 And y < Pix_H - 1 Then BR = PMPixels[yb+xr]
						If FL = C And BR = D Then P_4 = C
					EndIf

					If FL <> C Or BR <> D
						If x > 0 And y > 0 Then TL = PMPixels[yt+xl]
						If TL = C
							If y < Pix_H - 2 Then FB = PMPixels[yb2+x]
							If TL = C And FB = D Then P_1 = C
						EndIf
					EndIf

				' if B = D then check far right and bottom left pixel to see if it's necessary 
				' to modify P_3 as well
				ElseIf B = D
					P_4 = D
					If x < Pix_W - 2 Then FR = PMPixels[yc+xr2]
					If FR = B
						If x > 0 And y < Pix_H - 1 Then BL = PMPixels[yb+xl]
						If FR = B And BL = D Then P_3 = D
					EndIf

					If FR <> B Or BL <> D
						If x < Pix_W - 1 And y > 0 Then TR = PMPixels[yt+xr]
						If TR = B
							If y < Pix_H - 2 Then FB = PMPixels[yb2+x]
							If TR = B And FB = D Then P_2 = B
						EndIf
					EndIf
				EndIf
			EndIf


			' if equal pixel conditions aren't met then check for similar pixels instead:
			' TODO: match pixels by color similarity instead of just RGB average.
			If P_1 = P
				' if A is similar to C and very different from P then turn P_1 into C
				If A_Value < C_Value + 40 And A_Value > C_Value - 40 And (P_Value >= A_Value + 40 Or P_Value <= A_Value - 40) And B <> D And A <> B
					If A <> D And B <> C Then P_1 = C
				EndIf
			EndIf
			If P_2 = P
				' if B is similar to A and very different from P then turn P_2 into A
				If A_Value < B_Value + 40 And A_Value > B_Value - 40 And (P_Value >= B_Value + 40 Or P_Value <= B_Value - 40) And A <> C And B <> D
					If B <> C And A <> D Then P_2 = A
				EndIf
			EndIf
			If P_3 = P
				' if C is similar to D and very different from P then turn P_3 into D
				If D_Value < C_Value + 40 And D_Value > C_Value - 40 And (P_Value >= C_Value + 40 Or P_Value <= C_Value - 40) And B <> D And C <> A
					If A <> D And B <> C Then P_3 = D
				EndIf
			EndIf
			If P_4 = P
				' if D is similar to B and very different from P then turn P_4 into B
				If B_Value < D_Value + 40 And B_Value > D_Value - 40 And (P_Value >= D_Value + 40 Or P_Value <= D_Value - 40) And B <> A And D <> C
					If B <> C And A <> D Then P_4 = B
				EndIf
			EndIf

			x2PMPixels[(y*2  )*ScaledPM.Width+(x*2  )] = P_1
			x2PMPixels[(y*2  )*ScaledPM.width+(x*2+1)] = P_2
			x2PMPixels[(y*2+1)*ScaledPM.width+(x*2  )] = P_3
			x2PMPixels[(y*2+1)*ScaledPM.Width+(x*2+1)] = P_4
		Next
	Next

	OutputPixmap = ScaledPM

End Function



Global InputPixmap:TPixmap = LoadPixmap("ff.png")
inputpixmap = inputPixmap.convert(PF_RGBA8888)
Global OutputPixmap:TPixmap

Global TestImg:TImage



Graphics 800,600,32

Local secs:Int= MilliSecs()
ScaleEX(InputPixmap)
Print MilliSecs() - secs
TestImg = LoadImage(OutputPixmap)


While Not KeyDown(KEY_ESCAPE)

	Cls
		DrawImage(TestImg,0,0)
	Flip

Wend

End

Last edited 2010

ErikT

(Posted 2010) [#8]

Oh crap, that's brilliant! How? I thought Read/Writepixel was the only way to get to pixels.

On my netbook, I get 87 millisecs now as opposed to 192 with the old code. Thx for sharing 8)

Last edited 2010

Jesse

(Posted 2010) [#9]

take sometime and go through the modules source that interest you the most. you'll find a gold mind of information that I am sure you'll find useful for other projects as well.

Last edited 2010

GfK	(Posted 2010) [#10]

cor, Moonstone!

MGE	(Posted 2010) [#11]

For real time use, if you're just using x2 scaling, you can turn smoothing off and it looks great.

Leto	(Posted 2010) [#12]

Sorry to be off-topic, but what is that second game? (with the angel)

ErikT

(Posted 2010) [#13]

1. Final Fight
2. Castlevania: Order of Ecclesia
3. Moonstone

Chugs40

(Posted 2010) [#14]

This looks really cool - right up my alley.

Sorry to be off-topic, but what is that second game? (with the angel)

Definately Castlevania: Order of Ecclesia

ErikT

(Posted 2010) [#15]

Uploaded a fixed version to the code archives along with high quality versions:
http://blitzbasic.com/codearcs/codearcs.php?code=2791