start wars TM scrolling * free source code *

SuperStrict
Const screenWidth%  = 800, screenHeight% = 600

Graphics screenWidth, screenHeight, 0

Type TText
	Field x#, y#, scale#
	Field text$
	Global list:TList
	
	Function Create:TText(x#,y#,scale#,text$)
		Local t:TText = New TText
		If list = Null list = CreateList()	
		list.addlast t
		t.x = x
		t.y = y
		t.scale = scale
		t.text = text
		Return t
	End Function

	Function drawAll()
		If Not list Return
		For Local t:TText = EachIn list
			t.draw()
		Next
	End Function
	
	Method draw()
		drawTextCentred(x, y, scale, text)
	End Method
	
	Function updateAll()
		If Not list Return
		For Local t:TText = EachIn list
			t.update()
		Next
	End Function
	
	Method update()
		y:-0.5
		If y < screenheight scale:-0.002
	End Method	
	
End Type

TText.Create(screenWidth/2, screenHeight, 4, "StarWarsTM")
For Local i% = 1 To 10
	TText.Create(screenWidth/2, screenHeight + i * 45, 4, "Far Far")
Next
TText.Create(screenWidth/2, screenHeight + 11 * 45, 4, "Away")

While Not AppTerminate()
	TText.updateAll()
	Cls
	TText.drawAll()
	Flip
	Delay 1
Wend

Function drawTextCentred(x#, y#, scale#, text$)
	Local w# = TextWidth(text)
	If scale<>1 Then
		w=w*scale
	EndIf
	x# = x - ( w / 2 )
	If scale<>1 Then
		Local h#=TextHeight(text)
		Local diff# = (h*scale)-h
		y:-diff/2.0
	EndIf
	SetScale scale, scale
	DrawText text, x, y
	SetScale 1, 1
End Function