Mandelbrot Viewer (simple)

Community Forums/Showcase/Mandelbrot Viewer (simple)

Matty

(Posted 2010) [#1]

Good Morning, seeing the other thread in the general discussion on Mandelbrot stuff I thought I'd post a simple program that views the Mandelbrot Set and zooms in (higher zoomfactor = more gradual zoom, should be between 0 and 1 - but greater than 1). Press Escape at any time to exit. I've left some code commented out which captures each frame as a bitmap, in case you want to put together a movie later..

The code was written in blitzplus but should also work in blitz3d. Not sure if it will work on blitzmax, may need to change the writepixelfast and lockbuffer.

Now, if blitz3d/plus had double precision floats we could zoom in further, however I wonder if there is a way to increase the floating point precision in some other means...

Graphics 512,512,0,2
SetBuffer BackBuffer()

Const zoomfactor#=0.5

Global cx#,cy#,scale#,limit,lp,a1#,b1#,a2#,b2#,x,y,ax#,ay#

cx=0
cy=0
scale=0.02;
limit=4;
Repeat
	LockBuffer
	For x=-256 To 255 
	    For y=-256 To 255 
      	  ax=cx+x*scale
			ay=cy+y*scale;
	        a1=ax
			b1=ay
			lp=0
			Repeat
				If KeyDown(1) Then End 
				lp=lp+1;
				a2=a1*a1-b1*b1+ax;
				b2=2*a1*b1+ay;
				a1=a2
				b1=b2;
			Until (lp>767) Or ((a1*a1)+(b1*b1)>limit)
   			If lp>767 Then lp=0
			If lp<256 Then col=lp
			If lp>255 And lp<512 Then col=(255 Or ((lp-256) Shl 8))
			If lp>511 Then col = (255 Or (255 Shl 8) Or ((lp-512) Shl 16))
			WritePixelFast(x+256,y+256,col)
      		If lp > 100 And lp < 600
				newcx#=cx+scale*Float(x)
				newcy#=cy+scale*Float(y)
			EndIf
		Next
	Next
	cx=newcx
	cy=newcy
	If cx<>0 Or cy<>0 Then scale=scale*zoomfactor#
	UnlockBuffer
	If scale < 0.00000001 Then End 
	;frame=frame+1	
	;SaveBuffer BackBuffer(),"mandelbrot_"+Str(frame)+"0.bmp"
	;Text 0,0,scale
	;Text 0,20,"cx:"+cx+" cy:"+cy
	Flip
	If MouseHit(1)<>0 Then 
		cx=cx+scale*Float(MouseX()-256)
		cy=cy+scale*Float(MouseY()-256)
		scale=scale/2
	EndIf 
Until KeyDown(1)
WaitKey
End

Matty

(Posted 2010) [#2]

Edit - For some reason I cannot copy the code from the listing above into blitzplus without all sorts of garbage appearing in the code listing????

Edit - Ahh - copy to notepad first.

Last edited 2010

Oiduts Studios

(Posted 2010) [#3]

It's amazing that a formula that small can create a structure so complex.

Ross C

(Posted 2010) [#4]

Nice one man, i love this stuff.

Check out this guy:

http://www.hpdz.net/TechInfo.htm

Very low level stuff with the CPU, joining 32 bit numbers together to get, well practically unlimited resolution, depending on how long you'll live i suppose :)

Krischan

(Posted 2010) [#5]

Here is a nice variation of the mandelbrot set, the "Mandelbrot Lake" with an infinite river. Digged out of a very old computer magazin from the 80s :-D

AppTitle "Mandelbrot Lake"

Const ColorSteps%=2^16
Const Inverse%=True

Global SpectrumR%[ColorSteps],SpectrumG%[ColorSteps],SpectrumB%[ColorSteps]
Dim GradientPercent#(0),GradientRed%(0),GradientGreen%(0),GradientBlue%(0)

Local xx#=4.0
Local yy#=2.0
Local x#,y#
Local h%,height%
Local fx%,fy%
Local rgb%

Restore Earth : CreateGradient(7,ColorSteps,Inverse,SpectrumR,SpectrumG,SpectrumB)

Graphics xx*200,yy*200,32,2

LockBuffer FrontBuffer()

For x=-xx To xx Step .01
	
	For y=-yy To yy Step .01
		
		h%=Normalize(GetHeightAt(x+1.5,y),-0.04999,2.0,0,ColorSteps-1)
		
		If h>ColorSteps-1 Then height=ColorSteps-1
		If h<0 Then height=0
		
		fx=Int((x+xx)*100)
		fy=Int((y+yy)*100)
		
		rgb=SpectrumR[h]*$10000+SpectrumG[h]*$100+SpectrumB[h]
		
		If fx<xx*200 And fy<yy*200 Then WritePixelFast fx,fy,rgb,FrontBuffer()
		
	Next
	
Next

UnlockBuffer FrontBuffer()

WaitKey

End

Function GetHeightAt#(x1#,y1#)
	
	Local z#=2.0
	Local xa#=0.0
	Local ya#=0.0
	Local xc#=x1
	Local yc#=y1
	Local x2#,y2#,xn#
	
	Repeat
		
		x2=Abs(xa)
		y2=Abs(ya)
		
		xn=x2-y2-xc
		
		ya=xa*ya
		ya=ya+ya-yc
		
		xa=xn
		
		z=z-0.05
		
		If z<=0 Or (x2+y2>=1000) Then Return z
		
	Forever
	
End Function

Function Normalize#(value#=128.0,value_min#=0.0,value_max#=255.0,norm_min#=0.0,norm_max#=1.0)
	
	Return ((value-value_min)/(value_max-value_min))*(norm_max-norm_min)+norm_min
	
End Function

Function CreateGradient(colors%,steps%,inverse=False,R%[ColorSteps],G%[ColorSteps],B%[ColorSteps])
    
    Dim GradientPercent(colors)
    Dim GradientRed(colors),GradientGreen(colors),GradientBlue(colors)
    
    Local i%,pos1%,pos2%,pdiff%
    Local rdiff%,gdiff%,bdiff%
    Local rstep#,gstep#,bstep#
    Local counter%=0
    
    If inverse Then
        For i=colors To 1 Step -1
            Read GradientPercent(i),GradientRed(i),GradientGreen(i),GradientBlue(i)
            GradientPercent(i)=100.0-GradientPercent(i)
        Next
    Else
        For i=0 To colors-1
            Read GradientPercent(i),GradientRed(i),GradientGreen(i),GradientBlue(i)
        Next
    EndIf
    
    While counter<colors
        
        pos1=GradientPercent(counter)*steps*1.0/100
        pos2=GradientPercent(counter+1)*steps*1.0/100
        
        pdiff=pos2-pos1
        rdiff%=GradientRed(counter)-GradientRed(counter+1)
        gdiff%=GradientGreen(counter)-GradientGreen(counter+1)
        bdiff%=GradientBlue(counter)-GradientBlue(counter+1)
        rstep#=rdiff*1.0/pdiff
        gstep#=gdiff*1.0/pdiff
        bstep#=bdiff*1.0/pdiff
        
        For i=0 To pdiff
            
            R[pos1+i]=Int(GradientRed(counter)-(rstep*i))
            G[pos1+i]=Int(GradientGreen(counter)-(gstep*i))
            B[pos1+i]=Int(GradientBlue(counter)-(bstep*i))
            
        Next
        
        counter=counter+1
        
    Wend
    
End Function

.Earth
Data   0,153,143, 92
Data  15,115,128, 77
Data  45, 42,102, 41
Data  50, 69,108,118
Data  55, 17, 82,112
Data  75,  9, 62, 92
Data 100,  2, 43, 68