GL line fun...

Community Forums/Showcase/GL line fun...

Taron

(Posted 2010) [#1]

Ah screw it, I wasn't sure, if I should post this, but it's too much fun and kinda pretty. It's a GL line/particle test I just wrote after seeing _Skully's beautiful goodnight treat for the kids.

If you compile this with BLide's publishing compression it comes to 93kb.

Instructions are in the AppTitle...

SuperStrict
Framework brl.GLMax2D
AppTitle="Draw with Mouse    (KEY_V)vertical blank on/off     (KEY_SPACE) clear    (KEY_UP/DOWN)line length"
Graphics 800,600,0
Global spinnerlist:TList = CreateList()
Type spinner
	Field x:Float
	Field y:Float
	Field rx:Float
	Field ry:Float
	Field rot:Float
	Field col:Float[]
	
	Method move(t:Float)
		Local counter:Double =t+rot
		rx = Float(Cos(counter))
		ry = Sin(counter*2)
		x:-rx*Sin(rot)
		y:-ry*Sin(rot)
		col = [0.025+0.025*rx,0.025+0.025*ry,0.125+0.125*Float(Sin(counter-2*rot)),1.0]
		rx:*20.0
		ry:*20.0
	End Method
	
	Method draw(offset:Float)
		glColor4f(col[0],col[1],col[2],col[3])
		glVertex2f(x-rx, y-ry)
		glVertex2f(x+rx*offset, y+ry*offset)
	End Method
	
	Function Create:spinner(x:Float,y:Float, rot:Float)
		Local s:spinner = New spinner
		s.x = x
		s.y = y
		s.rot = rot
		s.col = [1.0,1.0,1.0,1.0]
		ListAddLast spinnerlist,s
		Return s
	End Function
End Type

glEnable(GL_ALPHA_TEST)
glAlphaFunc(GL_NOTEQUAL,0)           
glEnable (GL_BLEND);

Local offset:Float = 1.0
Local vb:Byte = 1

Local count_ms:Float = 1000
Local fc:Int = 0
Local fps:Int
Local store_ms:Float
Local t:Float = 0
While Not KeyHit(KEY_ESCAPE)
	count_ms :+(MilliSecs()-store_ms)
	fc:+1
	If count_ms >=1000
		fps = fc
		fc = 0
		count_ms = 0
	End If
	store_ms = MilliSecs()
	glBlendFunc (GL_SRC_ALPHA,GL_ONE_MINUS_SRC_ALPHA) 		
	glBegin GL_QUADS
		glColor4f(0.0,0.0,0.0,0.1)
		glVertex2f(0.0,0.0);glVertex2f(0.0,600.0);glVertex2f(800.0,600.0);glVertex2f(800.0,0.0)
		glColor4f(0.0,0.0,0.0,1.0)
		glVertex2f(0.0,5.0);glVertex2f(0.0,30.0);glVertex2f(250.0,30.0);glVertex2f(250.0,5.0)
	glEnd
	glColor4f(1.0,1.0,1.0,1.0)
	GLDrawText "spinners:"+ spinnerlist.Count()+"  fps:"+fps+ " vb:"+vb,10,10

	t:+1.5
	If MouseDown(1) Then spinner.Create(MouseX(),MouseY(),t*2)
	For Local s:spinner = EachIn spinnerlist
		s.move(t)
	Next
	glBlendFunc (GL_SRC_ALPHA,GL_ONE) 		
	glBegin(GL_LINES)
		For Local s:spinner = EachIn spinnerlist
			s.draw(offset)
		Next
	glEnd
	If KeyDown(KEY_UP) Then offset:+0.1
	If KeyDown(KEY_DOWN) Then offset:-0.1
	If KeyHit(KEY_V) Then vb:~1
	If KeyHit(KEY_SPACE) Then spinnerlist.Clear()
	Flip vb
WEnd

MGE	(Posted 2010) [#2]

Gorgeous. wow..

DavidDC

(Posted 2010) [#3]

Of course you should have posted it! It's great!

Taron

(Posted 2010) [#4]

THANKS! It's somehow fascinating and reminds me of how much my father would've loved to see all this. Ah well...

I still have to test how fast it would run with normal max2d commands.

Thanks again!

Small update...(not the cleverest, but kinda fun. Switch between lines and quads as well as left/right for offset multiplications)

SuperStrict
Framework brl.GLMax2D
AppTitle="(V)vertical blank on/off   (SPACE) clear   (UP/DOWN)line length   (LEFT/RIGHT)offset multiplier   (M)mode lines/quads"
Graphics 800,600,0
Global spinnerlist:TList = CreateList()
Type spinner
	Field x:Float
	Field y:Float
	Field rx:Float
	Field ry:Float
	Field rot:Float
	Field mult:Float
	Field col:Float[]
	Field order:Byte
	
	Method move(t:Float, scl:Float, dim:Float)
		Local counter:Double =t+rot
		rx = Float(Cos(counter))
		ry = Sin(counter*2)
		x:-rx*Sin(rot)
		y:-ry*Sin(rot)
		Local dim2:Float = dim*3
		col = [dim+dim*rx,dim+dim*ry,dim2+dim2*Float(Sin(counter-2*rot)),1.0]
		rx:*mult*scl
		ry:*mult*scl
	End Method
	
	Method draw(offset:Float, mode:Byte)
		glColor4f(col[0],col[1],col[2],col[3])
		If mode
			If order Then glVertex2f(x-rx, y-ry)
			glVertex2f(x+rx*offset, y+ry*offset)
			If Self <> spinnerlist.First() 
				glVertex2f(x-rx, y-ry);glVertex2f(x+rx*offset, y+ry*offset)
			End If
			If Not order Then glVertex2f(x-rx, y-ry)
		Else
			glVertex2f(x-rx, y-ry);glVertex2f(x+rx*offset, y+ry*offset)
		End If
	End Method
	
	Function Create:spinner(x:Float,y:Float, rot:Float, mult:Float, order:Byte)
		Local s:spinner = New spinner
		s.x = x
		s.y = y
		s.rot = rot
		s.mult = mult
		s.col = [1.0,1.0,1.0,1.0]
		s.order = order
		ListAddLast spinnerlist,s
		Return s
	End Function
End Type

glEnable(GL_ALPHA_TEST)
glAlphaFunc(GL_NOTEQUAL,0)           
glEnable (GL_BLEND);

Local dim:Float = 0.025
Local scaler:Float = 1.0
Local offset:Float = 1.0
Local order:Byte = 0
Local glow:Byte =1
Local mode:Byte =0
Local vb:Byte = 1

Local count_ms:Float = 1000
Local fc:Int = 0
Local fps:Int
Local store_ms:Float
Local t:Float = 0
While Not KeyHit(KEY_ESCAPE)
	count_ms :+(MilliSecs()-store_ms)
	fc:+1
	If count_ms >=1000
		fps = fc
		fc = 0
		count_ms = 0
	End If
	store_ms = MilliSecs()
	glBlendFunc (GL_SRC_ALPHA,GL_ONE_MINUS_SRC_ALPHA) 		
	glBegin GL_QUADS
		glColor4f(0.0,0.0,0.0,0.15)
		glVertex2f(0.0,0.0);glVertex2f(0.0,600.0);glVertex2f(800.0,600.0);glVertex2f(800.0,0.0)
		glColor4f(0.0,0.0,0.0,1.0)
		glVertex2f(0.0,5.0);glVertex2f(0.0,30.0);glVertex2f(250.0,30.0);glVertex2f(250.0,5.0)
	glEnd
	glColor4f(1.0,1.0,1.0,1.0)
	GLDrawText "spinners:"+ spinnerlist.Count()+"  fps:"+fps+ " vb:"+vb,10,10

	t:+1.5
	If MouseDown(1) Then spinner.Create(MouseX(),MouseY(),t*2,15+Cos(t)*20, order); order:~1
	For Local s:spinner = EachIn spinnerlist
		s.move(t,scaler,dim)
	Next
	If glow Then glBlendFunc (GL_SRC_ALPHA,GL_ONE) 		
	If mode Then glBegin(GL_QUADS) Else glBegin(GL_LINES)
		For Local s:spinner = EachIn spinnerlist
			s.draw(offset, mode)
		Next
	glEnd
	If KeyDown(KEY_PAGEUP) Then dim:+0.001
	If KeyDown(KEY_PAGEDOWN) Then dim:-0.001
	If KeyDown(KEY_UP) Then offset:+0.1
	If KeyDown(KEY_DOWN) Then offset:-0.1
	If KeyDown(KEY_LEFT) Then scaler:-0.1
	If KeyDown(KEY_RIGHT) Then scaler:+0.1
	If KeyHit(KEY_A) Then glow:~1
	If KeyHit(KEY_M) Then mode:~1
	If KeyHit(KEY_V) Then vb:~1
	If KeyHit(KEY_SPACE) Then spinnerlist.Clear()
	Flip vb
WEnd

_Skully

(Posted 2010) [#5]

Very pretty...looks like a plasma fire when you get enough going :)

beanage

(Posted 2010) [#6]

Cant think of another person doing something as cool as simple as this, thanks, awesome as always!

Taron

(Posted 2010) [#7]

If I'd only finish something bigger, haha!
THANK YOU! :}

It's actually one heck of a sandbox, too. I've added a few more things and get even wilder results. Loads of fun...

Taron

(Posted 2010) [#8]

More pretty patterns... playing around with the alpha of the vertecies is quite a blast. Very fascinating patterns...

SuperStrict
Framework brl.GLMax2D
AppTitle="(V)vertical blank on/off   (SPACE) clear   (UP/DOWN)line length   (LEFT/RIGHT)offset multiplier   (M)mode lines/quads"
Graphics 800,600,0
Global spinnerlist:TList = CreateList()
Type spinner
	Field x:Float
	Field y:Float
	Field rx:Float
	Field ry:Float
	Field rot:Float
	Field mult:Float
	Field col:Float[]
	Field order:Byte
	Field trimult:Float[2]
	
	Method move(t:Float, scl:Float, dim:Float)
		Local counter:Double =t+rot
		rx = Cos(counter*trimult[0])
		ry = Sin(counter*trimult[1])
		x:-rx*Sin(rot)
		y:-ry*Sin(rot)
		Local temp:Float = dim'*(rx*0.5+ry*0.5)
		Local dim2:Float = temp*3
		col = [temp+temp*rx,temp+temp*ry,dim2+dim2*Float(Sin(counter-2*rot)),1.0]
		rx:*mult*scl
		ry:*mult*scl
	End Method
	
	Method draw(offset:Float, mode:Byte)
		glColor4f(col[0],col[1],col[2],col[3])
		If mode
			If order Then glVertex2f(x-rx, y-ry);glColor4f(col[0],col[1],col[2],0.1)
			
			glVertex2f(x+rx*offset, y+ry*offset);glColor4f(col[0],col[1],col[2],0.1)
			If Self <> spinnerlist.First() 
				glVertex2f(x-rx, y-ry);glVertex2f(x+rx*offset, y+ry*offset)
			End If
			If Not order Then glVertex2f(x-rx, y-ry)
		Else
			glVertex2f(x-rx, y-ry);
			glColor4f(col[0],col[1],col[2],0.1)
			glVertex2f(x+rx*offset, y+ry*offset)
		End If
	End Method
	
	Function Create:spinner(x:Float,y:Float, rot:Float, mult:Float, order:Byte, tmx:Float, tmy:Float)
		Local s:spinner = New spinner
		s.x = x
		s.y = y
		s.rot = rot
		s.mult = mult
		s.col = [1.0,1.0,1.0,1.0]
		s.order = order
		s.trimult = [tmx, tmy]
		ListAddLast spinnerlist,s
		Return s
	End Function
End Type

glEnable(GL_ALPHA_TEST)
glAlphaFunc(GL_NOTEQUAL,0)           
glEnable (GL_BLEND);

Local dim:Float = 0.025
Local scaler:Float = 2.0
Local offset:Float = 5.0
Local order:Byte = 0
Local glow:Byte =1
Local mode:Byte =1
Local vb:Byte = 1
Local show:Byte = 1

Local count_ms:Float = 1000
Local fc:Int = 0
Local fps:Int
Local store_ms:Float
Local t:Float = 0
While Not KeyHit(KEY_ESCAPE)
	count_ms :+(MilliSecs()-store_ms)
	fc:+1
	If count_ms >=1000
		fps = fc
		fc = 0
		count_ms = 0
	End If
	store_ms = MilliSecs()
	glBlendFunc (GL_SRC_ALPHA,GL_ONE_MINUS_SRC_ALPHA) 		
	glBegin GL_QUADS
	glColor4f(0.0,0.0,0.0,0.15)
	glVertex2f(0.0,0.0);glVertex2f(0.0,600.0);glVertex2f(800.0,600.0);glVertex2f(800.0,0.0)
	If show
		glColor4f(0.0,0.0,0.0,1.0)
		glVertex2f(0.0,5.0);glVertex2f(0.0,30.0);glVertex2f(250.0,30.0);glVertex2f(250.0,5.0)
		glColor4f(1.0,1.0,1.0,1.0)
		glEnd
		GLDrawText "spinners:"+ spinnerlist.Count()+"  fps:"+fps+ " vb:"+vb,10,10
	Else
	glEnd	
	End If

	t:+1.5/(1.0+2*(1.0-vb))
	If MouseDown(1) Then spinner.Create(MouseX(),MouseY(),t*2,15+Cos(t)*20, order,2,1); order:~1
	If MouseDown(2) Then spinner.Create(MouseX(),MouseY(),t*2,15+Cos(t)*20, order,1,2); order:~1
	For Local s:spinner = EachIn spinnerlist
		s.move(t,scaler,dim)
	Next
	If glow Then glBlendFunc (GL_SRC_ALPHA,GL_ONE) 		
	If mode Then glBegin(GL_QUADS) Else glBegin(GL_LINES)
		For Local s:spinner = EachIn spinnerlist
			s.draw(offset, mode)
		Next
	glEnd
	If KeyDown(KEY_PAGEUP) Then dim:+0.001
	If KeyDown(KEY_PAGEDOWN) Then dim:-0.001
	If KeyDown(KEY_UP) Then offset:+0.1
	If KeyDown(KEY_DOWN) Then offset:-0.1
	If KeyDown(KEY_LEFT) Then scaler:-0.1
	If KeyDown(KEY_RIGHT) Then scaler:+0.1
	If KeyHit(KEY_A) Then glow:~1
	If KeyHit(KEY_M) Then mode:~1
	If KeyHit(KEY_V) Then vb:~1
	If KeyHit(KEY_SPACE) Then spinnerlist.Clear()
	If KeyHit(KEY_TAB) Then show:~1
	Flip vb
WEnd

Nate the Great

(Posted 2010) [#9]

wow nice... I wish I was this good at cool effects and GL

_Skully

(Posted 2010) [#10]

Can we create polygons with this direct OpenGL technique? or a mesh even... I'd like to capture the backbuffer texture, map that onto a mesh and manipulate the vertices

ImaginaryHuman

(Posted 2010) [#11]

Neat :-)

DavidDC

(Posted 2010) [#12]

I'd like to capture the backbuffer texture, map that onto a mesh and manipulate the vertices

Yes me too - my one track mind wanted to see how it looked as a kaleidoscope. You know, render as a texture onto a circle of tri's with their texture coords flipped appropriately.

Taron

(Posted 2010) [#13]

but of course you can! Go right ahead! :}
If you do a framebuffer solution, PLEASE, post it here, too!

Look at the code and you'll see that it simply creates either QUADS or LINES, but it's straight up GL.

...Oh, AND THANKS! :}

Taron

(Posted 2010) [#14]

There you go...just took a primitive approach with a pixel buffer, but it does it, too, I think. I still want to learn about the FBO solution, but I appear to be too stupid so far. Considering that I know next to nothing about GL, my crawling forward leads to some results already...

(not very fast, but hey)
HIT "Z" to toogle through mirror modes...

SuperStrict
Framework brl.GLMax2D

AppTitle="(V)vertical blank on/off   (SPACE) clear   (UP/DOWN)line length   (LEFT/RIGHT)offset multiplier   (M)mode lines/quads"

Global w:Int = 800
Global h:Int = 600
Graphics w,h,0
Global spinnerlist:TList = CreateList()
Type spinner
	Field x:Float
	Field y:Float
	Field rx:Float
	Field ry:Float
	Field rot:Float
	Field mult:Float
	Field col:Float[]
	Field order:Byte
	Field trimult:Float[2]
	
	Method move(t:Float, scl:Float, dim:Float)
		Local counter:Double =t+rot
		rx = Cos(counter*trimult[0])
		ry = Sin(counter*trimult[1])
		x:-rx*Sin(rot)
		y:-ry*Sin(rot)
		Local temp:Float = dim'*(rx*0.5+ry*0.5)
		Local dim2:Float = temp*3
		col = [temp+temp*rx,temp+temp*ry,dim2+dim2*Float(Sin(counter-2*rot)),1.0]
		rx:*mult*scl
		ry:*mult*scl
	End Method
	
	Method draw(offset:Float, mode:Byte)
		glColor4f(col[0],col[1],col[2],col[3])
		If mode
			If order Then glVertex2f(x-rx, y-ry);glColor4f(col[0],col[1],col[2],0.1)
			
			glVertex2f(x+rx*offset, y+ry*offset);glColor4f(col[0],col[1],col[2],0.1)
			If Self <> spinnerlist.First() 
				glVertex2f(x-rx, y-ry);glVertex2f(x+rx*offset, y+ry*offset)
			End If
			If Not order Then glVertex2f(x-rx, y-ry)
		Else
			glVertex2f(x-rx, y-ry);
			glColor4f(col[0],col[1],col[2],0.1)
			glVertex2f(x+rx*offset, y+ry*offset)
		End If
	End Method
	
	Function Create:spinner(x:Float,y:Float, rot:Float, mult:Float, order:Byte, tmx:Float, tmy:Float)
		Local s:spinner = New spinner
		s.x = x
		s.y = y
		s.rot = rot
		s.mult = mult
		s.col = [1.0,1.0,1.0,1.0]
		s.order = order
		s.trimult = [tmx, tmy]
		ListAddLast spinnerlist,s
		Return s
	End Function
End Type

glEnable(GL_ALPHA_TEST)
glAlphaFunc(GL_NOTEQUAL,0)           
glEnable (GL_BLEND);

Local buffer_id:Int

glEnable (GL_TEXTURE_2D)
glGenTextures (1, Varptr buffer_id)

glBindTexture GL_TEXTURE_2D, buffer_id
glTexImage2D GL_TEXTURE_2D, 0, GL_RGB, w, h, 0, GL_RGB, GL_UNSIGNED_BYTE, New Int[3 * w * h]
glTexParameteri GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_LINEAR
glTexParameteri GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR
glTexParameteri GL_TEXTURE_2D, GL_TEXTURE_WRAP_S, GL_CLAMP
glTexParameteri GL_TEXTURE_2D, GL_TEXTURE_WRAP_T, GL_CLAMP

Local speed:Float = 1.5
Local dim:Float = 0.025
Local scaler:Float = 2.0
Local offset:Float = 5.0
Local order:Byte = 0
Local glow:Byte =1
Local mode:Byte =1
Local vb:Byte = 1
Local show:Byte = 0
Local fullscreen:Byte = 0

Local mirror:Byte = 0

Local count_ms:Float = 1000
Local fc:Int = 0
Local fps:Int
Local store_ms:Float
Local t:Float = 0
While Not KeyHit(KEY_ESCAPE)
	count_ms :+(MilliSecs()-store_ms)
	fc:+1
	If count_ms >=1000
		fps = fc
		fc = 0
		count_ms = 0
	End If
	store_ms = MilliSecs()
	
	glDisable (GL_TEXTURE_2D)
	glBlendFunc (GL_SRC_ALPHA,GL_ONE_MINUS_SRC_ALPHA) 		
	glBegin GL_QUADS
	glColor4f(0.0,0.0,0.0,0.85)
	glVertex2f(0.0,0.0);glVertex2f(0.0,h);glVertex2f(w,h);glVertex2f(w,0.0)
	glEnd	

	t:+speed/(1.0+2*(1.0-vb))
	If MouseDown(1) Then spinner.Create(MouseX(),MouseY(),t*2,15+Cos(t)*20, order,2,1); order:~1
	If MouseDown(2) Then spinner.Create(MouseX(),MouseY(),t*2,15+Cos(t)*20, order,1,2); order:~1
	For Local s:spinner = EachIn spinnerlist
		s.move(t,scaler,dim)
	Next
	If glow Then glBlendFunc (GL_SRC_ALPHA,GL_ONE) 		
	If mode Then glBegin(GL_QUADS) Else glBegin(GL_LINES)
		For Local s:spinner = EachIn spinnerlist
			s.draw(offset, mode)
		Next
	glEnd
	
	If mirror>0
		glFlush ()
		glEnable (GL_TEXTURE_2D)
		glBindTexture(GL_TEXTURE_2D, buffer_id )
		glEnable GL_TEXTURE_2D 
	
	    glCopyTexImage2D(GL_TEXTURE_2D, 0, GL_RGB, 0, 0, w-1, h-1, 0)
		glBlendFunc (GL_SRC_ALPHA,GL_ONE_MINUS_SRC_ALPHA) 		
		glBegin GL_QUADS
			glColor4f(1.0,1.0,1.0,1.0)
			glTexCoord2f 0,0
			glVertex2f 0,0
			glTexCoord2f 0,1
			glVertex2f 0,h
			glTexCoord2f 1,1
			glVertex2f w,h
			glTexCoord2f 1,0
			glVertex2f w,0
		glEnd
		glBlendFunc (GL_SRC_ALPHA,GL_ONE) 		
			
		glBegin GL_QUADS
			glTexCoord2f 0,0
			glVertex2f w,0
			glTexCoord2f 0,1
			glVertex2f w,h
			glTexCoord2f 1,1
			glVertex2f 0,h
			glTexCoord2f 1,0
			glVertex2f 0,0
			If mirror>1
				glTexCoord2f 0,1
				glVertex2f w,0
				glTexCoord2f 0,0
				glVertex2f w,h
				glTexCoord2f 1,0
				glVertex2f 0,h
				glTexCoord2f 1,1
				glVertex2f 0,0
				
				glTexCoord2f 1,1
				glVertex2f w,0
				glTexCoord2f 1,0
				glVertex2f w,h
				glTexCoord2f 0,0
				glVertex2f 0,h
				glTexCoord2f 0,1
				glVertex2f 0,0
			End If
		glEnd
	End If
	If show
		glBegin GL_QUADS
		glColor4f(0.0,0.0,0.0,1.0)
		glVertex2f(0.0,5.0);glVertex2f(0.0,30.0);glVertex2f(250.0,30.0);glVertex2f(250.0,5.0)
		glColor4f(1.0,1.0,1.0,1.0)
		glEnd
		GLDrawText "spinners:"+ spinnerlist.Count()+"  fps:"+fps+ " vb:"+vb,10,10
	EndIf
	
	If KeyDown(KEY_HOME) Then speed:+0.25
	If KeyDown(KEY_END) Then speed:-0.25
	If KeyDown(KEY_PAGEUP) Then dim:+0.001
	If KeyDown(KEY_PAGEDOWN) Then dim:-0.001
	If KeyDown(KEY_UP) Then offset:+0.1
	If KeyDown(KEY_DOWN) Then offset:-0.1
	If KeyDown(KEY_LEFT) Then scaler:-0.1
	If KeyDown(KEY_RIGHT) Then scaler:+0.1
	If KeyHit(KEY_A) Then glow:~1
	If KeyHit(KEY_M) Then mode:~1
	If KeyHit(KEY_V) Then vb:~1
	If KeyHit(KEY_SPACE) Then spinnerlist.Clear()
	If KeyHit(KEY_TAB) Then show:~1
	If KeyHit(KEY_Z) Then mirror:+1; If mirror>2 Then mirror= 0
	If KeyHit(KEY_F) 
		fullscreen:~1;Graphics w,h,(32*fullscreen);
		glEnable(GL_ALPHA_TEST);glAlphaFunc(GL_NOTEQUAL,0);glEnable (GL_BLEND);
		glEnable (GL_TEXTURE_2D)
		glBindTexture GL_TEXTURE_2D, buffer_id
		glTexImage2D GL_TEXTURE_2D, 0, GL_RGB, w, h, 0, GL_RGB, GL_UNSIGNED_BYTE, New Int[3 * w * h]
		glTexParameteri GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_LINEAR
		glTexParameteri GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR
		glTexParameteri GL_TEXTURE_2D, GL_TEXTURE_WRAP_S, GL_CLAMP
		glTexParameteri GL_TEXTURE_2D, GL_TEXTURE_WRAP_T, GL_CLAMP
	EndIf
	Flip vb
Wend

DavidDC

(Posted 2010) [#15]

Hey thanks Taron! Sorry I didn't reply earlier. Have been upgrading my PC.

I don't know much GL either but I had a quick play/hack (below). It looks a little dark compared to the "pretty patterns" version above. Not sure what's wrong...

Maybe this kind of effect doesn't suit kaleidoscopes too much (although I did stumble on a few quite nice drawings). Fluids and plasma are prob more suited - although your fireworks might look interesting :-)

SuperStrict
Framework brl.GLMax2D

AppTitle="(V)vertical blank on/off   (SPACE) clear   (UP/DOWN)line length   (LEFT/RIGHT)offset multiplier   (M)mode lines/quads"

Global w:Int = 800
Global h:Int = 600
Graphics w,h,0
Global spinnerlist:TList = CreateList()
Type spinner
	Field x:Float
	Field y:Float
	Field rx:Float
	Field ry:Float
	Field rot:Float
	Field mult:Float
	Field col:Float[]
	Field order:Byte
	Field trimult:Float[2]
	
	Method move(t:Float, scl:Float, dim:Float)
		Local counter:Double =t+rot
		rx = Cos(counter*trimult[0])
		ry = Sin(counter*trimult[1])
		x:-rx*Sin(rot)
		y:-ry*Sin(rot)
		Local temp:Float = dim'*(rx*0.5+ry*0.5)
		Local dim2:Float = temp*3
		col = [temp+temp*rx,temp+temp*ry,dim2+dim2*Float(Sin(counter-2*rot)),1.0]
		rx:*mult*scl
		ry:*mult*scl
	End Method
	
	Method draw(offset:Float, Mode:Byte)
		glColor4f(col[0],col[1],col[2],col[3])
		If Mode
			If order Then glVertex2f(x-rx, y-ry);glColor4f(col[0],col[1],col[2],0.1)
			
			glVertex2f(x+rx*offset, y+ry*offset);glColor4f(col[0],col[1],col[2],0.1)
			If Self <> spinnerlist.First() 
				glVertex2f(x-rx, y-ry);glVertex2f(x+rx*offset, y+ry*offset)
			End If
			If Not order Then glVertex2f(x-rx, y-ry)
		Else
			glVertex2f(x-rx, y-ry);
			glColor4f(col[0],col[1],col[2],0.1)
			glVertex2f(x+rx*offset, y+ry*offset)
		End If
	End Method
	
	Function Create:spinner(x:Float,y:Float, rot:Float, mult:Float, order:Byte, tmx:Float, tmy:Float)
		Local s:spinner = New spinner
		s.x = x
		s.y = y
		s.rot = rot
		s.mult = mult
		s.col = [1.0,1.0,1.0,1.0]
		s.order = order
		s.trimult = [tmx, tmy]
		ListAddLast spinnerlist,s
		Return s
	End Function
End Type

glEnable(GL_ALPHA_TEST)
glAlphaFunc(GL_NOTEQUAL,0)           
glEnable (GL_BLEND);

Local buffer_id:Int

glEnable (GL_TEXTURE_2D)
glGenTextures (1, Varptr buffer_id)

glBindTexture GL_TEXTURE_2D, buffer_id
glTexImage2D GL_TEXTURE_2D, 0, GL_RGB, w, h, 0, GL_RGB, GL_UNSIGNED_BYTE, New Int[3 * w * h]
glTexParameteri GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_LINEAR
glTexParameteri GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR
glTexParameteri GL_TEXTURE_2D, GL_TEXTURE_WRAP_S, GL_CLAMP
glTexParameteri GL_TEXTURE_2D, GL_TEXTURE_WRAP_T, GL_CLAMP

Local speed:Float = 1.5
Local dim:Float = 0.025
Local scaler:Float = 2.0
Local offset:Float = 5.0
Local order:Byte = 0
Local glow:Byte =1
Local Mode:Byte =1
Local vb:Byte = 1
Local show:Byte = 0
Local fullscreen:Byte = 0

Local mirror:Byte = 0

Local count_ms:Float = 1000
Local fc:Int = 0
Local fps:Int
Local store_ms:Float
Local t:Float = 0
While Not KeyHit(KEY_ESCAPE)
	count_ms :+(MilliSecs()-store_ms)
	fc:+1
	If count_ms >=1000
		fps = fc
		fc = 0
		count_ms = 0
	End If
	store_ms = MilliSecs()
	
	glDisable (GL_TEXTURE_2D)
	glBlendFunc (GL_SRC_ALPHA,GL_ONE_MINUS_SRC_ALPHA) 		
	glBegin GL_QUADS
	glColor4f(0.0,0.0,0.0,0.85)
	glVertex2f(0.0,0.0);glVertex2f(0.0,h);glVertex2f(w,h);glVertex2f(w,0.0)
	glEnd	

	t:+speed/(1.0+2*(1.0-vb))
	If MouseDown(1) Then spinner.Create(MouseX(),MouseY(),t*2,15+Cos(t)*20, order,2,1); order:~1
	If MouseDown(2) Then spinner.Create(MouseX(),MouseY(),t*2,15+Cos(t)*20, order,1,2); order:~1
	For Local s:spinner = EachIn spinnerlist
		s.move(t,scaler,dim)
	Next
	If glow Then glBlendFunc (GL_SRC_ALPHA,GL_ONE) 		
	If Mode Then glBegin(GL_QUADS) Else glBegin(GL_LINES)
		For Local s:spinner = EachIn spinnerlist
			s.draw(offset, Mode)
		Next
	glEnd
	
	If mirror>0
	
		glFlush ()
		glEnable (GL_TEXTURE_2D)
		glBindTexture(GL_TEXTURE_2D, buffer_id )
		glEnable GL_TEXTURE_2D 
	
	   	glCopyTexImage2D(GL_TEXTURE_2D, 0, GL_RGB, 0, 0, w-1, h-1, 0)
		'glBlendFunc (GL_SRC_ALPHA,GL_ONE) 	
		glColor4f(1.0,1.0,1.0,1.0)
		
		glClear(GL_COLOR_BUFFER_BIT)
		KaleidoscopeII(30, h/2, w/2,h/2,0)

	End If
	If show
		glBegin GL_QUADS
		glColor4f(0.0,0.0,0.0,1.0)
		glVertex2f(0.0,5.0);glVertex2f(0.0,30.0);glVertex2f(250.0,30.0);glVertex2f(250.0,5.0)
		glColor4f(1.0,1.0,1.0,1.0)
		glEnd
		GLDrawText "spinners:"+ spinnerlist.Count()+"  fps:"+fps+ " vb:"+vb+" mirror:" +mirror,10,10 
	EndIf
	
	If KeyDown(KEY_HOME) Then speed:+0.25
	If KeyDown(KEY_END) Then speed:-0.25
	If KeyDown(KEY_PAGEUP) Then dim:+0.001
	If KeyDown(KEY_PAGEDOWN) Then dim:-0.001
	If KeyDown(KEY_UP) Then offset:+0.1
	If KeyDown(KEY_DOWN) Then offset:-0.1
	If KeyDown(KEY_LEFT) Then scaler:-0.1
	If KeyDown(KEY_RIGHT) Then scaler:+0.1
	If KeyHit(KEY_A) Then glow:~1
	If KeyHit(KEY_M) Then Mode:~1
	If KeyHit(KEY_V) Then vb:~1
	If KeyHit(KEY_SPACE) Then spinnerlist.Clear()
	If KeyHit(KEY_TAB) Then show:~1
	If KeyHit(KEY_Z) Then mirror:+1; If mirror>2 Then mirror= 0
	If KeyHit(KEY_F) 
		'w = 1920
		'h = 1080
		fullscreen:~1;Graphics w,h,(32*fullscreen);
		glEnable(GL_ALPHA_TEST);glAlphaFunc(GL_NOTEQUAL,0);glEnable (GL_BLEND);
		glEnable (GL_TEXTURE_2D)
		glBindTexture GL_TEXTURE_2D, buffer_id
		glTexImage2D GL_TEXTURE_2D, 0, GL_RGB, w, h, 0, GL_RGB, GL_UNSIGNED_BYTE, New Int[3 * w * h]
		glTexParameteri GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_LINEAR
		glTexParameteri GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR
		glTexParameteri GL_TEXTURE_2D, GL_TEXTURE_WRAP_S, GL_CLAMP
		glTexParameteri GL_TEXTURE_2D, GL_TEXTURE_WRAP_T, GL_CLAMP
	EndIf
	Flip vb
Wend

	
	' ----------------------------------------------------------------
	Rem
		bbdoc:   
	End Rem
	Function Circle(_f_angle:Float, _f_radius:Float = 2.0, _f_x:Float = 0, _f_y:Float = 0, _f_z:Float = 0, _index:Int = 0 )
		
	'	glLoadIdentity
	'	glTranslatef _f_x, _f_y, _f_z 
		
		Local f_alpha:Float = _f_angle
			
		Local f_x:Float
		Local f_y:Float	
		
		glBegin %GL_POLYGON
		
		While f_alpha  < 360 + _f_angle
						
			glTexCoord2f 0.0, 0.0
			
			glVertex3f  _f_x, _f_y, 0.0          
			
			If _index & 1
				glTexCoord2f 0.0, 1.0
			Else
				glTexCoord2f 1.0, 1.0
	
			EndIf
			
			f_x = _f_x + _f_radius * Cos(f_alpha)
			f_y = _f_y + _f_radius * Sin(f_alpha)
		
			glVertex3f f_x,f_y, 0.0          
			
			If _index& 1
				glTexCoord2f 1.0, 1.0
			Else
				glTexCoord2f 0.0, 1.0
			EndIf
			
			f_x = _f_x + _f_radius * Cos(f_alpha - _f_angle)
			f_y = _f_y + _f_radius * Sin(f_alpha - _f_angle)
			
			glVertex3f f_x, f_y, 0.0          
			  
			_index :+ 1
			
			f_alpha :+ _f_angle
			
		Wend
		glEnd
	
	End Function

	' ----------------------------------------------------------------
	Rem
		bbdoc:   
	End Rem		
	Function KaleidoscopeII(_f_angle:Float, _f_radius:Float = 2.0, _f_x:Float = 0, _f_y:Float = 0, _f_z:Float = -5, _index:Int = 0 )
		
	'	glClear GL_COLOR_BUFFER_BIT
	'	glLoadIdentity
	'	glTranslatef _f_x, _f_y, _f_z 
		
		Local f_alpha:Float = _f_angle
			
		Local f_x:Float
		Local f_y:Float	
				
		Circle(_f_angle, _f_radius, _f_x, _f_y, _f_z, _index)
	Rem	
		
		While f_alpha  < 360 + _f_angle
						
			f_x = _f_x + 1.0*_f_radius * Cos(f_alpha)
			f_y = _f_y + 1.0*_f_radius * Sin(f_alpha)
		
			Circle(_f_angle, _f_radius, f_x, f_y, _f_z, _index)
			
			f_alpha :+ 2*_f_angle
			
		Wend
		
	End Rem

	End Function

Taron

(Posted 2010) [#16]

OH NO, tHAT's FANTASTIC, DAVID!
Just go pageup to increase the brightness and it's one heck of a looker! SWEET!

I'll check out what you've done there in a moment for sure! Uh, how I hope this thread will keep going!

THANKS, and I'm honestly thrilled!

KaleidoscopeII(60/mirror, h, w/2,h/2,0)

DavidDC

(Posted 2010) [#17]

Well what do you know... Looks better when you can see it! :-)

_JIM	(Posted 2010) [#18]

This is very inspirational. Keep this thread going :)

Wonder if some shaders on top of this would improve the "wow" factor.

Taron

(Posted 2010) [#19]

Considering that the my old laptop gets the "woha" factor as soon as the word "Texture" appears... :D

Yup, this could become something completely wicked. I even thought about some deferred solution, which could make this a real trip. But, YEHAH, go right ahead, I'm already all giddy to see what you guys would do to this!!!

And, as a small reminder, anyone who'd like to make use of a FRAME BUFFER OBJECT solution, I'm swinging on my toes to see that! :}

_JIM	(Posted 2010) [#20]

I just wish I had more time to mess around with this. Right now most of my "time assigned to coding" goes right into my project and I can't delay it, because the other guys'll kill me heh.

Well, you were playing with shaders in that worm test. How did you do that if not on your amazingly old laptop? :)

Taron

(Posted 2010) [#21]

On my 8core mac pro under winXP64 with NVidia 7300. ;)

Ah rats...tell the boys, that you're just doing some mental jogging to stay in shape! :}

Here's a little nicer version. You can control the "motionblur" now, too. Additional mirror/kaleidoscope modes. Additional quad (fan) modes.

SuperStrict
Framework brl.GLMax2D

AppTitle="GL particle toy - <F1> show info"

Global w:Int = 800
Global h:Int = 600
Graphics w,h,0
Global spinnerlist:TList = CreateList()
Type spinner
	Field x:Float
	Field y:Float
	Field rx:Float
	Field ry:Float
	Field rot:Float
	Field mult:Float
	Field col:Float[]
	Field order:Byte
	Field trimult:Float[2]
	
	Method move(t:Float, scl:Float, dim:Float)
		Local counter:Double =t+rot
		rx = Cos(counter*trimult[0])
		ry = Sin(counter*trimult[1])
		counter = Sin(Double(rot))
		x:-rx*counter
		y:-ry*counter
		Local temp:Float = dim
		If shading Then temp:*(rx*0.5+ry*0.5)
		Local dim2:Float = temp*3
		col = [temp+temp*rx,temp+temp*ry,dim2+dim2*Float(Sin(counter-2*rot)),1.0]
		rx:*mult*scl
		ry:*mult*scl
	End Method
	
	Method draw(offset:Float, Mode:Byte)
		glColor4f(col[0],col[1],col[2],col[3])
		If Mode
			If order Then glVertex2f(x-rx, y-ry);If fan>0 Then glColor4f(col[0],col[1],col[2],0.1)
			
			glVertex2f(x+rx*offset, y+ry*offset);If fan>1 Then glColor4f(col[0],col[1],col[2],0.1)
			If Self <> spinnerlist.First() 
				glVertex2f(x-rx, y-ry);glVertex2f(x+rx*offset, y+ry*offset)
			End If
			If Not order Then glVertex2f(x-rx, y-ry)
		Else
			glVertex2f(x-rx, y-ry);
			glColor4f(col[0],col[1],col[2],0.1)
			glVertex2f(x+rx*offset, y+ry*offset)
		End If
	End Method
	
	Function Create:spinner(x:Float,y:Float, rot:Float, mult:Float, order:Byte, tmx:Float, tmy:Float)
		Local s:spinner = New spinner
		s.x = x
		s.y = y
		s.rot = rot
		s.mult = mult
		s.col = [1.0,1.0,1.0,1.0]
		s.order = order
		s.trimult = [tmx, tmy]
		ListAddLast spinnerlist,s
		Return s
	End Function
End Type

glEnable(GL_ALPHA_TEST)
glAlphaFunc(GL_NOTEQUAL,0)           
glEnable (GL_BLEND);

Local buffer_id:Int

glEnable (GL_TEXTURE_2D)
glGenTextures (1, Varptr buffer_id)

glBindTexture GL_TEXTURE_2D, buffer_id
glTexImage2D GL_TEXTURE_2D, 0, GL_RGB, w, h, 0, GL_RGB, GL_UNSIGNED_BYTE, New Int[3 * w * h]
glTexParameteri GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_LINEAR
glTexParameteri GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR
glTexParameteri GL_TEXTURE_2D, GL_TEXTURE_WRAP_S, GL_CLAMP
glTexParameteri GL_TEXTURE_2D, GL_TEXTURE_WRAP_T, GL_CLAMP

Global fan:Byte = 0
Global shading:Byte = 0
Local mblur:Float = 0.25
Local speed:Float = 1.5
Local dim:Float = 0.05
Local scaler:Float = 2.0
Local offset:Float = 5.0
Local order:Byte = 0
Local glow:Byte =1
Local Mode:Byte =1
Local vb:Byte = 1
Local show:Byte = 0
Local fullscreen:Byte = 0

Local mirror:Byte = 0

Local count_ms:Float = 1000
Local fc:Int = 0
Local fps:Int
Local store_ms:Float
Local t:Float = 0
While Not KeyHit(KEY_ESCAPE)
	count_ms :+(MilliSecs()-store_ms)
	fc:+1
	If count_ms >=1000
		fps = fc
		fc = 0
		count_ms = 0
	End If
	store_ms = MilliSecs()
	
	glDisable (GL_TEXTURE_2D)
	glBlendFunc (GL_SRC_ALPHA,GL_ONE_MINUS_SRC_ALPHA) 		
	glBegin GL_QUADS
	If mirror <5 Then glColor4f(0.0,0.0,0.0,mblur) Else glColor4f(0.0,0.0,0.0,0.15+mblur*2)
	glVertex2f(0.0,0.0);glVertex2f(0.0,h);glVertex2f(w,h);glVertex2f(w,0.0)
	glEnd	

	t:+speed/(1.0+2*(1.0-vb))
	If MouseDown(1) Then spinner.Create(MouseX(),MouseY(),t*2,15+Cos(t)*20, order,2,1); order:~1
	If MouseDown(2) Then spinner.Create(MouseX(),MouseY(),t*2,15+Sin(t)*20, order,1,2); order:~1
	For Local s:spinner = EachIn spinnerlist
		s.move(t,scaler,dim)
	Next
	If glow Then glBlendFunc (GL_SRC_ALPHA,GL_ONE) 		
	If Mode Then glBegin(GL_QUADS) Else glBegin(GL_LINES)
		For Local s:spinner = EachIn spinnerlist
			s.draw(offset, Mode)
		Next
	glEnd
	
	If mirror>0
	
		glFlush ()
		glEnable (GL_TEXTURE_2D)
		glBindTexture(GL_TEXTURE_2D, buffer_id )
		glEnable GL_TEXTURE_2D 
	
	   	glCopyTexImage2D(GL_TEXTURE_2D, 0, GL_RGB, 0, 0, w-1, h-1, 0)
		'glBlendFunc (GL_SRC_ALPHA,GL_ONE) 	
		glColor4f(1.0,1.0,1.0,1.0)
		
		glClear(GL_COLOR_BUFFER_BIT)
		If mirror<3 
			KaleidoscopeII(60/mirror, h, w/2,h/2,0) 
		Else
			glBlendFunc (GL_SRC_ALPHA,GL_ONE_MINUS_SRC_ALPHA) 	
			glBegin (GL_QUADS)
				glTexCoord2f(0,0);glVertex2f(0,0)
				glTexCoord2f(0,1);glVertex2f(0,h)
				glTexCoord2f(1,1);glVertex2f(w,h)
				glTexCoord2f(1,0);glVertex2f(w,0)
			glEnd
			If mirror>3
				If mirror>4 Then glBlendFunc (GL_SRC_ALPHA,GL_ONE) 	
				glBegin (GL_QUADS)
					glTexCoord2f(1,0);glVertex2f(0,0)
					glTexCoord2f(1,1);glVertex2f(0,h)
					glTexCoord2f(0,1);glVertex2f(w,h)
					glTexCoord2f(0,0);glVertex2f(w,0)
				glEnd
				glBlendFunc (GL_SRC_ALPHA,GL_ONE_MINUS_SRC_ALPHA) 	
			End If
		EndIf
	End If
	If show
		glBlendFunc (GL_SRC_ALPHA,GL_ONE_MINUS_SRC_ALPHA) 		
		glBegin GL_QUADS
		glColor4f(0.0,0.0,0.0,0.3)
		glVertex2f(0.0,5.0);glVertex2f(0.0,160.0);glVertex2f(500.0,160.0);glVertex2f(500.0,5.0)
		glColor4f(1.0,1.0,1.0,1.0)
		glEnd
		Local nextline:Int = 10
		GLDrawText "spinners:"+ spinnerlist.Count()+"  fps:"+fps+ " vb:"+vb,10,nextline;nextline:+15 
		GLDrawText "(M)toogle lines/quads:"+ mode+" (Z)Kaleidoscopes:"+mirror+" (SPACE) clear",10,nextline;nextline:+15
		GLDrawText "(A)toogle solid/glow:"+ glow+"  (N)toogle shading:"+shading+"  (V)v.blank:"+vb,10,nextline;nextline:+15
		GLDrawText "(B)fan:"+ fan,10,nextline;nextline:+25
		GLDrawText dim,10,nextline;		GLDrawText" :Luminance(pageUP/DOWN)",120,nextline;nextline:+15
		GLDrawText offset,10,nextline;	GLDrawText" :Line length (arrow UP/DOWN)",120,nextline;nextline:+15  
		GLDrawText mblur,10,nextline;	GLDrawText" :Motionblur(SHIFT + arrow UP/DOWN)",120,nextline;nextline:+15
		GLDrawText scaler,10,nextline;	GLDrawText" :Anim stretch(arrow LEFT/RIGHT)",120,nextline;nextline:+15
		GLDrawText speed,10,nextline;	GLDrawText" :Speed (Home/End)",120,nextline;nextline:+15
	EndIf
	
	If KeyDown(KEY_HOME) Then speed:+0.05
	If KeyDown(KEY_END) Then speed:-0.05
	If KeyDown(KEY_PAGEUP) Then dim:+0.001
	If KeyDown(KEY_PAGEDOWN) Then dim:-0.001
	If KeyDown(KEY_UP) 	Then If KeyDown(KEY_RSHIFT) Or KeyDown(KEY_LSHIFT) Then mblur:+0.01 Else offset:+0.1
	If KeyDown(KEY_DOWN)Then If KeyDown(KEY_RSHIFT) Or KeyDown(KEY_LSHIFT) Then mblur:-0.01 Else  offset:-0.1
	If KeyDown(KEY_LEFT) Then scaler:-0.1
	If KeyDown(KEY_RIGHT) Then scaler:+0.1
	If KeyHit(KEY_A) Then glow:~1
	If KeyHit(KEY_M) Then Mode:~1
	If KeyHit(KEY_N) Then shading:~1
	If KeyHit(KEY_V) Then vb:~1
	If KeyHit(KEY_SPACE) Then spinnerlist.Clear()
	If KeyHit(KEY_F1) Then show:~1
	If KeyHit(KEY_Z) Then mirror:+1; If mirror>5 Then mirror= 0
	If KeyHit(KEY_B) Then fan:+1; If fan>2 Then fan=0
	If KeyHit(KEY_F) 
		'w = 1920
		'h = 1080
		fullscreen:~1;Graphics w,h,(32*fullscreen);
		glEnable(GL_ALPHA_TEST);glAlphaFunc(GL_NOTEQUAL,0);glEnable (GL_BLEND);
		glEnable (GL_TEXTURE_2D)
		glBindTexture GL_TEXTURE_2D, buffer_id
		glTexImage2D GL_TEXTURE_2D, 0, GL_RGB, w, h, 0, GL_RGB, GL_UNSIGNED_BYTE, New Int[3 * w * h]
		glTexParameteri GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_LINEAR
		glTexParameteri GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR
		glTexParameteri GL_TEXTURE_2D, GL_TEXTURE_WRAP_S, GL_CLAMP
		glTexParameteri GL_TEXTURE_2D, GL_TEXTURE_WRAP_T, GL_CLAMP
	EndIf
	Flip vb
Wend

	
	' ----------------------------------------------------------------
	Rem
		bbdoc:   
	End Rem
	Function Circle(_f_angle:Float, _f_radius:Float = 2.0, _f_x:Float = 0, _f_y:Float = 0, _f_z:Float = 0, _index:Int = 0 )
		Local f_alpha:Float = _f_angle
			
		Local f_x:Float
		Local f_y:Float	
		
		glBegin %GL_POLYGON
		
		While f_alpha  < 360 + _f_angle
						
			glTexCoord2f 0.0, 0.0
			glVertex3f  _f_x, _f_y, 0.0          
			
			If _index & 1
				glTexCoord2f 0.0, 1.0
			Else
				glTexCoord2f 1.0, 1.0
			EndIf
			
			f_x = _f_x + _f_radius * Cos(f_alpha)
			f_y = _f_y + _f_radius * Sin(f_alpha)
		
			glVertex3f f_x,f_y, 0.0          
			
			If _index& 1
				glTexCoord2f 1.0, 1.0
			Else
				glTexCoord2f 0.0, 1.0
			EndIf
			
			f_x = _f_x + _f_radius * Cos(f_alpha - _f_angle)
			f_y = _f_y + _f_radius * Sin(f_alpha - _f_angle)
			
			glVertex3f f_x, f_y, 0.0          
			  
			_index :+ 1
			
			f_alpha :+ _f_angle
		Wend
		glEnd
	
	End Function

	' ----------------------------------------------------------------
	Function KaleidoscopeII(_f_angle:Float, _f_radius:Float = 2.0, _f_x:Float = 0, _f_y:Float = 0, _f_z:Float = -5, _index:Int = 0 )
		Circle(_f_angle, _f_radius, _f_x, _f_y, _f_z, _index)
	End Function

DavidDC

(Posted 2010) [#22]

Holy smokes! (instant reaction).... Looking closer with great interest :-)

Boiled Sweets

(Posted 2010) [#23]

Is this code public domain?

DavidDC

(Posted 2010) [#24]

OK so I've basically been spending the last hour gazing in wonder. Both at the output AND the code! Maybe it's because I'm a kaleidoscope nut, but I really find this exciting.

Yet I'm feeling embarrassed that I can't work out how that extra kaleidoscopic complexity has wormed its way in there? That's exactly what I was originally trying to do with the original "KaleidoscopeII" fn, but scrapped it because there were holes in the output. Yet you seem to have done just that. But where?

You have this wonderful ability to produce amazing effects from such a minimal code base. I really admire that. But in this case you've gone too far - the extra complexity seems to have been conjured from nothing! That's not playing fair :-)

Now if those spinners drifted slowly around the screen - maybe along smooth random spline paths... (hehe)

Taron

(Posted 2010) [#25]

LOL, hahaha! Thanks, David!
To your kaleidoscope, which I consider just as ingenius and simple, I've added the mirroring solution I've written earlier only as test for the buffers. A whole lot more can be created out of both solutions to really create some unusual visuals.

Boiled Sweets, well, I post such things here to create a platform for all of us to exchange ideas and grow. As long as you're not planning to commercialize this tool as one of your screensavers or claim for it to be yours, but you want to learn from it to write your own, that's exactly what it's for. Other than that the rights remain with all contributers. I think I'd personally explode, if I saw our little toy here as a product somewhere! So, be good and join the fun, but contain other aspirations with it...please. Fair question, though. I think ultimatively just because it's here, it's kinda pd by default, not sure.

Thanks for asking, though! <even if it feels a lil' icky>

_Skully

(Posted 2010) [#26]

though. I think ultimatively just because it's here, it's kinda pd by default, not sure.

Not really... the Code Archives specifically states that code posted there is PD... technically speaking, just because you post code here doesn't mean its PD... I suppose one could always say "I thought it was" but you have caveated its use... which is essentially like a license.

just IMHO.. no legal presedence here.

Taron

(Posted 2010) [#27]

I just wished non of that would ever have to be a topic. Call me naive, but all the corruption scratches our power to evolve wholeheartedly. I enjoy far too much to share my findings and hope to find us all linking our minds to learn from each other and enable us to produce the best we can produce. If someone bounces in to take advantage of it with the result of discouraging such a common disclosure of discoveries, it's more than just a shame. The least I'd expect is real participation and some action that boosts our readiness to share with and trust each other. It's all too easy for all of us to crawl back into our own machine and just develop by ourselves, some hoping for some profits, others just trying to endulge.

One day, if we manage to as a species, we will remember the oldest of all understandings and that is that we have managed to survive and thrive, because we had the ability to work together! It became our nature to do so. Millenia of deceitful propaganda and idealisations of superiority devorced us from the jaded roots that once made us strong.

I offer you my mind, because I can feel this power and hope that you recognize the same, be it consciously or due to the resulting sense of joy. And I'm telling you, it's almost too much joy for me when we bounce this innocent little code back and forth between us!

And thanks, Skully, I kinda thought the same.

dmaz	(Posted 2010) [#28]

I'm no expert and don't claim legally binding knowledge...

you hold all copyright to your "specific" code, basically the code as a whole unless posted in the code archives as _Skully said. the issues with that though are; -you- have to prove infringement and posting in a forum like this will make "fair use" an easy defense. not to mention that if you really wanted to keep the code close you could have either prefaced it with copyright or limited license or even just posted an executable.... any specific algorithms above are not copyrightable(though maybe patentable :( ) so anybody can glean that information they need for free.... but that's exactly what it sounds like you and most of us want, which I applaud! ideas are not protect-able by copyright but the work put into it is.

Boiled Sweets

(Posted 2010) [#29]

Perhaps I should have made it clear that it would be a FREEWARE screen saver and would acknowledge IN LARGE PRINT that the code was written by you and/or the Blitz community.

No worries, just an idle thought.

Taron

(Posted 2010) [#30]

What you should do is add what's minimally necessary to actually turn this into a screensaver and post the updated code! That would be the spirit.
You could offer your website as release channel, knowing that it wouldn't be limited to it, while it very well could become the spot for more releases of that kind. I think that would be fantastic! And I think you'd have a beautiful idle thought there! :}

Again, I wished that copyrights and patents would all become redundant troubles of the past right along with money, actually, haha. Rise above indoctrinations and embrace the full and increasing capacity of human ingenuity!
<I'm gonna go offer my freshly roasted coffeebeans now, see if I can get some batteries!> :P

But, really, if we were putting our heads together, I can imagine that we'd come up with a system that would free us from monetary ties, realising that our basic needs can be covered elegantly and beautifully by ingenuity in different fields (architecture and agriculture to name the first). When you truely enjoy something, you move outside of the realm of egocentricity and status ambitions. When you create something, research and discover something, you are in a sincere zone outside of civilization's rules and doctrins. Relating to this garanties you that you are in the right field. Opportunism is for banksters, agents and industrials, who'd all be screwed, if we'd know better.

So, well, let's start or rather continue here and see how these babysteps get us to join our minds more and enable us to do better.

One more little thing, though, I've learned from most of you all that enabled me to write bmax code in the first place and more than once I took complete sections of code to get things rolling. But it's been key for me to understand what's going on in order to apply my ideas and get to where I want to take things. I'm still learning and feel like I know next to nothing. My advice, however, never take code and rest on the result, but understand what's going on, heck, ruin it or improve it, but make it your understanding. You, genius brother, have a brilliance that can only come from you and it would be wasted, if not applied!